《第二十一楼》 目录索引： QUOTE: 951.问: 这句话如何表达？ zdz:=hhv(macd,SYSPARAM(3)-SYSPARAM(2)); zdz[SYSPARAM(3)]; DRAWNUMBER(macd=zdz and zdz<>ref(zdz,1),macd,zdz,3) ; 我想把可见区间的macd最大值标注在对应的macd上，只标注最大的一组数据。 答(股市骑兵00): 这样试试： zdz:=hhv(macd,SYSPARAM(3)-SYSPARAM(2)+1); DRAWNUMBER(macd=zdz[SYSPARAM(3)],macd,MACD,3) ; QUOTE: 952.问: 能否给一个上证指数副图的指标? 答(hx817): 副图显示指数 方法一 foxc:="1A0001$close";foxo:="1A0001$open";foxl:="1A0001$low";foxh:="1A0001$high"; ktj:=(foxc>foxo or foxc=o and foxc>ref(foxc,1)); stickline(ktj,foxh,foxl,0.1,1),colorred; stickline(ktj,foxc,foxo,7,1),colorred; stickline(not(ktj),foxh,foxl,0.1,0),colorcyan; stickline(not(ktj),foxc,foxo,7,0),colorcyan; 方法二 XO:=INDEXO;XH:=INDEXH;XL:=INDEXL;XC:=INDEXC; STICKLINE(XC>XO OR (XC=XO AND XC>REF(XO,1)),XC,XH,0.1,0),COLORMAGENTA; STICKLINE(XC>XO OR (XC=XO AND XC>REF(XO,1)),XO,XL,0.1,0),COLORMAGENTA; STICKLINE(XC>XO OR (XC=XO AND XC>REF(XO,1)),XO,XC,7,0),COLORMAGENTA; STICKLINE(XC<XO OR (XC=XO AND XC<=REF(XO,1)),XH,XL,0.1,0),COLORCYAN; STICKLINE(XC<XO OR (XC=XO AND XC<=REF(XO,1)),XO,XC,7,0),COLORCYAN; 对应指数开:INDEXO LINETHICK0 PRECISION0 COLORYELLOW;高:INDEXH LINETHICK0 PRECISION0 COLORWHITE; 低:INDEXL LINETHICK0 PRECISION0 COLORRED;收:INDEXC LINETHICK0 PRECISION0 COLORCYAN; QUOTE: 953.问: 我想选股上午停牌一小时的个股,也就是当天出消息的个股. 答(南客): 只能选出开盘后1小时内没有交易的股票，是否停牌还需人工判断 试试如下公式： //注意，必须用于1分钟选股 tn:=(TIME0-37800)/60-(time>113000)*90; tj:＝sum(vol,60)<=0.001 and time=103000; tj:ref(tj,tn); //当日10：30前，成交量＝0 QUOTE: 954.问: 此低点比上次的低点要高,这个公式怎么写. （原码）:vvar1:=(HIGH+LOW+5*CLOSE)/7; vvar2:=MA(vvar1,5)-MA(vvar1,34); vvar3:=MA(vvar2,5); TEG:vvar2-vvar3,colorff0000,,linethick2 ; p:=IF(TEG<REF(TEG,1),1,0); a:=BARSLAST(p); b:IF(a>0.5,teg,0); 答(股市骑兵00): 参考看看： vvar1:=(HIGH+LOW+5*CLOSE)/7; vvar2:=MA(vvar1,5)-MA(vvar1,34); vvar3:=MA(vvar2,5); TEG:vvar2-vvar3,colorff0000,,linethick2 ; p:=IF(TEG<REF(TEG,1),1,0); a:=BARSLAST(p); b:IF(a>0.5,teg,0); X:=TEG>REF(TEG,1) AND REF(TEG,1)<REF(TEG,2); Y:=TEG>REF(TEG,SUMBARS(X,2)-1) AND X; DRAWICON(Y,TEG,4); CODE:[Copy to clipboard]955.问: 个股上市第一天最高价及最低价画线公式 答(股市骑兵00): ref(h,barpos-1); 答(hx817): 一样的 fh:=h; fl:=l; fh[1]; fl[1]; QUOTE: 956.问: 欲求过去的某一天（给出年、月、日）至今天的交易天数 答(peter109): DD:=1050829;//參數 指定日期 DATEDIFF(CURRENTDATE,DD);//計算計算机日期到指定日期間隔天數 DATEDIFF(DATE,DD);//計算K線日期到指定日期間隔天數 CODE:[Copy to clipboard]957.问: 换手率累加到100后从0开始再累加怎么写 答(南客): sv:vol; s:=0; for i=1 to datacount do begin if s>=capital then s:=0; s:=s+sv ;
sv:=s;
end;
QUOTE:
958.问:
能具体讲一下MOM这个指标的原码吗
答(anlb):
动量线MOM
公式概说
1.12天MOM：（当日收盘价-12天前收盘价）
2.25天MOM：（当日收盘价-25天前收盘价）
3.图表上除了显示动量线之外，经常另外配置一条动量线的10天平均线。
来龙去脉
MOmentum动量线，简称MOM。“动量”这一名词，市场上的解释相当广泛。以Momentum命名的指标，种类更是繁多。综合而言，动量可以视为一段期间内，股价涨跌变动的比率。这里所介绍的动量线，是由Perry Kaufman 在《 Trading Systems and Methods》一书所发表的简易动量模式。
一般股民，经常将Momentum视为超买超卖指标，而忽略其在“速度”方面的表现。事实上，将Momentum解释成“速度线”，更符合其实际的作用。理论上，一波健全的股价趋势，其上涨或下跌的过程，应该维持着一定的行进速度。如果行进的速度逐渐减缓，股价很容易转变成整理的格局，甚至于反转。因此，观察股价的速度感，对于股价多空力道的判定，有很大的帮助。
指标剑法
12天M0M以O轴为中心线，O轴的上、下方，分成六等份的超买超卖区，分别为＋1、＋2、+3和-1、-2、-3。例如：甲股的12天MOM上升至6·8时，我们将它定义为＋1。那么，13.6就是＋2，20.4就是+3。相反的，-6.8定义为-1·-13·6为-2，-20·4为-3。
注意！每一支股票的超买超卖区都不一样，读者必须自行寻找适合的界限值。
1.短线行情，12日MOM上升至+1时，股价回档。
2.短线行情，12日MOM下跌至-1时，股价反弹。
3.中期趋势， 2日MOM＞＋2时，经常是上升波段结束的时机。
4.中期趋势，12日MOM＜-2时，经常是下跌波段结束的时机。
5.12日MOM＞＋3变成极端行情时，视为强势多头格局，持股不必过早卖出。可以等待MOM指标曲线，变成一波顶比一波顶低，而与股价走势背离时，再卖出不迟。
6.12日MOM＜-3变成极端行情时，视为极弱势空头格局，不可随意进场买入股票。至少等待MOM指标曲线，形成一波底比一波底高，而与股价走势背离时，再择机进场买入。
25天MOM（速度线）以O轴为中心线：
1.25天MOM＞O轴，代表中期多头走势。
2.25天MOM＜O轴，代表中期空头走势。
3.25天MOM向上交叉其6天平均线，并且其6天平均线也同步向上扭转时，股价容易上涨。
4.25天MOM向下交叉其6天平均线，并且其6天平均线也同步向下扭转时，股价容易下跌。
注意！单纯观察25天MOM的6天平均线时，这条曲线一般都与股价同步。因此，当25天MOM的6天平均线开始走缓，并且有转弯迹象时，应小心股价是否即将反转。
（附注一）25天MOM也可以规画出+3至-3六个超买超卖界限，但是，一般以12天MOM较为常用。
（附注二）25天MOM与12天MOM合并使用效果更佳.当12天MOM显示超买或超卖状况时，同时观察25天MOM,可以检查其是否构成反转的条件。如果条件尚未成熟，则12天MOM所显示的超买或超卖现象，可能只会促使股价回档或者反弹而已。
（附注三）如果12天MOM曾经上升至＋2或＋3的界限，同时25天MOM也显示股价有向下反转的疑虑时。请参考EXPMA指数平均数，观察其0.15指数平均数，是否发生向下交叉0.04指数平均数的现象。如果EXPMA的两条平均数，已经出现向下交叉的讯号，则可以确定股价正式向下反转。
（附注四）如果12天MOM曾经下跌至-2或-3的界限，同时25天MOM也显示股价有向上回升的迹象时。请参考EXPMA指数平均数，观察其0.15指数平均数，是否发生向上交叉0.04指数平均数的现象。如果EXPMA的两条平均数，已经出现向上交叉的讯号，则可以确定股价正式向上反转。
深入讲解
常态与极端的区别
传统的超买超卖指标，一般波动于0～100之间，并且拥有固定的超买超卖值。当股价温和波动时，这一类型指标，在短线买卖的时机上，尚可以提供相当的参考价值。但是，当股价波动幅度加剧，出现大行情时，传统指标因受限于固定的波动范围，常会出现指标钝化的现象，这种现象股民常常称之为“指标失灵”。
为了突破超买超卖指标的限制，行情必须分级。MOM动量线将行情分成三级，第一和第二级称为“常态行情”，第三级称为“极端行情”。第一级行情就是所谓的短期趋势，第二级行情为中期趋势。行情处于第一或第二级波动时，股价的回档或反弹，大都能和MOM指标的超买超卖线相呼应。类似这种模式的行情，其MOM很少超过＋3和-3的范围。
MOM的最大波动，如果是仅局限于+2～-2之间的行情，我们称之为“常态行情”。例如：“矩形”和标准的“三波段”行情。这类型股票，一般都是股性较温和的个股，循环规律有节奏感，涨跌脉动有迹可寻，走势较容易掌握。
“矩形”的行情，其动量线大多波动于＋1～-1之间。但是，其股价的行进并不一定呈横向整理。单方向的上涨或下跌，只要股价以“涨、跌、涨、跌”的温和速度前进，都可视为“矩形”行情。就好像“轨道线”、“路径指标”一样，很规矩的被限制在一定的空间，它的买进卖出讯号，非常明确而且肯定。
标准三波段上涨或者三波段下跌的行情，其动量线波动范围，经常会扩充至＋2～-2之间。MOM抵达+1或-1时，第一波行情结束。第二波行情属于回档或者反弹波。最后，由第三波行情将MOM推移至＋2或-2。（这里指的是波浪理论中的前三波，其第五波行情一般都属极端行情较多）。
一般理想状况之下，MOM动量线会依上述两种模式，规矩的波动在第一与第二级超买超卖界限内。而且，股民很容易掌握股价的脉动，我们称之为“常态行情”。然而，当行情变成超强势或极弱势时，MOM指标会急冲至＋3之上或-3之下，我们称之为“极端行情”。一旦股价出现极端行情时，超买超卖型指标会失去作用，读者应选择采用趋势指标，或者等待指标形成“背离”的状态时，再进行买卖的动作。
价差引力
深入了解MOM动量线之前，必须先了解其公式的计算方法。以12日MOM为例子，他是将当天的股价，和12天前的股价做比较的结果。我们可以想像两个股价间，存在着一种引力。当目前的价格和12天前的价格，两者之间的差距扩大到一定极限时，当天的股价会受到牵制，暂时停止前进。也就是说，当天的价格和12天前的价格，存在着最大极限距离的限制。在一般“常态行情”下，大多数个股几乎都能符合这种运动规律。
“价差引力”也可视为“价格乖离”，乖离率太大时，股价必须调整修正。随着行情大小的不同，两个价格之间的差距，存在着最大容许极限。一旦短线行情，突破第一级差距极限时，则股价会朝第二级差距极限前进，并且转变成中级行情。如果中级行情突破第三级差距极限，则“常态行情”变成“非常态行情”，股价像断了线的风筝，变成无法掌控的脱轨状况。
多空天秤
25天的MOM动量线，是价格平衡原理的典型代表。市场上所有的价格行为，只有强和弱之分。基于“汰弱择强”的操作原则，股民一定会选择介入强势股。然而强和弱、多和空是相对的名词，股民在决定一次交易之前，必须先明确区分多空的界线，才能对目前的价位下一个定义。
股价走势表现在K线图表上时，是由左向右倾斜的。如果价格曲线向有上方倾斜前进，则代表股价上涨；如果价格曲线向右下方倾斜前进，则代表股价下跌。换句话说，现在的价格必须高于先前的价格，才能视为强势多头。但是，现在的价格，并不一定是近期内的最高价。它可能比前天的价位高，比昨天的价位低。如此一来，怎么样才能对“价格倾斜”下定义呢？
现在，我们以25天为周期，取第13天为中间支点，左右各占12天。把今天的价格与25天前的价格连成一直线，将这条直线视为一根横杆。右边的当日价格和左边的25天前价格，当成左右两边的秤盘。然后组合中间支点、横杆、秤盘。
当右方的秤盘高于左方的秤盘时，表示右方卖压轻，股价强势。此时，MOM指
标会高于O轴，代表多头走势。当右方的秤盘低于左方的秤盘时，表示右方卖压重，股价弱势。此时，MOM指标会低于O轴，代表空头走势。也许，你想修改25天的周期参数。但是，根据研究，25天的周期参数，在认定多空界限方面，显然较具代表性。
QUOTE:
959.问:
取指定证券名称字符串
用法:
STKNAMEEX(S),S为证券代码
例如STKNAMEEX('600000')或STKNAMEEX('SH600000')返回浦发银行。
如何取指定证券代码字符串呢？如“浦发银行”返回“600000”。
答(cwy):
STRTONUM(STRRIGHT(STKLABEL,6));
QUOTE:
960.问:
設
價差: 當KD金叉時, 顯示C-REF(L,金叉)之價差.而金叉之後皆以C-REF(L,金叉-1)之價差顯示.
如
價差:IF(CROSS(K,D),C-REF(L,金叉),IF(條件,C-REF(L,金叉-1),0));
請問這樣條件如何編寫
答(peter109):
INPUT:n(9,1,100),m1(3,2,40),m2(3,2,40);
RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
K:=SMA(RSV,M1,1);
D:=SMA(K,M2,1);
a:=CROSS(k,d);
//b:=CROSS(d,k);
x:=BARSLAST(a);
//y:=BARSLAST(b);
//fl:=x-y;
價差:IF(A,C-ref(L,x),C-ref(L,x+1));
QUOTE:
961.问:
如何在副图的指标曲线旁显示自己希望数字内容,如公式kdj中k值>95时的数字?
答(peter109):
drawnumber(K>95,K,K,0);
QUOTE:
962.问:
請教 畫水平線,設 KD 金叉
1:當金叉成立,就取前低劃一水平線.
2:之後,就取金叉的低點劃一水平線.一直顯示到死叉為止.
用 DRAWSL 來編寫
答(xxllxxll):
INPUT:n(9,1,100),m1(3,2,40),m2(3,2,40);
RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
K:=SMA(RSV,M1,1);
D:=SMA(K,M2,1);
a:=CROSS(k,d);
b:=CROSS(d,k);
x:=BARSLAST(a);
y:=BARSLAST(b);
fl:=x-y;
DRAWSL(b,ref(low,fl),0,fl,1);
有游標
INPUT:n(9,1,100),m1(3,2,40),m2(3,2,40);
RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
K:=SMA(RSV,M1,1);
D:=SMA(K,M2,1);
a:=CROSS(k,d);
b:=CROSS(d,k);
x:=BARSLAST(a);
y:=BARSLAST(b);
ya:=sysparam(1);
yb:=barssince(c)+1;
金叉前低:if(x=0,ref(low,x+1),0) LINETHICK0 ;
金叉后低:if(ref(y,1)>ref(x,1) and y<>0,ref(low,x),0) LINETHICK0;
死叉前高:if(y=0,ref(high,y+1),0) LINETHICK0;
死叉后高:if(ref(x,1)>ref(y,1) and x<>0,ref(high,y),0) LINETHICK0;
DRAWSL(x=0 and ya=yb,ref(low,1),0,0,0);
DRAWSL(y>x and x>0 and ya=yb,ref(low,x),0,0,0);
DRAWSL(y=0 and ya=yb,ref(high,1),0,0,0);
DRAWSL(x>y and y>0 and ya=yb,ref(high,y),0,0,0);
答(gusi):
金叉是不是这样，如是的话，那死叉请自己再改改吧
INPUT:n(9,1,100),m1(3,2,40),m2(3,2,40);
RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
K:=SMA(RSV,M1,1);
D:=SMA(K,M2,1);
a:=CROSS(k,d);
b:=CROSS(d,k);
x:=BARSLAST(a);
y:=BARSLAST(b);
ya:=sysparam(1);
yb:=barssince(c)+1;
金叉前低:if(x=0,ref(low,x+1),0),LINETHICK0 ;
金叉后低:if(ref(y,1)>ref(x,1) and y<>0,ref(low,x),0),LINETHICK0;
死叉前高:if(y=0,ref(high,y+1),0) LINETHICK0;
死叉后高:if(ref(x,1)>ref(y,1) and x<>0,ref(high,y),0),LINETHICK0;
DRAWSL(x=0 and ya=yb,ref(low,1),0,0,0);
DRAWSL(y>x and x>0 and ya=yb,low,0,0,0);
DRAWSL(y=0 and ya=yb,ref(high,1),0,0,0);
DRAWSL(x>y and y>0 and ya=yb,ref(high,y),0,0,0);
DRAWNUMBER(x=0 and ya=yb,low,ref(low,x),2),COLORWHITE;
DRAWNUMBER(y>x and x>0 and ya=yb,low,low,2),COLORWHITE;
答(xxllxxll)
INPUT:n(9,1,100),m1(3,2,40),m2(3,2,40);
RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
K:=SMA(RSV,M1,1);
D:=SMA(K,M2,1);
a:=CROSS(k,d);
b:=CROSS(d,k);
x:=BARSLAST(a);
y:=BARSLAST(b);
ya:=sysparam(1);
yb:=barssince(c)+1;
金叉前低:if(x=0,ref(low,1),0),LINETHICK0 ;
金叉后低:if(ref(y,1)>ref(x,1) and y<>0,ref(low,x),0),LINETHICK0;
死叉前高:if(y=0,ref(high,1),0) LINETHICK0;
死叉后高:if(ref(x,1)>ref(y,1) and x<>0,ref(high,y),0),LINETHICK0;
DRAWSL(x=0 and ya=yb,ref(low,1),0,0,0);
DRAWSL(y>x and x>0 and ya=yb,ref(low,x),0,x,1);
DRAWSL(y=0 and ya=yb,ref(high,1),0,0,0);
DRAWSL(x>y and y>0 and ya=yb,ref(high,y),0,y,1);
QUOTE:
963.问:
每週或每月交易日的第一天或最後一天
答(peter109)
第一天的位置找到了
TM:month<>ref(month,1),linethick0;
mp:ref(barpos,Barslast(TM)),linethick0;
mp1:IF(MP>ref(MP,1),1,-1),linethick1;
答(bajatje):
这样？
barslast(month<>ref(month,1))=0;
barslast(weekday<ref(weekday,1))=0;
QUOTE:
964.问:
K线阳吞阴公式如何写?
答(peter109):
參考看看
ISUP AND L<ref(L,1) AND H>ref(H,1)
QUOTE:
965.问:
如果是现价大于昨天阴线的开盘价应该如何改动?
答(peter109):
C>ref(O,1) AND ref(C,1)<ref(O,1);
QUOTE:
966.问:
求江恩下降线和江恩上升线— 一帆风顺源码
答(goldhill1965):
江恩下降线
VAR1:=peak(1,10,1);
VAR2:=peakBARS(1,10,1);
var3:=(hhv(h,0)-llv(l,0))/barscount(c);
m0:var1-(var2-1)*0.00000001;
ma010:VAR1-(VAR2-1)*var3;
ma01:VAR1-(VAR2-1)*2*var3;
m1:VAR1-(VAR2-1)*4*var3;
m2:VAR1-(VAR2-1)*6*var3;
m3:VAR1-(VAR2-1)*8*var3,colorwhite;
m4:VAR1-(VAR2-1)*10*var3,colorwhite;
m5:VAR1-(VAR2-1)*12*var3,coloryellow;
m6:VAR1-(VAR2-1)*16*var3,colorff00ff;
江恩上升线源码—— 一帆风顺
VAR1:=trough(2,15,1);
VAR2:=troughBARS(2,15,1);
var3:=(hhv(h,0)-llv(l,0))/barscount(c);
m0:var1+(var2-1)*0.000000001;
ma010:VAR1+(VAR2-1)*var3;
ma01:VAR1+(VAR2-1)*2*var3;
m1:VAR1+(VAR2-1)*4*var3;
m2:VAR1+(VAR2-1)*6*var3;
m3:VAR1+(VAR2-1)*8*var3;
m4:VAR1+(VAR2-1)*10*var3,color00ff00;
m5:VAR1+(VAR2-1)*12*var3,coloryellow;
m6:VAR1+(VAR2-1)*14*var3,colorff00ff;
m7:VAR1+(VAR2-1)*16*var3,colorff00ff;
m8:VAR1+(VAR2-1)*18*var3,colorff00ff;
m9:VAR1+(VAR2-1)*22*var3,colorff00ff;
QUOTE:
967.问:
本周一、二、三、四、五 与上周五的涨幅公式怎么写
答(cwy):
(c/ref(c,WEEKDAY)-1)*100;
QUOTE:
968.问:
请问,该语句怎么描述
tj1:m1大于m2持续成立的周期数大于5
tj:上一次tj1成立到当前(计算日)的周期数小于5
答(bajatje):
tj1:=all(m1>m2,6);
tj:barslast(tj1)<5;
QUOTE:
969.问:
将成交量累积曲线变换成一种摆动指数，把成交量累积线的3天和10天移动平均线的数值之差描绘在零线的上下。
具体描述请看墨非的《期货市场技术分析》第291页图
答(bajatje):
这样？
LC:=REF(CLOSE,1);
vr:=SUM(IF(CLOSE>LC,VOL,0),N)/
SUM(IF(CLOSE<=LC,VOL,0),N)*100;
s3:=sma(vr,3,1);
s10:=sma(vr,10,1);
s3-s10,COLORSTICK;
0;
QUOTE:
970.问:
求今日X是在n日内第m次金叉Y的公式.
答(股市骑兵00):
sum(金叉,n)=m;
或
n=60;
M5:=MA(C,5);
M10:=MA(c,10);
M510:=cross(M5,M10);
am:sum(m510,n)=2 and M510;
QUOTE:
971.问:
有个问题请帮忙:如图:用下面公式能提出,但社保组合太多,其他组和就不行了能否找个其他办法,只要是社保就能识别.请帮忙解决.
1.社保持股和咋写。
2.供有几几家社保。
GD:=F10FIND('六、基金持股',0);
BS1:=F10FIND('社保103',GD)+10;
BS2:=F10FIND('社保102',GD)+10;
BS3:=F10FIND('社保101',GD)+10;
A:=F10FIND('合计│',GD);
STRTONUM(F10TEXT(if(bs1<a,bs1,0),0))
+STRTONUM(F10TEXT(if(bs2<a,bs2,0),0))
+STRTONUM(F10TEXT(if(bs3<a,bs3,0),0));
答(xxllxxll):
GD:=F10FIND('基金持股',0);
BS1:=F10FIND('社保',GD)+10;
BS2:=F10FIND('社保',bs1)+10;
BS3:=F10FIND('社保',bs2)+10;
A:=F10FIND('合计',GD);
社保1持股:STRTONUM(F10TEXT(if(bs1<a and bs1>gd,bs1,0),0)) LINETHICK0;
社保2持股:STRTONUM(F10TEXT(if(bs2<a and bs2>gd,bs2,0),0)) LINETHICK0;
社保3持股:STRTONUM(F10TEXT(if(bs3<a and bs3>gd,bs3,0),0)) LINETHICK0;
社保持股合计:社保1持股+社保2持股+社保3持股 LINETHICK0;//你要显示图形只需把LINETHICK0 去掉
这个公式要求资料库1里相应部分有‘基金持股'，'社保'等字样
若你的资料库1是别的，则需修改公式里的”基金持股“，”社保“等使之相同
不过看你图示的资料库1可能可以
这个公式能否正常与资料库1的f10有关，
《维赛特财经》和 ◇鹏搏资讯F10资料◇ 可以，
◇港澳资讯财经信息◇不行。
具体用到哪个f10就要根据该f10的情况修改
主要是段标志 '基金持股' 和段内标志 '社保'
QUOTE:
972.问:
怎样计算满足制定条件之间的天数，比如：2004年8月25日，k<5, 然后k一直小于5，在直到 返回到k>=5时之间的天数；
答(bajatje):
barslast(k>=5)+1
CODE:[Copy to clipboard]973.问:
当日收盘价在上市第一天最高及最低价之间公式怎么写？
答(bajatje):
c>ref(L,barscount(c)-1) and c<ref(h,barscount(c));
答(hx817):
这样也可以
fh:=h;
fl:=l;
between(c,fh[1],fl[1]);
QUOTE:
974.问:
日振幅大于7%，换手率大于3%该怎么写？。
第二个就是MACD指标选股：
DIFF和DEA在零轴上粘合、金叉。
答(bajatje):
1.
(h-L)/ref(c,1)>1.07 and v/capital>0.03
2.
m:="macd.macd";
d:="macd.dea";
aLL(m>0 and m<0.03 and d>0,3);
QUOTE:
975.问:
如 KD的K
1:下20反轉往上才買, 要在50以上反轉往下才賣.
1:上80反轉往下才賣, 要在50以下反轉往上才買.
答(peter109):
B1:ref("KDJ.K",1)<20 AND ref("KDJ.K",1)<ref("KDJ.K",2) AND "KDJ.K">ref("KDJ.K",1);
S1:ref("KDJ.K",1)>50 AND ref("KDJ.K",1)>ref("KDJ.K",2) AND "KDJ.K"<ref("KDJ.K",1);
B2:ref("KDJ.K",1)<50 AND ref("KDJ.K",1)<ref("KDJ.K",2) AND "KDJ.K">ref("KDJ.K",1);
S2:ref("KDJ.K",1)>80 AND ref("KDJ.K",1)>ref("KDJ.K",2) AND "KDJ.K"<ref("KDJ.K",1);
QUOTE:
976.问:
求13日中最大量(A點)成立後的最大量(B點)兩點畫線
答(股市骑兵00):
h1:=hhvbars(v,13);h2:=hhvbars(v,h1);
p1:=BACKSET(ISLASTBAR,h1+1);
p2:=BACKSET(ISLASTBAR,h2+1);
DRAWLINE(p1>ref(p1,1),v,p2>ref(p2,1),v,1);
v,VOLSTICK;
CODE:[Copy to clipboard]977.问:
N週期中, 有重複數據,應該如何修改
//今日與昨日數據完全相同
Y:O=ref(O,1) AND H=ref(H,1) AND L=ref(L,1) AND C=ref(C,1),linethick0;
vertline(Y=1);
//N週期中, 有重複數據
N:=60;
Y1:ANY(O=ref(O,n) AND H=ref(H,n) AND L=ref(L,n) AND C=ref(C,n),N),linethick0;
vertline(Y1=1);
答(bajatje):
//今日與昨日數據完全相同
Y:O=ref(O,1) AND H=ref(H,1) AND L=ref(L,1) AND C=ref(C,1) and v=ref(v,1) and amount=ref(amount,1);//重复数据信号。仅是K线完全相同还不足以证明数据重复，还要成交量和成交额也相同才能完全证明。
count(y,N);//N个周期中的重复数据数量
问:
看看 N週期的公式部分嗎
咱這有重複數據 (相差32天 姑且不論您說的量和額)
可是咱的公式卻無法標示出
所以 咱認為 該部分的公式有問題
答(xxllxxll):
x1:=0*c;x2:=x1;
Fc:=c; fh:=h;
fl:=l; fo:=o;
pc:=c;
q:=SORTPOS(pc,0,1,DATACOUNT);
for i=2 to datacount do
if fc[pc[i-1]]=fc[pc] then
begin
if fo[pc[i-1]]=fo[pc] then
begin
if fl[pc[i-1]]=fl[pc] then
begin
if fh[pc[i-1]]=fh[pc] then
begin
x1:=pc;
x2:=pc[i-1];
end;
end;
end;
end;
相等甲数位置:x1;
相等乙数位置:x2;
位置指针:BARSSINCE(c)+1 LINETHICK0;
(xxllxxll注:一般甲乙两数都是0，有相同k线时，图上有一脉冲，把光标移到
脉冲上,甲乙两数都有数值，这便是两个相等k线的位置，用光标分别按 ‘位置指针’
的指示查看即可。)
QUOTE:
978.问:
本次J转折值大于上一J转折值并且上一J转折值等于20日最低值。
答(清扬):
供参考：
A:"KDJ.J";
B:=A<REF(A,1) AND A<REFX(A,1);
D:=B AND A=LLV(A,20);
E:=REF(BARSLAST(B),1)+1;
F:=B AND A>REF(A,E) AND REF(D,E);
CON:REF(F,1);
QUOTE:
979.问:
连续三天最低点抬高指示
答(peter109):
ALL(L>ref(L,1),3)
QUOTE:
980.问:
如何写日均线第二次(15天内)上穿10日均线?
答(peter109):
A:=cross(MA(C,5),MA(C,10));
count(A,15)=2;
QUOTE:
981.问:
看到价量时空里移动的江恩角度线，看到黄金分割上下的移动线，
我想能否把二者结合制作成江恩箱
答(yhcheng):
用公式画江恩箱在飞狐是有瓶颈的,若是固定的箱宽, 画到过去或没有K棒的未来都可以,
但是要画到没有K棒的未来,只能在255K棒内,听一位高人说过正确的江恩箱是建立在前波
高低规画出最佳的箱高低,然后依据最佳的波动率系数转换出箱宽,所以箱宽不固定,而飞
狐的shift函数最多可右移255K棒到右边去且参数固定,这就是瓶颈所在,若不必显示每一
条角度线或水平线的值,可直接使用飞狐的画线函数,在过去模拟运算出全部箱子后,用shift
函数映射至光标的位置,与光标同步移动不受255的限制,但垂直分割线仍会受255的限制,
所以这做法只限于固定箱宽及箱宽在255以内,因为大部分参考价值是画在未来,若要制做不固
定宽度的箱子,建议在搭配箱子的公式里直接算出箱宽,高,低值后,用工具箱随便画出再修改参数
QUOTE:
982.问:
能不能帮我编个无未来数据的月MA指标？
答(股市骑兵00):
INPUT:N(5);
x:=INTPART(date/100)<>ref(INTPART(date/100),1);
z:=refx(x,1);zq1:=sumbars(z,n-1); zq2:=sumbars(z,n);
均线:if(z,sum(z*c,zq2)/n,(sum(z*c,zq1)+c)/n);
答(joneslee):
XX:=datediff(ref(date,1),date)<>DAY-ref(DAY,1);
ZX:=refx(XX,1);
月30:=if(ZX,sum(ZX*c,sumbars(ZX,p11))/p11,(sum(ZX*c,sumbars(ZX,p11-1))+c)/p11),color00EEFF;
QUOTE:
983.问:
江恩角度线比原版提前7天显示行吗 fxj
答(goldhill1965):
在分析家里，角度线可以延伸到未来,参数：190001 1400 1700 17
把原B1=10改为b1＝3，所以会提前7天显示。
s:=llv(c,500); m3:ma(c,3); m10:ma(c,10); m30:ma(c,30);
AA:=YEAR*100+MONTH>年月; BB:=(AA=0)+1;
p1:=(c-ref(c,1))/ref(c,1)*1000; p2:=sum(abs(p1),0); p3:=count(c>0,0); k1:=p2/p3;
a1:=ZIG(3 , n2); aa1:=a1>ref(a1,1); a2:=ZIG(2,n2); aa2:=a2<ref(a2,1); K2:=K1*0.8;
b1:=HHVBARS( a1, 30); b2:=LLVBARS(a2 ,30);
X1:DRAWLINE(c=A1*BB and aa1>0,c,B1=3 ,REF(c,B1)-s*K1/下降角度,1),COLOR33FFCC;
X2:DRAWLINE(c=A1*BB and aa1>0,c,B1=3 ,REF(c,B1)-s*2*K1/下降角度,1),COLOR6666FF,LINETHICK2;
X3:DRAWLINE(c=A1*BB and aa1>0,c,B1=3 ,REF(c,B1)-s*4*K1/下降角度,1),COLORFFFFCC;
X4:DRAWLINE(c=A1*BB and aa1>0,c,B1=3 ,REF(c,B1)-s*8*K1/下降角度,1),COLOR00CCFF;
X5:DRAWLINE(c=A1*BB and aa1>0,c,B1=3 ,REF(c,B1)-s*0.5*K1/下降角度,1),COLORgreen;
Y1:DRAWLINE(l=A2*AA and aa2>0,L,B2=3 ,REF(l,B2)+s*8*K1/上升角度*2,1),COLOR33FFCC;
Y2:DRAWLINE(l=A2*AA and aa2>0,L,B2=3 ,REF(l,B2)+s*K1/上升角度*2,1),COLOR00CCFF;
Y3:DRAWLINE(l=A2*AA and aa2>0,L,B2=3 ,REF(l,B2)+s*2*K1/上升角度*2,1),COLOR6666FF,LINETHICK2;
Y4:DRAWLINE(l=A2*AA and aa2>0,l,B2=3 ,REF(l,b2)+s*4*K1/上升角度*2,1),COLORFFFFCC;
Y5:DRAWLINE(l=A2*AA and aa2>0,l,B2=3 ,REF(l,b2)+s*0.5*K1/上升角度*2,1),COLORgreen;
ma3:ma(close,3);
QUOTE:
984.问:
请帮写一公式:如公式和图:
以式中zq1=0为起点(起点往左zq1天)写一前zq1天换手公式.
b:=ma(c,20);
jc:=b>ref(b,2) and b<ref(b,1);
zq1:BARSLAST(jc=1);
0;
答(peter109):
N:=10;//參數 自行調整
b:=ma(c,20);
jc:=b>ref(b,2) and b<ref(b,1);
zq1:=BARSLAST(jc=1)+1;
//vertline(zq1=1);
HSL:=(V/capital)*100;
y:=sysparam(3)-zq1-n+1;
sxHSL:=SUM(HSL,zq1);
syHSL:=SUM(HSL,y);
sHSL:=SUM(HSL,0);
nHSL:sHSL-sxHSL-syHSL,precision4;
答(xxllxxll):
a:=ma(c,20);
b:=ref(a,1)>a and refx(a,1)>a;
n:=BARSLAST(b);
m:=if(n=0,ref(n,1),n);
右侧换手率:sum(v,m)/CAPITAL*100 ;
左侧换手率:(sum(v,2*m)-sum(v,m))/CAPITAL*100;
换手天数:n LINETHICK0;
0;
QUOTE:
985.问:
图中柱状线的位置应画在QA的最后一天,现在是在起始一天.请把柱线往左移1天.公式:
b:=MA(C,10)>MA(C,30);
QA:BARSLAST(b);
tj:=QA=0 AND REF(QA,1)>0;
x:REF(QA,1)>ref(qa,sumbars(tj,2)),LINETHICK0;;
STICKLINE(tj and x=0,REF(QA,1),0,1,0),COLORGREEN,LINETHICK4;
STICKLINE(tj and x,REF(QA,1),0,1,0),COLORMAGENTA,LINETHICK4;
答(xxllxxll):
b:=MA(C,10)>MA(C,30);
QA:BARSLAST(b);
tj:=QA=0 AND REF(QA,1)>0;
x:REF(QA,1)>ref(qa,sumbars(tj,2)),LINETHICK0;;
STICKLINE(refx(tj and x=0,1),QA,0,1,0),COLORGREEN,LINETHICK4;
STICKLINE(refx(tj and x,1),QA,0,1,0),COLORMAGENTA,LINETHICK4;
QUOTE:
986.问:
如何使半年线在满足条件时才显示出来
答(peter109):
A:=MA(C,125);
B:=c>A*0.8;
partline(B,A);
QUOTE:
987.问:
谁有这样的公式,连收三阳,且K线的实体阳线一根比一根长
答(hx817):
zf:=(c-o)/o;
tj:all(zf>ref(zf,1),3) and all(isup,3);
QUOTE:
988.问:
股价的波峰的位置确定了，求对应的k值，再将临近的两个k值作比较
答(bajatje):
w1:=PEAKBARS(4,n,1);//波峰B位置
w2:=PEAKBARS(4,n,2);//波峰A位置
k:="kd.k";
Ak:ref(k,w1);
Bk:ref(k,w2);
Ak-Bk;
QUOTE:
989.问:
怎样计算出高点连线的值
这是 rsi 里的高点连线指标，只有画线，而他的数值怎样计算出来，请高手用公式表示，万分感谢！
input:n1(6,1,100),n2(12,1,100),n3(24,1,100),n(10,1,100),m1(10,1,100),m2(8,1,100);
LC := REF(CLOSE,1);
RSI1:SMA(MAX(CLOSE-LC,0),N1,1)/SMA(ABS(CLOSE-LC),N1,1)*100,color00ff00;
RSI2:SMA(MAX(CLOSE-LC,0),N2,1)/SMA(ABS(CLOSE-LC),N2,1)*100,coloryellow;
RSI3:SMA(MAX(CLOSE-LC,0),N3,1)/SMA(ABS(CLOSE-LC),N3,1)*100,colorff00ff;
//北京阳光飞狐 恒悦制作http://www./Discuz/index.php
gz1:=PEAKBARSA(rsi1,n,m1);
gg1:=BACKSET(ISLASTBAR,gz1+1);
gz2:=PEAKBARSA(rsi1,n,m2);
gg2:=BACKSET(ISLASTBAR,gz2+1);
dz1:=TROUGHBARSA(rsi1,n,m1);
dg1:=BACKSET(ISLASTBAR,dz1+1);
dz2:=TROUGHBARSA(rsi1,n,m2);
dg2:=BACKSET(ISLASTBAR,dz2+1);
高点连线dRAWLINE(gg1<>ref(gg1,1),rsi1,gg2<>ref(gg2,1),rsi1,1),colorgreen,linethick2;
DRAWLINE(dg1<>ref(dg1,1),rsi1,dg2<>ref(dg2,1),rsi1,1),color5252ff,linethick2;
答(bajatje):
input:n1(6,1,100),n2(12,1,100),n3(24,1,100),n(10,1,100),m1(10,1,100),m2(8,1,100);
LC := REF(CLOSE,1);
RSI1:SMA(MAX(CLOSE-LC,0),N1,1)/SMA(ABS(CLOSE-LC),N1,1)*100,color00ff00;
RSI2:SMA(MAX(CLOSE-LC,0),N2,1)/SMA(ABS(CLOSE-LC),N2,1)*100,coloryellow;
RSI3:SMA(MAX(CLOSE-LC,0),N3,1)/SMA(ABS(CLOSE-LC),N3,1)*100,colorff00ff;
//北京阳光飞狐 恒悦制作http://www./Discuz/index.php
gz1:=PEAKBARSA(rsi1,n,m1);
gg1:=BACKSET(ISLASTBAR,gz1+1);
gz2:=PEAKBARSA(rsi1,n,m2);
gg2:=BACKSET(ISLASTBAR,gz2+1);
dz1:=TROUGHBARSA(rsi1,n,m1);
dg1:=BACKSET(ISLASTBAR,dz1+1);
dz2:=TROUGHBARSA(rsi1,n,m2);
dg2:=BACKSET(ISLASTBAR,dz2+1);
高点连线:LINEVALUE(gg1<>ref(gg1,1),rsi1,gg2<>ref(gg2,1),rsi1,0,0),colorgreen,linethick2;
LINEVALUE(dg1<>ref(dg1,1),rsi1,dg2<>ref(dg2,1),rsi1,0,0),color5252ff,linethick2;
QUOTE:
990.问:
怎样做到在光标移动时，显示五日涨幅。
答(cwy):
zf:=(c/ref(c,4)-1)*100;
s:='五日涨幅:'+' \n '+NUMTOSTR(zf[SYSPARAM(1)],2);
DRAWTEXT(BARPOS=SYSPARAM(1),h,s) ALIGN4;
QUOTE:
991.问:
如涨停过年线，或大阳过年线，（包括ST）。
答(cwy):
a:=ROUND((c/ref(c,1)-1)*100)>=5;
a and c>ma(c,250) and ref(l,1)<ma(c,250);
QUOTE:
992.问:
要求是飞狐公式：
１自由画矩行
２在矩行框中能自由调整等分线（横线和纵线都能自由等分调整）
答(xxllxxll):
INPUT:n(30,1,100),n1(500,0,9999),n2(1.3,0,100),n3(0.1,0,100);
a:=BARSCOUNT(c);
DRAWLINE(a=n1-2*n,refx(c*n2,2*n),a=n1+2*n,ref(c*n2,2*n),0) COLORYELLOW;
DRAWLINE(a=n1-2*n,refx(c*(n2-2*n3),2*n),a=n1+2*n,ref(c*(n2-2*n3),2*n),0) COLORYELLOW;
DRAWLINE(a=n1-2*n,refx(c*(n2-n3),2*n),a=n1+2*n,ref(c*(n2-n3),2*n),0) COLORYELLOW;
DRAWLINE(a=n1-2*n,refx(c*(n2+n3),2*n),a=n1+2*n,ref(c*(n2+n3),2*n),0) COLORYELLOW;
DRAWLINE(a=n1-2*n,refx(c*(n2+2*n3),2*n),a=n1+2*n,ref(c*(n2+2*n3),2*n),0) COLORYELLOW;
STICKLINE(a=n1,c*(n2+2*n3),c*(n2-2*n3),0.8,1) COLORYELLOW;
STICKLINE(a=n1-n,refx(c,n)*(n2+2*n3),refx(c,n)*(n2-2*n3),0.8,1) COLORYELLOW;
STICKLINE(a=n1-2*n,refx(c,2*n)*(n2+2*n3),refx(c,2*n)*(n2-2*n3),0.8,1) COLORYELLOW;
STICKLINE(a=n1+n,ref(c,n)*(n2+2*n3),ref(c,n)*(n2-2*n3),0.8,1) COLORYELLOW;
STICKLINE(a=n1+2*n,ref(c,2*n)*(n2+2*n3),ref(c,2*n)*(n2-2*n3),0.8,1) COLORYELLOW;
DRAWICON(a=n1,c*n2,10);
QUOTE:
993.问:
如何能夠快速的決定中心點(價/K線)位置
答(xxllxxll):
INPUT:n(30,1,100),n1(500,0,9999),n2(1.3,0,100),n3(0.1,0,100),m(5,0,100);
a:=BARSCOUNT(c) ;
DRAWLINE(a=n1-2*n,refx(c*n2,2*n),a=n1+2*n,ref(c*n2,2*n),0) COLORYELLOW;
DRAWLINE(a=n1-2*n,refx(c*(n2-2*n3),2*n),a=n1+2*n,ref(c*(n2-2*n3),2*n),0) COLORYELLOW;
DRAWLINE(a=n1-2*n,refx(c*(n2-n3),2*n),a=n1+2*n,ref(c*(n2-n3),2*n),0) COLORYELLOW;
DRAWLINE(a=n1-2*n,refx(c*(n2+n3),2*n),a=n1+2*n,ref(c*(n2+n3),2*n),0) COLORYELLOW;
DRAWLINE(a=n1-2*n,refx(c*(n2+2*n3),2*n),a=n1+2*n,ref(c*(n2+2*n3),2*n),0) COLORYELLOW;
STICKLINE(a=n1,c*(n2+2*n3),c*(n2-2*n3),0.8,1) COLORYELLOW;
STICKLINE(a=n1-n,refx(c,n)*(n2+2*n3),refx(c,n)*(n2-2*n3),0.8,1) COLORYELLOW;
STICKLINE(a=n1-2*n,refx(c,2*n)*(n2+2*n3),refx(c,2*n)*(n2-2*n3),0.8,1) COLORYELLOW;
STICKLINE(a=n1+n,ref(c,n)*(n2+2*n3),ref(c,n)*(n2-2*n3),0.8,1) COLORYELLOW;
STICKLINE(a=n1+2*n,ref(c,2*n)*(n2+2*n3),ref(c,2*n)*(n2-2*n3),0.8,1) COLORYELLOW;
DRAWICON(a=n1,c*n2,10);
X轴指针:a LINETHICK0;
Y轴指针:m/c LINETHICK0;
将光标移到盘面上任意你要定位的位置，读x轴指针值，填在n1参数框
内，
y轴定位麻烦一些，要先把你原点的高度，即盘面原点的价位填入m参数
框内，确认后将光标移到x轴指针值处，读y轴指针值，填入n2参数框内
即可
如果只用参数定位，也可以试试这个，此时m就是y轴原点
INPUT:n(30,1,100),n1(500,0,9999),n3(0.3,0,100),m(5,0,100);
a:=BARSCOUNT(c) ;
DRAWLINE(a=n1-2*n,m,a=n1+2*n,m,0) COLORYELLOW;
DRAWLINE(a=n1-2*n,m-2*n3,a=n1+2*n,m-2*n3,0) COLORYELLOW;
DRAWLINE(a=n1-2*n,m-n3,a=n1+2*n,m-n3,0) COLORYELLOW;
DRAWLINE(a=n1-2*n,m+n3,a=n1+2*n,m+n3,0) COLORYELLOW;
DRAWLINE(a=n1-2*n,m+2*n3,a=n1+2*n,m+2*n3,0) COLORYELLOW;
STICKLINE(a=n1,m+2*n3,m-2*n3,0.8,1) COLORYELLOW;
STICKLINE(a=n1-n,m+2*n3,m-2*n3,0.8,1) COLORYELLOW;
STICKLINE(a=n1-2*n,m+2*n3,m-2*n3,0.8,1) COLORYELLOW;
STICKLINE(a=n1+n,m+2*n3,m-2*n3,0.8,1) COLORYELLOW;
STICKLINE(a=n1+2*n,m+2*n3,m-2*n3,0.8,1) COLORYELLOW;
DRAWICON(a=n1,m,10);
X轴指针:a LINETHICK0;
Y轴指针:m LINETHICK0;
答(peter109):
採用中心點定位,根據該公式完成了自己想要的 自由矩形+自由調整等分線+江恩重要角度線
//自由畫矩行並可在矩行框中能自由調整等分線
//無論向上或向下起點開始後須有8根k線以上才會畫出
//N,N4為K線縱向間隔 N1為低點K線位置 N3為為高點K線位置
//N2 為百分比
//將光標移到盤面上任意你要定位的位置(最高/低價)，讀光標所在位置的值，填在n3/n1參數框內，
INPUT:n1(1724,30,99999),n2(0.03,0,100),n3(1786,0,99999);
a:=BARSCOUNT(c);
x:=sysparam(3)-N1+1;
N:IF(X<8,0,IF(X>40,10,round(x/5))),linethick0;//K線數 預設是10
AA:=ref(L,barslast(a=n1){縱最左}),linethick0;//定位點 L可變更為其他
//以下為橫線Y軸
DRAWLINE(a=n1{縱最左},AA,a=n1+4*n,AA,0),ColorBBFFDD;//橫最下1
DRAWLINE(a=n1,AA*(1+n2),a=n1+4*n,AA*(1+n2),0),ColorBBFFDD;//橫中下1.1
DRAWLINE(a=n1,AA*(1+2*n2),a=n1+4*n,AA*(1+2*n2),0),ColorBBFFDD;//橫中1.2
DRAWLINE(a=n1,AA*(1+3*N2),a=n1+4*n,AA*(1+3*N2),0),ColorBBFFDD;//橫中上1.3
DRAWLINE(a=n1,AA*(1+4*N2),a=n1+4*n,AA*(1+4*N2),0),ColorBBFFDD;//橫最上1.4
//以下為縱線X軸
STICKLINE(a=n1,AA,AA*(1+4*N2),0.8,1),ColorBBFFDD;//縱最左
STICKLINE(a=n1+n,AA,AA*(1+4*N2),0.8,1),ColorBBFFDD;//縱中左
STICKLINE(a=n1+2*n,AA,AA*(1+4*N2),0.8,1),colorRED;//縱中
STICKLINE(a=n1+3*n,AA,AA*(1+4*N2),0.8,1),ColorBBFFDD;//縱中右
STICKLINE(a=n1+4*n,AA,AA*(1+4*N2),0.8,1),ColorBBFFDD;//縱最右
x1125:linevalue(a=n1,AA,a=n1+intpart(0.125*(4*N)),AA*(1+4*N2),0,0),colorYELLOW;//0.125位置
x133:linevalue(a=n1,AA,a=n1+intpart(0.33*(4*N)),AA*(1+4*N2),0,0),colorYELLOW;//0.33位置
x1618:linevalue(a=n1,AA,a=n1+intpart(0.382*(4*N)),AA*(1+4*N2),0,0),colorYELLOW;//0.382位置取整 會有些許誤差
x1382:linevalue(a=n1,AA,a=n1+intpart(0.618*(4*N)),AA*(1+4*N2),0,0),colorYELLOW;//0.618位置取整 會有些許誤差
x13:linevalue(a=n1{縱最左},AA,a=n1+n,AA*(1+4*N2),0,0),colorBLUE;
x12:linevalue(a=n1,AA,a=n1+2*n,AA*(1+4*N2),0,0),colorBLUE;
x11:linevalue(a=n1,AA,a=n1+3*n,AA*(1+4*N2),0,0),colorBLUE;//大於45度
x1:linevalue(a=n1,AA,a=n1+4*n,AA*(1+4*N2),0,0),colorGREEN;//45度
x21:linevalue(a=n1,AA,a=n1+4*n,AA*(1+3*N2),0,0),colorBLUE;//小於45度
x22:linevalue(a=n1,AA,a=n1+4*n,AA*(1+2*N2),0,0),colorBLUE;
x23:linevalue(a=n1,AA,a=n1+4*n,AA*(1+N2),0,0),colorBLUE;
x2125:linevalue(a=n1,AA,a=n1+4*n,AA*(1+0.125*(4*N2)),0,0),colorYELLOW;//0.125位置
x2375:linevalue(a=n1,AA,a=n1+4*n,AA/(1-0.0375),0,0),colorYELLOW;//0.375位置
x2618:linevalue(a=n1,AA,a=n1+4*n,AA*(1+0.618*(4*N2)),0,0),colorYELLOW;//0.382位置
x2382:linevalue(a=n1,AA,a=n1+4*n,AA*(1+0.382*(4*N2)),0,0),colorYELLOW;//0.618位置
//以上為向上
//以下為向下
y:=sysparam(3)-N3+1;
N4:IF(y<8,0,IF(y>40,10,round(y/5))),linethick0;//K線數 預設是10
BB:ref(H,barslast(a=n3){縱最左}),linethick0;//定位點 最高價
DRAWLINE(a=n3{縱最右},BB,a=n3+4*n4,BB,0),colorMAGENTA;//橫最上
DRAWLINE(a=n3,BB*(1-n2),a=n3+4*n4,BB*(1-n2),0),colorMAGENTA;//橫中上
DRAWLINE(a=n3,BB*(1-2*n2),a=n3+4*n4,BB*(1-2*n2),0),colorMAGENTA;//橫中
DRAWLINE(a=n3,BB*(1-3*N2),a=n3+4*n4,BB*(1-3*N2),0),colorMAGENTA;//橫中下
DRAWLINE(a=n3,BB*(1-4*N2),a=n3+4*n4,BB*(1-4*N2),0),colorMAGENTA;//橫最下
//以下為縱線X軸
STICKLINE(a=n3,BB,BB*(1-4*N2),0.8,1),colorMAGENTA;//縱最右
STICKLINE(a=n3+n4,BB,BB*(1-4*N2),0.8,1),colorMAGENTA;//縱中右
STICKLINE(a=n3+2*n4,BB,BB*(1-4*N2),0.8,1),colorRED;//縱中
STICKLINE(a=n3+3*n4,BB,BB*(1-4*N2),0.8,1),colorMAGENTA;//縱中左
STICKLINE(a=n3+4*n4,BB,BB*(1-4*N2),0.8,1),colorMAGENTA;//縱最左
y1125:linevalue(a=n3,BB,a=n3+intpart(0.125*(4*N4)),BB*(1-4*N2),0,0),colorYELLOW;//0.125位置
y133:linevalue(a=n3,BB,a=n3+intpart(0.33*(4*N4)),BB*(1-4*N2),0,0),colorYELLOW;//0.33位置
y1382:linevalue(a=n3,BB,a=n3+intpart(0.382*(4*N4)),BB*(1-4*N2),0,0),colorYELLOW;//0.382位置
y1618:linevalue(a=n3,BB,a=n3+intpart(0.618*(4*N4)),BB*(1-4*N2),0,0),colorYELLOW;//0.618位置
y13:linevalue(a=n3{縱最左},BB,a=n3+n4,BB*(1-4*N2),0,0),Color56AAFF;
y12:linevalue(a=n3,BB,a=n3+2*n4,BB*(1-4*N2),0,0),Color56AAFF;
y11:linevalue(a=n3,BB,a=n3+3*n4,BB*(1-4*N2),0,0),Color56AAFF;//中心線下面
y1:linevalue(a=n3,BB,a=n3+4*n4,BB*(1-4*N2),0,0),colorGREEN;//中心線
y21:linevalue(a=n3,BB,a=n3+4*n4,BB*(1-3*N2),0,0),Color56AAFF;//中心線上面
y22:linevalue(a=n3,BB,a=n3+4*n4,BB*(1-2*N2),0,0),Color56AAFF;
y23:linevalue(a=n3,BB,a=n3+4*n4,BB*(1-N2),0,0),Color56AAFF;
y2125:linevalue(a=n3,BB,a=n3+4*n,BB*(1-0.125*(4*N2)),0,0),colorYELLOW;//0.125位置
y233:linevalue(a=n3,BB,a=n3+4*n,BB*(1-0.333*(4*N2)),0,0),colorYELLOW;//0.33位置
y2618:linevalue(a=n3,BB,a=n3+4*n,BB*(1-0.618*(4*N2)),0,0),colorYELLOW;//0.382位置
y2382:linevalue(a=n3,BB,a=n3+4*n,BB*(1-0.382*(4*N2)),0,0),colorYELLOW;//0.618位置
CODE:[Copy to clipboard]994.问:
由於畫出的線條太多 想要有目前CLOSE的確實位置
因此試著進行下列排序後直接在圖上標出數字公式
失敗了 難道只有用解盤文字才可以達到目的嗎
//排序 騎大解盤方式
收盤:=C;
gb:=SYSPARAM(1);
p[1]:=收盤[gb];p[2]:=x1[gb];
p[3]:=x11[gb];p[4]:=x12[gb];
p[5]:=x13[gb];p[6]:=x1382[gb];
p[7]:=x1618[gb];p[8]:=x21[gb];
p[9]:=x22[gb];p[10]:=x23[gb];
s[1]:=收盤[gb];s[2]:=x1[gb];
s[3]:=x11[gb];s[4]:=x12[gb];
s[5]:=x13[gb];s[6]:=x1382[gb];
s[7]:=x1618[gb];s[8]:=x21[gb];
s[9]:=x22[gb];s[10]:=x23[gb];
VARIABLE:ptr[10]='';
//列出排序後想要的部分 目前僅針對向上部分內容排序
for i=1 to 10 do if ptr[p]='收盤' then break;//以 收盤 做解盤中心點
//以下為問題點
if i-1>0 then drawnumber(ISLASTBAR,s[p[i-1]],s[p[i-1]],0);//小數位數可修改 預設沒有小數位數
if i+1<11 then drawnumber(ISLASTBAR,s[p[i+1]],s[p[i+1]],0);
答(peter109):
drawnumber(islastbar AND (C>=x1125 OR (C<x1125 AND C>=x13)),x1125,x1125,0),colorRED;
drawnumber(islastbar AND ((C<x1125 AND C>=x13) OR (C<x13 AND C>=x133)),x13,x13,0),colorRED;
drawnumber(islastbar AND ((C<x13 AND C>=x133) OR (C<x133 AND C>=x1382)),x133,x133,0),colorRED;
drawnumber(islastbar AND ((C<x133 AND C>=x1382) OR (C<x1382 AND C>=x12)),x1382,x1382,0),colorRED;
drawnumber(islastbar AND ((C<x1382 AND C>=x12) OR (C<x12 AND C>=x1618)),x12,x12,0),colorRED;
drawnumber(islastbar AND ((C<x12 AND C>=x1618) OR (C<x1618 AND C>=x11)),x1618,x1618,0),colorRED;
drawnumber(islastbar AND ((C<x1618 AND C>=x11) OR (C<x11 AND C>=x1)),x11,x11,0),colorRED;
drawnumber(islastbar AND ((C<x11 AND C>=x1) OR (C<x1 AND C>=x21)),x1,x1,0),colorRED;
drawnumber(islastbar AND ((C<x1 AND C>=x21) OR (C<x21 AND C>=x2618)),x21,x21,0),colorRED;
drawnumber(islastbar AND ((C<x21 AND C>=x2618) AND (C<x2618 AND C>=x22)),x2618,x2618,0),colorRED;
drawnumber(islastbar AND ((C<x2618 AND C>=x22) OR (C<x22 AND C>=x2382)),x22,x22,0),colorRED;
drawnumber(islastbar AND ((C<x22 AND C>=x2382) OR (C<x2382 AND C>=x2375)),x2382,x2382,0),colorRED;
drawnumber(islastbar AND ((C<x2382 AND C>=x2375) OR (C<x2375 AND C>=x23)),x2375,x2375,0),colorRED;
drawnumber(islastbar AND ((C<x2375 AND C>=x23) OR (C<x23 AND C>=x2125)),x23,x23,0),colorRED;
drawnumber(islastbar AND ((C<x23 AND C>=x2125) OR C<x2125),x2125,x2125,0),colorRED;
drawnumber(islastbar AND (C<=y1125 OR (C>y1125 AND C<=y13)),y1125,y1125,0),colorWHITE;
drawnumber(islastbar AND ((C>y1125 AND C<=y13) OR (C>y13 AND C<=y133)),y13,y13,0),colorWHITE;
drawnumber(islastbar AND ((C>y13 AND C<=y133) OR (C>y133 AND C<=y1382)),y133,y133,0),colorWHITE;
drawnumber(islastbar AND ((C>y133 AND C<=y1382) OR (C>y1382 AND C<=y12)),y1382,y1382,0),colorWHITE;
drawnumber(islastbar AND ((C>y1382 AND C<=y12) OR (C>y12 AND C<=y1618)),y12,y12,0),colorWHITE;
drawnumber(islastbar AND ((C>y12 AND C<=y1618) OR (C>y1618 AND C<=y11)),y1618,y1618,0),colorWHITE;
drawnumber(islastbar AND ((C>y1618 AND C<=y11) OR (C>y11 AND C<=y1)),y11,y11,0),colorWHITE;
drawnumber(islastbar AND ((C>y11 AND C<=y1) OR (C>y1 AND C<=y21)),y1,y1,0),colorWHITE;
drawnumber(islastbar AND ((C>y1 AND C<=y21) OR (C>y21 AND C<=y2618)),y21,y21,0),colorWHITE;
drawnumber(islastbar AND ((C>y21 AND C<=y2618) OR (C>y2618 AND C<=y22)),y2618,y2618,0),colorWHITE;
drawnumber(islastbar AND ((C>y2618 AND C<=y22) OR (C>y22 AND C<=y2382)),y22,y22,0),colorWHITE;
drawnumber(islastbar AND ((C>y22 AND C<=y2382) OR (C>y2382 AND C<=y233)),y2382,y2382,0),colorWHITE;
drawnumber(islastbar AND ((C>y2382 AND C<=y233) OR (C>y233 AND C<=y23)),y233,y233,0),colorWHITE;
drawnumber(islastbar AND ((C>y233 AND C<=y23) OR (C>y23 AND C<=y2125)),y23,y23,0),colorWHITE;
drawnumber(islastbar AND ((C>y23 AND C<=y2125) OR C>=y2125),y2125,y2125,0),colorWHITE;
CODE:[Copy to clipboard]995.问:
以半年内最高点作移动平均线（即该移动平均线通过半年内最高点）
答(xxllxxll):
已知移动平均线通过半年内最高点，求该均线参数
a:=hhv(h,120);
b:=a[DATACOUNT];
jl:=HHVBARS(h,120);
nz:=SUMBARS(c-b,0);
n:=ref(nz,jl);
均线参数:n[DATACOUNT] LINETHICK0;
均线:ma(c,均线参数);
半年内高点:b LINETHICK0;
注：
1 可能有正负1的误差
2 有些股票无解
3 以上代码只能求最近120天的
问:
為何NZ這邊用C-B
答(xxllxxll):
’c-b'的用法是效仿南客老师的 'sumbars()的巧妙用法'
在本题中
均线过某一点是指均线在该处的值与该点的值相等
设该点值为H，另均线可表为（c1+c2+...+cn)/n
则 （c1+c2+...+cn)/n＝H
或 c1+c2+...+cn＝n*H
或 （c1-H)+(c2-H)+...+(cn-H)=0
这样，用sumbars()函数来对c1-H,c2-H,...等进行试加，直到>=0,
这时函数返回值便是N值
由于H是120天内最高值，所以一般不担心cn-H>=0
但有相等的可能，若c1=H，则此时会出错，
答(南客):
加入一行判断，可能显示效果稍好些：
if lbound(nz)=0 then exit; //加到nz变量定义之后
试试
fh:=high;
jl:=HHVBARS(h,120);
k:=0*c;
fc:=if(barpos=1,99999,c);
for i=lbound(jl) to datacount do tj[i-jl]:=1;//“半年内最高点”的位置
for i=datacount downto 120 do begin
if tj then begin
tmp:=0;
for j=i downto 1 do begin //以下循环，等价于sumbars()运算
tmp:=tmp+fc[j];
if tmp>=(i-j+1)*fh then break;
end;
k:=if(j=1,0,i-j+1); //计算到第1根K线的话，则视为无效，此处可另行斟酌
end;
end;
k; //均线参数
QUOTE:
996.问:
能在高低点处画一小段水平线吗？
答(股市骑兵00):
大概这样。
X:=FLATZIG(4,10);Y:=BARSLAST(X=1 OR X=0);
PARTLINE(Y,IF(REF(X,Y)=1,REF(H,Y),REF(L,Y)));
想画长点
//都画5跟K线长度，
X:=FLATZIG(4,10);Y:=BARSLAST(X=1 OR X=0);
PARTLINE(Y<5 AND Y>0,IF(REF(X,Y)=1,REF(H,Y),REF(L,Y)));
最后一个有效的拐点
X:=FLATZIG(4,10);Y:=BARSLAST(X=1 OR X=0 AND ISLASTBAR=0);
Z:=IF(REF(X,Y)=1,REF(H,Y),REF(L,Y));
PARTLINE(Y<5 AND Y>0,Z);
PARTLINE(BACKSET(ISLASTBAR,Y),Z);//画最后跟线
还可这样
X:=FLATZIG(4,10);Y:=BARSLAST((X=1 OR X=0) AND ISLASTBAR=0);
Z:=IF(REF(X,Y)=1,REF(H,Y),REF(L,Y));
PARTLINE(Y<5 AND Y>0,Z);
P:=BACKSET(ISLASTBAR,Y+1);
DRAWSL(P>REF(P,1),Z,0,0,0);
答(cwy):
试试
N是ZIG转向幅度,T是水平线长短。
INPUT:N(10,0,100),t(3,0,10);
a:ZIG(4,n);
X:=FLATZIG(4,n);
DRAWSL(X=0,a,0,t,0);
DRAWSL(X=1,a,0,t,0);
(http://bbs./t-22621-f23.html)
CODE:[Copy to clipboard]997.问:
如何畫游標所在處高低兩條水平線,並在其線上下顯示其值
答(股市骑兵00):
fl:=l;fh:=h;gb:=SYSPARAM(1);
PARTLINE(barpos>gb,fl[gb]);
PARTLINE(barpos>gb,fh[gb]);
DRAWNUMBER(barpos=datacount,fl[gb],fl[gb],2);
DRAWNUMBER(barpos=datacount,fh[gb],fh[gb],2);
显示数值
DD:datacount-sysparam(1),linethick;
QUOTE:
998.问:
如何统计画面可见k线第一根到最后一根k线的周期数？
这个统计的k线数量应该是随画面大小的变化，而变化。画面缩小，k线数增多，画面可见k线第一根到最后一根的数目也相应增多，故统计二者之间的k线数目也应该相应增加。
答(股市骑兵00):
SYSPARAM(3)-SYSPARAM(2)+1;
QUOTE:
999.问:
这是OBV的公式VA:=IF(CLOSE>REF(CLOSE,1),VOL,-VOL);
OBV:SUM(IF(CLOSE=REF(CLOSE,1),0,VA),0);
MAOBV:MA(OBV,M);
如何在五分钟中做这样的公式;
OBV大于MAOBV并且OBV大于零,还有在30个单位内OBV和MAOBV是向上运行的
答(股市骑兵00):
OBV>MAOBV AND MAOBV>0;//OBV大于MAOBV并且OBV大于零
ALL(OBV>REF(OBV,1),30) AND ALL(MAOBV>REF(MAOBV,1),30);//30个单位内OBV和MAOBV是向上运行
问:
用于5分钟选股,本应是没问题的,为什么选出的个股MAOBV还是有小于零
答(xxllxxll):
为什么会选出小于零的个股呢？
问题出在调入内存用于选股的五分钟K线数上,
把调入值设为最大值5000.
用OBV>0选股时，obv的参数最大值只能是4999
用maobv>0选股，obv的参数最大值只能为4999－m.
糟糕的是，当参数大等于5000或取0，
而硬盘中的五分钟k线数大于5000时，
在盘面上看指标是不错的，但用于选股就会出错，
这恐怕是软件需要改进的地方
否则在不知情的情况下，会得出错误结论
QUOTE:
1000.问:
帮我编个日换手率的指标,用柱状表示,上面加根10日平均线.
答(hx817):
日换手{％}:100*VOL/CAPITAL,VOLSTICK;
ma(日换手{％},10);
[ 本帖最后由 AHFYXL1 于 2005-12-1 14:10 编辑 ]
|
| 快速免费注册，并邮件激活，赠送高级会员内参、千元课程、8枚金币，享受纯净看帖与交流。 |
变色卡 提升卡 加粗卡  |
四级MACD会员 
UID 788344
阅读权限 40
注册 2004-4-8
- 积分 126
- 帖子 1
- 精华 7
- 奖励 97
- 热心 0
- 金币 0
-
-
|
发表于 2005-9-14 17:53 只看该作者
|
|
1001.问:
显示的节气字符不能随光标的移动变化
请教各位，如何才能正确显示（输出方式不能变）
jqfc:=if(date>=LSOLARTERMDATE(1) and date<LSOLARTERMDATE(2),'小寒',
if(date>=LSOLARTERMDATE(2) and date<LSOLARTERMDATE(3),'大寒',
if(date>=LSOLARTERMDATE(3) and date<LSOLARTERMDATE(4),'立春',
if(date>=LSOLARTERMDATE(4) and date<LSOLARTERMDATE(5),'雨水',
if(date>=LSOLARTERMDATE(5) and date<LSOLARTERMDATE(6),'惊蛰',
if(date>=LSOLARTERMDATE(6) and date<LSOLARTERMDATE(7),'春分',
if(date>=LSOLARTERMDATE(7) and date<LSOLARTERMDATE(8),'清明',
if(date>=LSOLARTERMDATE(8) and date<LSOLARTERMDATE(9),'谷雨',
if(date>=LSOLARTERMDATE(9) and date<LSOLARTERMDATE(10),'立夏',
if(date>=LSOLARTERMDATE(10) and date<LSOLARTERMDATE(11),'小满',
if(date>=LSOLARTERMDATE(11) and date<LSOLARTERMDATE(12),'芒种',
if(date>=LSOLARTERMDATE(12) and date<LSOLARTERMDATE(13),'夏至',
if(date>=LSOLARTERMDATE(13) and date<LSOLARTERMDATE(14),'小暑',
if(date>=LSOLARTERMDATE(14) and date<LSOLARTERMDATE(15),'大暑',
if(date>=LSOLARTERMDATE(15) and date<LSOLARTERMDATE(16),'立秋',
if(date>=LSOLARTERMDATE(16) and date<LSOLARTERMDATE(17),'处暑',
if(date>=LSOLARTERMDATE(17) and date<LSOLARTERMDATE(18),'白露',
if(date>=LSOLARTERMDATE(18) and date<LSOLARTERMDATE(19),'秋分',
if(date>=LSOLARTERMDATE(19) and date<LSOLARTERMDATE(20),'寒露',
if(date>=LSOLARTERMDATE(20) and date<LSOLARTERMDATE(21),'霜降',
if(date>=LSOLARTERMDATE(21) and date<LSOLARTERMDATE(22),'立冬',
if(date>=LSOLARTERMDATE(22) and date<LSOLARTERMDATE(23),'小雪',
if(date>=LSOLARTERMDATE(23) and date<LSOLARTERMDATE(24),'大雪',
if(date>=LSOLARTERMDATE(24) and date<LSOLARTERMDATE(1),'冬至',''))))))))))))))))))))))));
yuri:=LSOLARTERMDAY(date);
EXPLAIN(SYSPARAM(1)=BARPOS,'今日●'+jqfc + '节后第 '+NUMTOSTR(yuri[SYSPARAM(1)],0)+'天'),COLORGREEN ;
答(林汉明):
非常简单
N:=SYSPARAM(1);
DAT:=DATE;
jqfc:=if(LSOLARTERMDATE(1)<dat[N] and dat[N]<LSOLARTERMDATE(2),'小寒',
if(LSOLARTERMDATE(2)<dat[N] and dat[N]<LSOLARTERMDATE(3),'大寒',
if(LSOLARTERMDATE(3)<dat[N] and dat[N]<LSOLARTERMDATE(4),'立春',
if(LSOLARTERMDATE(4)<dat[N] and dat[N]<LSOLARTERMDATE(5),'雨水',
if(LSOLARTERMDATE(5)<dat[N] and dat[N]<LSOLARTERMDATE(6),'惊蛰',
if(LSOLARTERMDATE(6)<dat[N] and dat[N]<LSOLARTERMDATE(7),'春分',
if(LSOLARTERMDATE(7)<dat[N] and dat[N]<LSOLARTERMDATE(8),'清明',
if(LSOLARTERMDATE(8)<dat[N] and dat[N]<LSOLARTERMDATE(9),'谷雨',
if(LSOLARTERMDATE(9)<dat[N] and dat[N]<LSOLARTERMDATE(10),'立夏',
if(LSOLARTERMDATE(10)<dat[N] and dat[N]<LSOLARTERMDATE(11),'小满',
if(LSOLARTERMDATE(11)<dat[N] and dat[N]<LSOLARTERMDATE(12),'芒种',
if(LSOLARTERMDATE(12)<dat[N] and dat[N]<LSOLARTERMDATE(13),'夏至',
if(LSOLARTERMDATE(13)<dat[N] and dat[N]<LSOLARTERMDATE(14),'小暑',
if(LSOLARTERMDATE(14)<dat[N] and dat[N]<LSOLARTERMDATE(15),'大暑',
if(LSOLARTERMDATE(15)<dat[N] and dat[N]<LSOLARTERMDATE(16),'立秋',
if(LSOLARTERMDATE(16)<dat[N] and dat[N]<LSOLARTERMDATE(17),'处暑',
if(LSOLARTERMDATE(17)<dat[N] and dat[N]<LSOLARTERMDATE(18),'白露',
if(LSOLARTERMDATE(18)<dat[N] and dat[N]<LSOLARTERMDATE(19),'秋分',
if(LSOLARTERMDATE(19)<dat[N] and dat[N]<LSOLARTERMDATE(20),'寒露',
if(LSOLARTERMDATE(20)<dat[N] and dat[N]<LSOLARTERMDATE(21),'霜降',
if(LSOLARTERMDATE(21)<dat[N] and dat[N]<LSOLARTERMDATE(22),'立冬',
if(LSOLARTERMDATE(22)<dat[N] and dat[N]<LSOLARTERMDATE(23),'小雪',
if(LSOLARTERMDATE(23)<dat[N] and dat[N]<LSOLARTERMDATE(24),'大雪',
if(LSOLARTERMDATE(24)<dat[N] and dat[N]<LSOLARTERMDATE(1),'冬至',''))))))))))))))))))))))));
yuri:=LSOLARTERMDAY(date);
YURI2:=yuri[N];
EXPLAIN(SYSPARAM(1)=BARPOS,'今日●'+jqfc+ '节后第 '+NUMTOSTR(YURI2,0)+'天'),COLORGREEN;
QUOTE:
1002.问:
如何画一个十字把没有任何指标的主图画面分成相等的四个长方形
答(goldhill1965):
b1:=sysparam(1);
b2:=sysparam(2);
b3:=sysparam(3);
b4:=sysparam(4);
b5:=sysparam(5);
a1:=b3-b2+1;//可視畫面k線總數
a2:=round(a1/3);//可視畫面分成三份
a3:=b3-a2;//右區塊
a4:=a3-a2;//中區塊
a5:=a4-a2;//左區塊=b2
a6:=a4+a2;//左區塊=b2
VERTLINE(BARPOS=a3 or BARPOS=a4 or BARPOS=a5 or BARPOS=a6);
三分线:(b4+b5)/3;
中线:(b4+b5)/2;
六六线:2*(b4+b5)/3;
画面放大缩小后，需要按动箭头键
QUOTE:
1003.问:
1.光标移动时，日k线和5，10，20，30，60，120，250均线跟随光标移动显示出来。
附图周k线 5 10 20 30周均线跟随光标移动显示出来。光标所在位置及其左边
的都显示，光标右边的都部显示
2.能把k线也做成这样的吗
答(bajatje):
1.举例
uu:=barpos<=SYSPARAM(1);//显示条件
m:ma(c,5),linethick,COLORWHITE;//只显示数值
PARTLINE(uu,m),COLORWHITE;//画线。注意颜色与Ｍ配对；
2. 当然！
f:=c>o or (c=o and c>ref(c,1));//原有条件
STICKLINE(f and uu,c,o,6,1);
QUOTE:
1004.问:
1:因畫面是30分鐘週期 而引用60分鐘KD時(60KD) 其60KD線會產生階梯狀
2:希望 產生階梯狀部份用曲線幾乎直線將其連線 使成為一條很平順的線條
答(peter109):
範例
K:"KDJ.K#MIN60";
D:"KDJ.D#MIN60";
J:"KDJ.J#MIN60";
EMA(K,2);
QUOTE:
1005.问:
五天内有一天的成交量是三十日内最小成交量应怎么写,
答(欣儿):
llv(v,5)=llv(v,30);
QUOTE:
1006.问:
求教，怎样找出某一时段内高低点值的公式方法，例如：想找出某一股票2002年至今的时段内，
高点和低点的值，
答(bajatje):
w:=barslast(date<=1020101)+1;
hh:hhv(h,w)
LL:LLV(L,w);
CODE:[Copy to clipboard]1007.问:
如何使用字符型数组？非VBS语句，最好有实例
VARIABLE:varname1=initvalue1,varname2=initvalue2...;
例如:
VARIABLE:x=1,y=CLOSE,ARR[10]=0,SARR[5]='str';
表示定义常数变量x并初始化为1,
申明序列变量y并初始化为收盘价,
申明含10个浮点数的数组并全部初始化为0
申明含5个字符串的数组并都初始化为'str'
答(bajatje):
F10TEXT(F10FIND('{想输出的资料起始字符组。如：发 行 价}',{开始查找的位置。如：１－从Ｆ１０的第一个字符开始}),{输出的字符数。为０则只输出起始字符组的第一个字符所在行});
F10TEXT(F10FIND('发 行 价',１),０);
注意：空格也算字符。中文一个字为两个字符
别名: F10资料查找
所属类别: 字符串函数 参数数量: 2
当前证券的F10资料中查找字符串
用法:
F10FIND(S,N),将从当前股票的F10资料的第N个字符开始查找字符串S，返回找到的位置，返回-1表示未找到
例如:
F10FIND('发行价',1),将从F10资料的第1个字符开始查找字符串'发行价'，返回找到的位置。
别名: F10资料子字符串
所属类别: 字符串函数 参数数量: 2
取得当前证券的F10资料中指定范围的子字符串
用法:
F10TEXT(N,M),将得到当前股票的F10资料中从第N个字符开使的M个字节长的字符串，M=0表示一直取到行尾
例如:
EXPLAIN(1,F10TEXT(F10FIND('发行价',1),0));
输出F10资料中'发行价'所在行
CODE:[Copy to clipboard]1008.问:
想选出与指定股票同行业的所有股票！
答(股市骑兵00):
//◇鹏搏资讯F10资料◇
INPUT:n(1,1,100);
VARIABLE:hytr[100]='',ptr='';
hytr[1]:='港口';//把选股行业都写好，按1，2，3......数组方式写完
hytr[2]:='银行';
hytr[3]:='汽车';
str:=F10TEXT(F10FIND('行业类别',1)+16,0);//F10公式提出行业字符串
for i=1 to 100 do if hytr<>'' then ptr:=ptr+NUMTOSTR(i,0)+hytr+'\n';
行业选股:STRFIND(str,hytr[n],1);
EXPLAIN(1,'该股行业：'+str+'\n'+'选股行业：'+hytr[n]);
EXPLAIN(1,ptr);//查看解盘中"数字"所对应的行业，来调 N 参数选股
QUOTE:
1009.问:
如何求某一具体日期后100天的日期？谢谢！
如求1050908后100天的日期。这个日期是还未到的日期
答(hx817):
d1:=1050908;
d2:D1970TODATE(DATETOD1970(d1)+100);
QUOTE:
1010.问:
去年今天的 期货持仓量 怎么写?
答(cwy):
a:=date-10000;
a1:=a[datacount];
b:=date-20000;
b1:=b[datacount];
d:=date-30000;
d1:=d[datacount];
去年:ref((date=a1)*v,BARSLAST(date=a1));
⒉年前:ref((date=b1)*v,BARSLAST(date=b1));
⒊年前:ref((date=d1)*v,BARSLAST(date=d1));
| |
|
