本文介绍 Microsoft Excel 中 TEXT 函数 （函数:函数是预先编写的公式，可以对一个或多个值执行运算，并返回一个或多个值。函数可以简化和缩短工作表中的公式，尤其在用公式执行很长或复杂的计算时。）的公式语法和用法。
说明
TEXT 函数可将数值转换为文本，并可使用户通过使用特殊格式字符串来指定显示格式。需要以可读性更高的格式显示数字或需要合并数字、文本或符号时，此函数很有用。例如，假设单元格 A1 含有数字 23.5。若要将数字格式设置为人民币金额，可以使用以下公式：
=TEXT(A1,"￥0.00")
在本例中，Excel 会显示 ￥23.50。
也可以使用功能区上“开始”选项卡上的“数字”组中的命令来设置数字格式。但是，只有整个单元格都为数字时，这些命令才起作用。如果需要设置数字格式并将其与其他文本合并，使用 TEXT 函数是最佳选择。例如，可以向前一个公式中添加文本：
=TEXT(A1,"￥0.00") & " 每小时"
Excel 会显示 ￥23.50 每小时。
语法
TEXT(value, format_text)
TEXT 函数语法具有以下参数 （参数:为操作、事件、方法、属性、函数或过程提供信息的值。）：
- value 必需。数值、计算结果为数值的公式，或对包含数值的单元格的引用。
- format_text 必需。使用双引号括起来作为文本字符串的数字格式，例如，"m/d/yyyy" 或 "#,##0.00"。有关详细的格式准则，请参阅以下部分。
有关数字格式的准则
- 显示小数位和有效位 若要设置分数或含有小数点的数字的格式，请在 format_text 参数中包含以下位占位符、小数点和千位分隔符。
| 占位符 |
说明 |
| 0（零） |
如果数字的位数少于格式中零的数量，则显示非有效零。例如，如果键入 8.9，但要将其显示为 8.90，请使用格式 #.00。 |
| # |
按照与 0（零）相同的规则执行操作。但是，如果键入的数字在小数点任一侧的位数均少于格式中 # 符号的数量，Excel 不会显示多余的零。例如，如果自定义格式为 #.## 且在单元格中键入了 8.9，则会显示数字 8.9。 |
|
按照与 0（零）相同的规则执行操作。但是，对于小数点任一侧的非有效零，Excel 会加上空格，使得小数点在列中对齐。例如，自定义格式 0.0? 会对齐列中数字 8.9 和 88.99 的小数点。 |
| . （句点） |
在数字中显示小数点。 |
- 如果数字的小数点右侧的位数大于格式中的占位符，该数字会四舍五入到与占位符具有相同小数点位的数字。如果小数点左侧的位数大于占位符数，Excel 会显示多余的位数。如果格式仅在小数点左侧含有数字符号 (#)，小于 1 的数字会以小数点开头；例如，.47。
| 显示内容 |
显示格式 |
使用此格式 |
| 1234.59 |
1234.6 |
"####.#" |
| 8.9 |
8.900 |
"#.000" |
| 0.631 |
0.6 |
"0.#" |
12
1234.568 |
12.0
1234.57 |
"#.0#" |
44.398
102.65
2.8 |
44.398
102.65
2.8
（小数点对齐） |
"???.???" |
5.25
5.3 |
5 1/4
5 3/10
（分数对齐） |
"# ???/???" |
- 显示千位分隔符 要将逗号显示为千位分隔符或按倍数 1,000 缩放数字，请在数字格式中包含以下分隔符。
| ,（逗号） |
在数字中显示千位分隔符。如果格式中含有被数字符号 (#) 或零包围起来的逗号，Excel 会分隔千位。位占位符后的逗号会以 1,000 为单位计量数字。例如，如果 format_text 参数为 "#,###.0,"，Excel 会将数字 12,200,000 显示为 12,200.0。 |
| 显示内容 |
显示格式 |
使用此格式 |
| 12000 |
12,000 |
"#,###" |
| 12000 |
12 |
"#," |
| 12200000 |
12.2 |
"0.0,," |
有关日期和时间格式的准则
- 显示日、月和年 若要将数字显示为日期格式（如日、月和年），请在 format_text 参数中使用以下代码。
| m |
将月显示为不带前导零的数字。 |
| mm |
根据需要将月显示为带前导零的数字。 |
| mmm |
将月显示为缩写形式（Jan 到 Dec）。 |
| mmmm |
将月显示为完整名称（January 到 December）。 |
| mmmmm |
将月显示为单个字母（J 到 D）。 |
| d |
将日显示为不带前导零的数字。 |
| dd |
根据需要将日显示为带前导零的数字。 |
| ddd |
将日显示为缩写形式（Sun 到 Sat）。 |
| dddd |
将日显示为完整名称（Sunday 到 Saturday）。 |
| yy |
将年显示为两位数字。 |
| yyyy |
将年显示为四位数字。 |
| 显示内容 |
显示格式 |
使用此格式 |
| 月 |
1–12 |
"m" |
| 月 |
01–12 |
"mm" |
| 月 |
Jan–Dec |
"mmm" |
| 月 |
January–December |
"mmmm" |
| 月 |
J–D |
"mmmmm" |
| 日 |
1–31 |
"d" |
| 日 |
01–31 |
"dd" |
| 日 |
Sun–Sat |
"ddd" |
| 日 |
Sunday–Saturday |
"dddd" |
| 年 |
00–99 |
"yy" |
| 年 |
1900–9999 |
"yyyy" |
- 显示小时、分钟和秒钟 若要显示时间格式（如小时、分钟和秒钟），请在 format_text 参数中使用以下代码。
| h |
将小时显示为不带前导零的数字。 |
| [h] |
以小时为单位显示经过的时间。如果使用了公式，该公式返回小时数超过 24 的时间，请使用类似于 [h]:mm:ss 的数字格式。 |
| hh |
根据需要将小时显示为带前导零的数字。如果格式含有 AM 或 PM，则基于 12 小时制显示小时； 否则，基于 24 小时制显示小时。 |
| m |
将分钟显示为不带前导零的数字。
注释 m 或 mm 代码必须紧跟在 h 或 hh 代码之后或紧跟在 ss 代码之前；否则，Excel 会显示月份而不是分钟。
|
| [m] |
以分钟为单位显示经过的时间。如果所用的公式返回的分钟数超过 60，请使用类似于 [mm]:ss 的数字格式。 |
| mm |
根据需要将分钟显示为带前导零的数字。
注释 m 或 mm 代码必须紧跟在 h 或 hh 代码之后或紧跟在 ss 代码之前；否则，Excel 会显示月份而不是分钟。
|
| s |
将秒显示为不带前导零的数字。 |
| [s] |
以秒为单位显示经过的时间。如果所用的公式返回的秒数超过 60，请使用类似于 [ss] 的数字格式。 |
| ss |
根据需要将秒显示为带前导零的数字。如果要显示秒的小数部分，请使用类似于 h:mm:ss.00 的数字格式。 |
| AM/PM、am/pm、A/P、a/p |
基于 12 小时制显示小时。时间介于午夜和中午之间时，Excel 会使用 AM、am、A 或 a 表示时间；时间介于中午和午夜之间时，Excel 会使用 PM、pm、P 或 p 表示时间。 |
| 显示内容 |
显示格式 |
使用此格式 |
| Hours |
0–23 |
"h" |
| Hours |
00–23 |
"hh" |
| 分钟 |
0–59 |
"m" |
| 分钟 |
00–59 |
"mm" |
| 秒 |
0–59 |
"s" |
| 秒 |
00–59 |
"ss" |
| 时间 |
4 AM |
"h AM/PM" |
| 时间 |
4:36 PM |
"h:mm AM/PM" |
| 时间 |
4:36:03 P |
"h:mm:ss A/P" |
| 时间 |
4:36:03.75 |
"h:mm:ss.00" |
| 经过的时间（小时和分钟） |
1:02 |
"[h]:mm" |
| 经过的时间（分钟和秒） |
62:16 |
"[mm]:ss" |
| 经过的时间（秒和百分之一秒） |
3735.80 |
"[ss].00" |
有关货币、百分比和科学记数法格式的准则
- 包含货币符号 若要在数字前加上人民币符号 (￥)，请在 format_text 参数的开头键入人民币符号（例如，"￥#,##0.00"）。若要以数字格式输入以下货币符号之一，请按 Num Lock 并使用数字小键盘键入各符号对应的 ANSI 代码。
| 显示内容 |
使用此组合键 |
| ¢ |
Alt+0162 |
| £ |
Alt+0163 |
| ¥ |
Alt+0165 |
 |
Alt+0128 |
| E（E-、E+、e-、e+） |
以科学记数（指数）格式显示数字。Excel 会在“E”或“e”的右侧显示与小数点移动的位数对应的数字。例如，如果 format_text 参数为 "0.00E+00"，Excel 会将数字 12,200,000 显示为 1.22E+07。如果将 format_text 参数更改为 "#0.0E+0"，Excel 会显示 12.2E+6。 |
有关包含文本和添加空格的准则
- 如果在 format_text 参数中包括以下任一字符，则它们会按输入时的原样显示。
| $ |
美元符号 |
| + |
加号 |
| ( |
左括号 |
| : |
冒号 |
| ^ |
扬抑符（脱字符） |
| ' |
撇号 |
| { |
左大括号 |
| < |
小于号 |
| = |
等于号 |
| - |
减号 |
| / |
斜杠符号 |
| ) |
右括号 |
| ! |
感叹号 |
| & |
与号 |
| ~ |
波形符 |
| } |
右大括号 |
| > |
大于号 |
| |
空格字符 |
注释
- format_text 参数不能包含星号 (*)。
- 使用 TEXT 函数将数值转换为带格式的文本，此时将无法将结果当作数字来执行计算。若要设置某个单元格的格式以使得其值仍保持为数字，请右键单击该单元格，选择“设置单元格格式”，然后在“设置单元格格式”对话框的“数字”选项卡上设置所需的格式选项。有关使用“设置单元格格式”对话框的详细信息，请单击对话框右上角的“帮助”按钮 (?) 。
示例
如果将示例复制到一个空白工作表中，可能会更容易理解该示例。
如何复制示例？
要点 不要选择行或列标题。
从“帮助”中选择示例
- 按 Ctrl+C。
- 在 Excel 中，创建一个空白工作簿或工作表。
- 在工作表中，选择单元格 A1，然后按 Ctrl+V。
要点 若要使该示例能够正常工作，必须将其粘贴到工作表的单元格 A1 中。
- 要在查看结果和查看返回结果的公式之间进行切换，请按 Ctrl+`（重音符），或在“公式”选项卡上的“公式审核”组中，单击“显示公式”按钮。
将示例复制到一个空白工作表中后，可以按照您的需要改编示例。
|
|
| A |
B |
C |
| 销售人员 |
销售额 |
数据 |
| Burke |
2800 |
39300.625 |
| Dykstra |
40% |
|
| 公式 |
说明 |
结果 |
| =A2&" sold "&TEXT(B2, "￥0.00")&" worth of units." |
将单元格 A2、文本字符串 " sold"、单元格 B2（货币格式）以及文本字符串 " worth of units." 合并为一个短语。 |
Burke sold ￥2800.00 worth of units. |
| =A3&" sold "&TEXT(B3, "0%")&" of the total sales." |
将单元格 A3、字符串 " sold"、单元格 B3（百分比格式）和文本字符串 " of the total sales." 合并为一个短语。 |
Dykstra accounted for 40% of the total sales. |
| ="Date: " & TEXT(C2, "yyyy-mm-dd") |
以 4 位年、2 位月和 2 位日格式显示单元格 C2 中的值。 |
Date: 2007-08-06 |
| ="Date-time: " & TEXT(C2, "m/d/yyyy h:mm AM/PM") |
以短日期、12 小时制格式显示单元格 C2 中的值。 |
Date-time: 8/6/2007 3:00 PM |
| =TEXT(C2, "0.00E+00") |
以科学记数（指数）格式显示单元格 C2 中的值。 |
3.93E+04 |
| TEXT(C2, "￥#, ##0.00") |
以货币格式和千位分隔符显示单元格 C2 中的值。 |
￥39,300.63 |
|
