在VBScript中使用类（四）

    现在的代码离我们想要的还是有些不太实用，我们将在其他页使用类tvprogram，因此最好将其独立定义，以便所有也面都可以调用。创建一个asp页面，并命名为tvprogramclass.asp，我们在其中定义类tvprogram。

--tvprogramclass.asp--

<%

class tvprogram

         private internal_starttime

         public property get starttime
                 starttime = hour(internal_starttime) & _
                      ":" & minute(internal_starttime)
         end property

         public property let starttime(byval vartimein)
                 if isdate(vartimein) then
                    internal_starttime = vartimein
                 end if
         end property

         private internal_programdate

         public property get programdate
               programdate = day(internal_programdate) & _
                      " " & monthname(month(internal_programdate)) & _
                      " " & year(internal_programdate)
         end property

         public property let programdate(byval vardatein)
               if isdate(vardatein) then
                      internal_programdate = vardatein
               end if
         end property

         public programtitle

end class

%>

    这样就可以在任何asp中调用我们定义的类了，语法如下：

<!-- #include virtual="tvprogramclass.asp" -->
<%
        dim objtvshow
        set objtvshow = new tvprogram
        objtvshow.starttime = cdate("17:30")
        objtvshow.programdate = dateserial(1999,9,17)
        objtvshow.programtitle = "the jerry springer show"
%>

<%= objtvshow.programtitle %> is on at <%= objtvshow.starttime %> on <%= objtvshow.programdate %>.

 

这里有一个建议。如果你重命名你的包含文件.asp，并保证所有重要代码都在<code><% ... %>< code>中，那么就算有人猜到了你包含文件的文件名，也没办法看见里面的内容！