徐文明抄底模型

徐文明抄底模型：

１、当前流通股本小于5亿股；

２、KDJ的J小于0；

３、CCI的值在-200以下；
４、股价位于BOLL下轨以下；

５、股价远离5日线10%以上。

使用：

收盘后选股，次日继续下跌时择机买入，
反弹到5日均线卖出，盘面好时反弹到10日均线卖出。
加入条件选股中，适用于暴跌后的抄底。

{选股或附图公式１：}

N:=5;{５日内选出}

QJ0:=CAPITAL<5000000;
QJ1:="KDJ.J"<0;
QJ2:=CCI<-200;
QJ3:=CLOSE<"BOLL.LOWER";
QJ4:=CLOSE<MA(C,5)*0.9;
QJ5:="DMI.ADX">40;{这个条件比较严厉，也可设为：QJ5:=1;}
TJ:=QJ0 AND QJ1 AND QJ2 AND QJ3 AND QJ4 AND QJ5;
XG: COUNT(TJ,N)>=1;

 

=============考虑到TDX运行上面公式有时不成功,以下给出完整公式===============

{选股或附图公式２：}

N:=5;{５日内选出}

QJ0:=CAPITAL<5000000;
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=SMA(RSV,3,1);
D:=SMA(K,3,1);
J:=3*K-2*D;
QJ1:=J{"KDJ.J"}<0;

QJ2:=CCI<-200;

BOLL:=MA(CLOSE,20);
UPPER:=BOLL+2*STD(CLOSE,20);
LOWER:=BOLL-2*STD(CLOSE,20);
QJ3:=CLOSE<LOWER{"BOLL.LOWER"};

QJ4:=CLOSE<=MA(C,5)*0.9;

TR1 := SMA(MAX(MAX(HIGH-LOW,ABS(HIGH-REF(CLOSE,1))),ABS(LOW-REF(CLOSE,1))),7,1);
HD := HIGH-REF(HIGH,1);
LD := REF(LOW,1)-LOW;
DMP:= SMA(IF(HD>0 AND HD>LD,HD,0),7,1);
DMM:= SMA(IF(LD>0 AND LD>HD,LD,0),7,1);
PDI:= DMP*100/TR1,LINETHICK2;
MDI:= DMM*100/TR1;
ADX:= SMA(ABS(MDI-PDI)/(MDI+PDI)*100,7,1);

QJ5:=ADX{"DMI.ADX"}>40;{这个条件比较严厉，也可设为：QJ5:=1;}
TJ:= QJ0 AND QJ1 AND QJ2 AND QJ3 AND QJ4 AND QJ5;
XG: COUNT(TJ,N)>=1;

需要说明的是：

１、如果用未来函数检验软件检测，会发现CAPITAL是未来函数，因为这是流通盘指标，所以不影响使用。
２、BOLL线下轨BOLL.LOWER，因为通达信版本的原因，有的函数是BOLL.LB，导入时发现错误时要替换，由于通达信软件的不稳定，公式测试时可能提示没有此参数，可以先用BOLL指标显示附图，再测试使用本公式};

３、如果上面第一个公式运行无效，请采用第二个公式，功能相同。

　　wen98提醒大家：底下还有底。这里所说抄底，也只是相对低点而已！