分享

自制Flash FLV视频播放器 - MaxIE - 博客园

 w3322laile123 2007-12-11
大家好,前不久笔者将CenFun Music Player加入flv视频播放功能,这里单独拿出来给大家做一个Flash FLV播放器(仅ActionScript控制,不使用 FLVPlayback 组件),如有不当之处还望指正。
下面就打开您的Macromedia Flash Player 8(推荐)开始吧!

首先新建文档,设置背景色黑色,其他默认,然后建四个图层。

第一层用来放视频元件,方法如下:

1,在"库"面板("窗口">"库")中,从"库"弹出菜单中选择"新建视频"。
2,在"视频属性"对话框中,命名视频元件并选择"视频"(由 ActionScript 控制)。
3,将视频对象从"库"面板拖到舞台正中间,以创建视频对象实例。
4,对此视频元件取实例名为 "my_video"。

第二层用来放视频地址输入栏,方法如下:

1,在舞台左下方用文本工具(快捷键T)画一个地址输入文本框,类型选择"输入文本"类型。
2,在"线条类型"弹出菜单中选择"单行",并确认"在文本周围显示边框"处于选中状态。
3,对此文本框取实例名为"url"。

第三层用来放播放开始按钮,方法如下:

1,在"库"面板("窗口">"库")中,新建元件按钮,按钮样式自行制作好,暂时能用就行。
2,将新建的按钮对象从"库"面板拖到舞台地址输入框后面,以创建播放开始按钮。
3,对此播放开始按钮取实例名为"play_bt"。

第四层用来放所有的ActionScript:


//首先初始化  
//创建一个 NetConnection 对象
var my_nc:NetConnection = new NetConnection();
//创建一个本地流连接
my_nc.connect(null);
//创建一个 NetStream 对象
var my_ns:NetStream = new NetStream(my_nc);  
//写一个播放函数playflv()  
function playflv(flv) {
//参数flv是要播放的flv视频地址
//trace(flv);//测试用
// 将 NetStream 视频输入信号附加到 Video 对象,即视频元件my_video
my_video.attachVideo(my_ns);
// 设置缓冲时间,单位秒,下面设置3秒即可
my_ns.setBufferTime(3);
// 开始播放 FLV 文件
my_ns.play(flv);
}  
//点击开始播放按钮开始播放  
play_bt.onRelease = function() {
playflv(url.text);
//获得url输入框的视频文件地址,并调用播放函数播放url对应的flv视频文件
};
//////////////////////////////////////////////////////////////////////////////
//至此一个最简单的播放器已经做完了,下面要做的都是对其进行更多的控制和表现工作。
//这里就其几个重要的方面进行制作,其他的还需要大家发挥自己的想象去进行更好的设计制作。
//注意,以下代码非必要,未经测试,望大家一个一个尝试实现。特别注意路径和实例名的对应。

//*********************************
//1,播放的控制,暂停和停止的实现
//新建两个按钮,一个暂停(pause_bt),一个停止(stop_bt),原理和播放按钮一样。

pause_bt.onRelease = function() {
my_ns.pause();
};  
stop_bt.onRelease = function() {
my_ns.seek(0);
//搜寻从0开始播放
my_ns.pause(true);
//参数true表示暂停,若是false则表示从暂停变为继续播放,若没有参数则为在暂停/播放中切换。
};
//*********************************
//2,视频下载进度
//这个比较简单,和一般的下载进度类似,原理就是播放时将已下载的和总共文件大小进行百分比,然后显示出来。
//新建显示百分比的静态文本(info)和进度条(bar),其初始状态、位置自行调整


this.onEnterFrame =function () {
var loadedbytes = my_ns.bytesLoaded;
//获得已经下载字节
var totalbytes = my_ns.bytesTotal;
//文件总大小
if (totalbytes == undefined || totalbytes<4000) {
  info.text = "0%";
  bar._width = 1;
} else {
  var nowLoadPercent = Math.round(loadedbytes/totalbytes*100);
  if (isNaN(nowLoadPercent)) {
   info.text = "0%";
   bar._width = 1;
  } else {
   info.text = nowLoadPercent+"%";
   bar._width = nowLoadPercent*35/100;
   if (nowLoadPercent == 100) {
    delete this.onEnterFrame;
   }
  }
}
}
//*********************************
//3,视频尺寸修正或调整
//这个比较重要,因为视频尺寸比例一般都不一样,故播放时要进行调整,以免失真变形。
//原理就是获得flv的尺寸,然后重新调整my_video的尺寸,最后将位置居中,必要时还可进行缩放处理(这里省略)。


//首先写个改变尺寸函数changesize(w, h),w为要改变为的宽度,h为要改变为的高度
function changesize(w, h) {
//改变到传进来的参数尺寸
my_video._width = w;
my_video._height = h;
//trace("w:"+w+"h:"+h);//测试用
//位置居中处理,假如你的视频舞台宽550,高400
my_video._x = 550/2-w/2;
my_video._y = 400/2-h/2;
}
//然后获得flv的固有尺寸,并调用以上函数改变它
//此处理函数在调用 my_ns.play() 方法后而在视频播放头前进之前触发
my_ns.onMetaData = function(infoObject:Object) {
//获得FLV文件中嵌入的描述性信息,这里获得宽/高
var flv_width = infoObject.width;
var flv_height = infoObject.height;
//改变尺寸
changesize(flv_width, flv_height);
};
//*********************************
//4,播放时间和进度
//原理和下载进度类似,先获得总持续时间,然后获得当前时间对其进行百分比,也可做进度条。


// 定义总持续时间全局变量,并获得其值。
var flv_duration;
my_ns.onMetaData = function(infoObject:Object) {
//获得FLV文件中嵌入的描述性信息,这里获得获得总持续时间(单位:秒)
var flv_duration = infoObject.duration;
};
//注意:这里可以和获得宽高写在一起。
//获取当前播放时间
var flv_thistime = my_ns.time;
//然后便可制作播放进度了,和下载进度类似,大家自己制作,此处略。
//*********************************
//5,音量的控制


//这个复杂一点,必须先将音频从 FLV 文件附加到舞台上的影片剪辑,然后对其进行控制
//新建影片剪辑my_ns_mc,并附加音频
my_ns_mc.attachAudio(my_ns);
//为影片剪辑创建新的 Sound 对象
var my_ns_sound = new Sound(my_ns_mc);
//初始化音量(此处默认80)
var flv_volume = 80;
my_ns_sound.setVolume(flv_volume);
//最后对flv_volume的大小(0到100间)进行控制即可改变音量大小
//这部分制作也省略,大家自由发挥,还可以制作静音功能,即flv_volume为0
//*********************************
//还有,像快进,快退,缓冲显示等等,都可以实现,大家自行研究。

////////////////////////////////////////////
最后,一个Flash FLV播放器的制作基本完成了,推荐想学flash的朋友亲自动手去实现,不要老是想去下载什么源码然后修改一通,那样就体会不到其中的很多奥妙了!

补充一个相关问题:flv播放没有图象,只有声音,这是因为这个flv文件用flash 8的编码格式压缩,而你发布的flash播放器为flash 7或更低的版本,故升级为版本8即可,或者将flv文件采用flash 7的编码格式压缩。

    本站是提供个人知识管理的网络存储空间,所有内容均由用户发布,不代表本站观点。请注意甄别内容中的联系方式、诱导购买等信息,谨防诈骗。如发现有害或侵权内容,请点击一键举报。
    转藏 分享 献花(0

    0条评论

    发表

    请遵守用户 评论公约

    类似文章 更多