分享

几种实用的条件选股公式

 银狐1963 2012-04-04
几种实用的条件选股公式

 以下收藏的条件选股公式供投资者参考,后市调整后青龙探水选股会派上用场:

条件选股公式:D!HMCSF (黑马草上飞) 缺省周期:日线
==============================================================
LCZ:=(C-MA(C,60))/MA(C,60)*100;

A1:=COUNT(MA(C,60)>REF(MA(C,60),1),100)>95;
A2:=COUNT(LCZ<20,100)>95;
A3:=COUNT(C>MA(C,60),100)>80;
A4:=C/REF(C,1)>1.04;
A5:=V/CAPITAL*100>2.8;

ZTJ:=A1 AND A2 AND A3 AND A4 AND A5;
ZTJ AND (REF(BARSLAST(ZTJ),1)>20 OR BARSSINCE( ZTJ)=0);
==============================================================
黑马草上飞:
1
60日价格均线平稳上扬。
2
、日K线按照60日均线斜率震荡上行。
3
、经过大半年的震荡向上,终于向上突破。
操作:
发出信号后逢低积极介入。
==============================================================

条件选股公式:D!LYT (老鸭头) 缺省周期:日线
==============================================================
MA5 := MA(close,5);
MA10 := MA(close,10);
MA60 := MA(close,60);

pday1 := barslast(cross(ma5,ma60));{5日均线上穿60日均线}
pday2 := barslast(cross(ma10,ma60));{10日均线上穿60日均线,至此形成鸭颈部}
pday3 := barslast(high=hhv(high,pday2));{形成头部,要下跌}
pday4 := barslast(cross(ma10,ma5));{下跌后,5日均线和10日均线死叉}
pday5 := barslast(cross(ma5,ma10));{回落不久,5日均线和10日均线形成金叉,形成嘴部}

a1:= pday1>pday2 and pday2>pday3 and pday3>pday4 and pday4>pday5 and pday5<5;

a2:= count(cross(ma10,ma5),pday2)=1;

A1 AND A2;
==============================================================
老鸭头:
(1)采用5、10和60周期的价格平均线。当5日、10日均线放量上穿60日平均线后,形成鸭颈部。
(2)股价回落时形成的高点形成鸭头部。
(3)当股价回落不久,5日、10日均线再次金叉向上形成鸭嘴部。
操作:
(1)在5日、10日均线放量上穿60日平均线形成鸭颈部时买入。
(2)在鸭嘴部附近成交量芝麻点一带逢低买入。
(3)当股价放量冲过鸭头顶瞬间时介入。
==============================================================


条件选股公式:D!LZMD (量芝麻点) 缺省周期:日线
==============================================================
V1:=MA(V,40);
HSL:=V/CAPITAL*100;

A1:=COUNT(V/V1<1.3,14)>11;
A2:=CROSS(HSL,2);
A3:=C/REF(C,1)>1.025 AND C>OPEN;

ZTJ:=A1 AND A2 AND A3;

==============================================================
量芝麻点:
成交量连续出现萎缩,在量柱体图上表现为小芝麻点,连续的小芝麻点与40日量平均线形成一个小水坑。
操作建议:
最好K线浅幅回档,且成交量越小越好,当放量上行时买入。
==============================================================


条件选股公式:D!QLQS (青龙取水) 缺省周期:日线
==============================================================
A1:=MIN(MA(C,5),MA(C,10))>MA(C,60) AND CROSS(MA(C,5),MA(C,10));
A2:=MIN(MA(C,5),MA(C,10))/MA(C,60)<1.05;
A3:=COUNT(V<MA(V,10),10)>6;

A1 AND A2 AND A3;
==============================================================
青龙取水:
1、在5日、10日、60日均线图上,5、10日均线起伏不定,日K线在60日均线上逶迤。
2、龙头回到60日均线附近,犹如青龙取水,同时成交量萎缩
3、然后大涨。
操作:待龙头形成,成交量萎缩又放大后,逢低介入。
==============================================================


条件选股公式:D!QSGT (轻松过头) 缺省周期:日线
==============================================================
nday := hhvbars(high,120); {120日内最高价的周期数}
nday1:= nday-10; {最高点之后10日}
nday2:= nday+10; {庄家应该在nday1--nday2之间吸纳大部分筹码}

a1 := nday>=30;{确保高点出现的周期数大于30}

a2 := ref(sum(vol,20),nday1) > finance(7) * 0.4; {吸纳40%}

VMA:=MA(Vol,40);{40日量均线}

A3:=COUNT(Vol<VMA,nday1)/nday1>0.9;{成交量呈现芝麻点}

A4:=Close>=hhv(high,120);{股价在冲击前高位}

A5:=COUNT(Vol<(MA(vol,10)*1.3),10)>8;{近期无明显放量}

A1 AND A2 AND A3 AND A4 AND A5;
==============================================================
轻松过头:
(1)前一个头部下方的成交量巨大,股价筑头后开始回档。
(2)回档完毕后成交量呈量芝麻点,股价再次上扬冲击前一头部。
(3)轻松冲过前一头部并未明显放量。
操作:
(1)在前一头部成交量巨大时跟进。
(2)在回档完毕后成交量呈现芝麻点时逢低吸纳。
(3)最经济、最大利润化的方法是在轻松过头前的一瞬间迅速介入。
(4)前头部价格一般是上升浪的腰部。
==============================================================


条件选股公式:D!SJCJD (三金叉见底) 缺省周期:日线
==============================================================
nday := 5;

down := close/llv(low,60)<=1.2;

pma1 := ma(close,5);
pma2 := ma(close,10);

vma1 := ma(vol,5);
vma2 := ma(vol,10);

diff := ema(close,12) - ema(close,26);
dea := ema(diff,9);

ppday := barslast(cross(pma1,pma2));
vvday := barslast(cross(vma1,vma2));
macdday := barslast(cross(diff,dea));

sjcjd:= if((ppday<=nday and vvday<=nday and macdday<=nday),1,0);

==============================================================
三金叉见底:
(1)当股价长期下跌后开始企稳筑底,而后股价缓慢上升。有时会同时出现5日和10日均价线、5日和10日均量线、MACD的黄金交叉点,这是股价见底回升的信号。
(2)有时会伴随出现两阳夹一阴多方炮、出水芙蓉、量顶天立地和MACD上穿零线等图形。
操作:
(1)当出现三金叉后开始买入股票。
(2)或等股价回档时在10日均线附近逢低吸纳。
==============================================================


条件选股公式:D!SSCJD (三死叉见顶) 缺省周期:日线
==============================================================
nday := 5;

down := hhv(high,20)/high<=1.15;

pma1 := ma(close,5);
pma2 := ma(close,10);

vma1 := ma(vol,5);
vma2 := ma(vol,10);

diff := ema(close,12) - ema(close,26);
dea := ema(diff,9);

ppday := barslast(cross(pma2,pma1));
vvday := barslast(cross(vma2,vma1));
macdday := barslast(cross(dea,diff));

sscjd:= if((ppday<=nday and vvday<=nday and macdday<=nday),1,0);

==============================================================
三死叉见顶:
(1)当股价长期上涨后开始进入头部,而后股价缓慢下跌。有时会同时出现5日和10日均价线、5日和10日均量线、MACD的死亡交叉点,这是股价见顶回落的信号。
(2)有时会伴随出现两阴夹一阳空方炮、断头铡刀MACD下穿零线等图形。
操作:
(1)当出现三死叉后坚决卖出股票。
(2)或等股价反弹到10日均线附近逢高派发。

    本站是提供个人知识管理的网络存储空间,所有内容均由用户发布,不代表本站观点。请注意甄别内容中的联系方式、诱导购买等信息,谨防诈骗。如发现有害或侵权内容,请点击一键举报。
    转藏 分享 献花(0

    0条评论

    发表

    请遵守用户 评论公约

    类似文章 更多