在VBScript中使用类来组织开发

当在一个机构内部创建Web应用程序时，有些时候你会发现你自己从一个应用程序中复制和粘贴相同的代码到其它的应用程序中。如果你能够固化所有这些过程到一个好用的小包（package）中，其后你就可以在整个域中使用它了，这样会方便很多。

同时，如果你有一个再三使用的过程，创建一个类包含你的过程可能会比较有用。使用类组织你的代码有一些优点：它使得你的代码容易阅读和调试；你可以将你的类轻松的移值到一个Web服务中；你为其它开发人员提供一个抽象工具（从而节省了时间和资金）；同时在一个项目的开发阶段你还保留了灵活性。

当把你的通用过程组织到一个类的时候，你创建一级抽象，允许你在几乎所有代码中实现这些过程。例如，假设在你创建的每个Web应用程序中，你需要初始化用户信息。这个初始化过程包括在用户登录到你的应用程序时根据用户凭证所做的一些数据库服务器连接。如果你在每个应用程序中都需要完成这个任务的话，那么将你的代码固化到一个类中相当有意义。下面是方法：

Dim MyToolbox
Set MyToolbox = New CToolbox
Response.Write "UserName: " & MyToolbox.UserName & "<BR>" & vbCrLf
Response.Write "UserPhone: " &  MyToolbox.UserPhone & "<BR>" & vbCrLf
Set MyToolbox = Nothing

Class CToolbox
Private m_conn, m_rs
Private m_username, m_userphone

Public Property Get UserName()
    UserName = m_username
End Property

Public Property Get UserPhone()
    UserPhone = m_userphone
End Property

Private Sub Class_Initialize()
    Set m_conn = Server.CreateObject("ADODB.Connection")
    m_conn.ConnectionString = "Some connection string"
    m_conn.Open
    Set m_rs = Server.CreateObject("ADODB.Recordset")
    Set m_rs.ActiveConnection = m_conn
    m_rs.Open "SELECT * FROM Users WHERE userid = ‘" &
                        Request.ServerVariables("LOGON_USER") & "‘"
    If Not m_rs.EOF Then
        m_username = m_rs.Fields("username")
        m_userphone = m_rs.Fields("userphone")
    End If
End Sub

Private Sub Class_Terminate()
    On Error Resume Next
    m_rs.Close
    Set m_rs = Nothing
    m_conn.Close
    Set m_conn = Nothing
End Sub

End Class

 

从例子中你可以看到，UserName和UserPhone属性在类初始化之后就会有值。你可以将这个类的代码放到ASP代码的底部。然后在其余的代码中其功能就可以在使用，不用实例化ADO对象，进行数据库调用和之后的清理。而且，如果你使用的是Microsoft Visual InterDev，你在类中定义的属性和方法可以通过IntelliSense使用。

>

IntelliSense只对一级有效，所以如果你创建一个类返回其它ASP类的对象的话，可用的方法和属性就不会提供给你。

下面的代码是一个类的骨架：

Class MyClass

Private Sub Class_Initialize()
End Sub

Private Sub Class_Terminate()
End Sub

End Class

使用这个基本信息，一个类被声明，并且可以使用它来创建对象。然后这个类的对象没有功能——它们是无用的东西。类的方法从Public Sub或者Public Function声明构建（Subs没有返回值，而Function有返回值）。

有两个方法可以暴露属性：既可以使用在类的全局上下文中的Public VarName，也可以使用Public Property Get/Set/Let。如果你需要一个只读属性，只要简单地使用一个Property Get声明。所有其它声明为Private的Properties，Subs或者Functions只有在实例化的对象可用。在类的全局上下文中声明为Private的变量是成员变量。

创建类的另外一个优点是你可以轻易的将这个类声明移值到Web服务中。因为这是很多开发人员前进的方向，你可以通过使用类创建面向对象的代码先行一步。当你移值这些类声明到一个Web服务时，你不需要重写所有的放置了那段代码的ASP代码。所要做的唯一的改变就是你的对象的实例化。

我发现创建这个抽象的最大的优点是可以使用其它Web开发者的帮助。因为对于很多开发人员来说在每个不同的实现中重复创建相同的代码效率相当低，所以这个方法为每个开发人员提供了一个抽象工具。这就允许每个开发人员将精力更多地集中在当前工作的功能上面，而不是花费时间开发已经开发过的代码上面。

如果你奇怪为什么我不提供一个COM对象来处理这个功能，那是因为它会把你锁定到细节设计中。通过在ASP中动态地创建类，你可以不用重新编译和发布就能够能类做出改动。在类固定之后，再将它移值到COM、Windows脚本组件（WSC）或者一个Web服务中。但是在开发阶段还是灵活一些好。