叠加K线 通达信选股流程图解

叠加K线

来自作者：蔚蓝222

---

相关标签: ST

以下部份源码为网络资料,原作佚名,在此感谢原作

{如不嫌花,可在自定主图指标下加入以下源码}
周期:=160;
{可改:CTRL+D\设置4\锁定分析图中的初始K线数\勾选及填数}

自动C:=INDEXC;
自动O:=INDEXO;
自动H:=INDEXH;
自动L:=INDEXL;
{以上自动对应沪深中创指数}
{自动行业C:=HY_INDEXC;
自动行业O:=HY_INDEXO;
自动行业H:=HY_INDEXH;
自动行业L:=HY_INDEXL};
{以上自动对应行业指数,需TDX新版及板块指数服务器支持}
指定O:="SH999999$O";
指定H:="SH999999$H";
指定L:="SH999999$L";
指定C:="SH999999$C";
{以上指定对应上证指数}

{以下为指定对应上证指数,可改为你喜欢叠加的指数,见上}
大盘低:=CONST(LLV(指定L,周期));{'指定'二字可改'自动'或'自动行业'}
大盘高:=CONST(HHV(指定H,周期));
大盘差:=大盘高-大盘低;
当前低:=CONST(LLV(L,周期));
当前高:=CONST(HHV(H,周期));
当前差:=当前高-当前低;
比:=当前差/大盘差;

变C:=当前低+(指定C-大盘低)*比;{改'指定'为你喜欢的}
变H:=当前低+(指定H-大盘低)*比;
变L:=当前低+(指定L-大盘低)*比;
变O:=当前低+(指定O-大盘低)*比;

低点周期:=20;
QA:=REF(指定L,低点周期)=LLV(指定L,3*低点周期+1);{改'指定'为你喜欢的}
QB:=BACKSET(QA,低点周期+1);
QC:=FILTER(QB,低点周期) AND 指定L=LLV(指定L,低点周期+1);{改'指定'为你喜欢的}
QD:=BARSLAST(QC);
QE:=IF(QC,CURRBARSCOUNT,0);
QF:=IF(QD,REF(QE,QD),QE);
QG:=CONST(QF);
{以上含未来函数,可删掉}

STICKLINE(CURRBARSCOUNT<QG,变H,变L,0,0),COLOR888888;
STICKLINE(CURRBARSCOUNT<QG,变O,变C,3,0),COLOR888888;
STICKLINE(CURRBARSCOUNT<QG AND 变C>=变O,变O,变C,3,1),COLOR888888;
{以上QG可改为你指定的周期数,不怕花的填上'周期'二字}
DRAWKLINE(H,O,L,C);

波谷:=20;
最低:=TROUGHBARS(C,波谷,1);{调整之字幅度找到低位起点}
低价:=REF(C,BARSLAST(最低=0));
低价线:=DRAWLINE(最低=0,C,ISLASTBAR,低价,0);
现价线:=DRAWLINE(最低=0,C,ISLASTBAR,C,0);
低点涨幅:(C-低价线)/低价线*100,COLORFF00FF,NODRAW;
DRAWBAND(低价线,RGB(255,00,255),低价线,0);
DRAWBAND(现价线,RGB(255,00,255),现价线,0);
DRAWTEXT(CURRBARSCOUNT=CONST(最低+9),CONST(低价线),STRCAT(CON2STR(低点涨幅,2),'％')),COLORFF00FF;
{以上含未来函数,可删掉};

 

 

 

通达信选股流程图解——————

来自作者：杨文峰

---

相关标签: 通达信

1、软件需要下载数据
（数据最基本的是要保证他的正确性，这是基本条件）

2、建立公式，通过菜单里面的功能——选股器——综合选股
（我的条件是：
超B:=L2_AMO(0,2)/10000.0;
大B:=L2_AMO(1,2)/10000.0;
中B:=L2_AMO(2,2)/10000.0;
小B:=L2_AMO(3,2)/10000.0;
超S:=L2_AMO(0,3)/10000.0;
大S:=L2_AMO(1,3)/10000.0;
中S:=L2_AMO(2,3)/10000.0;
小S:=L2_AMO(3,3)/10000.0;
净流入:(超B+大B+中B+小B)-(超S+大S+中S+小S),NODRAW;
超大单:(超B)-(超S),NODRAW,COLORRED;
大单:(大B)-(大S),NODRAW,COLORMAGENTA;
中单:(中B)-(中S),NODRAW,COLORAAAA00;
小单:(小B)-(小S),NODRAW,COLOR008000;
连续流入:EVERY(净流入>0,N) AND 超大单>0 AND 大单>0 AND 中单>0 AND 小单>0,NODRAW;）

3、按图片设置选股，选出来后利用报表排序，按DELETE键删除不需要的删除即可