本帖最后由 水星钓鱼 于 2009-12-7 19:48 编辑
Q:如何给列表框或组合框添加单列或者多列项目? A:由于给列表框和组合框添加项目的方法是一样的。所以接下来都以列表框为例,且假设用户窗体上有一个列表框控件ListBox1。 附件如下 对于单列的列表框,向一个空的列表框添加项目可以使用列表框的AddItem方法。 如下所示:
- Private Sub UserForm_Initialize()
- With Me.ListBox1
- .AddItem = "a"
- .AddItem = "b"
- .AddItem = "c"
- End With
- End Sub
复制代码 使用Additem方法只能一个元素一个元素的添加,利用它的第二个参数还可以灵活的指定将要添加的元素的位置。 如果想要一次性添加多个元素,可以使用列表框的List属性。 如以下代码也是向列表框添加a,b,c元素:
- Private Sub UserForm_Initialize()
- With Me.ListBox1
- .List = Array("a", "b", "c")
- End With
- End Sub
复制代码 可以把List属性的数据类型看作是Variant类型。当列表框中无项目时,List属性值为Null,一旦列表框中有了项目,它就是一个以行数为第一维,列数为第二维的二维数组。 对于想要设置显示为多列的列表框,首先要设置列表框的ColumnCount属性为想要显示的列数。(如果不设置该属性,将不能显示多列数据) 如果再用AddItem方法给列表框添加项目的话,会出现怎样的情况呢? 如下所示:
- Private Sub UserForm_Initialize()
- With Me.ListBox1
- .ColumnCount = 2
- .AddItem "A"
- .AddItem "B"
- '检查列表框第2列第1行的元素
- MsgBox VarType(.List(0, 1)) = vbNull
- End With
- End Sub
复制代码 运行代码可以发现,用AddItem方法给多列的列表框赋值时,只能赋值给第一列,其余列都是Null值。此时可以使用List属性来改变其余列的元素。 如下所示:
- Private Sub UserForm_Initialize()
- With Me.ListBox1
- .ColumnCount = 2
- .AddItem "A"
- .AddItem "B"
- .List(0, 1) = "C"
- .List(1, 1) = "D"
- End With
- End Sub
复制代码 当然也可以一次性将一个二维数组赋值给列表框。 如下所示:
- Private Sub UserForm_Initialize()
- With Me.ListBox1
- .ColumnCount = 2
- .List = Application.Evaluate("{""A"",""C"";""B"",""D""}")
- End With
- End Sub
复制代码 这里容易犯的错误就是直接用list属性来为列表框的某行某列赋值。 如下所示:
- Private Sub UserForm_Initialize()
- With Me.ListBox1
- .ColumnCount = 2
- .List(0, 0) = 1
- End With
- End Sub
复制代码 这是错误的,因为当要指定具体的某个行列数时,前提是要这个行列已经存在。事实上,在给List(0, 0)赋值前,它是不存在的。引用了不存在的元素将导致错误。 |