量柱量价有关公式

1、{长阴加长腿XG--王子老师伏击涨停书中思路--自设参数:N(1,10,1)}
长阴短柱:=(C/REF(C,1)<=0.95 OR C/O<=0.95) AND V/HHV(V,20)<=0.618;
长腿:= (MIN(O,C)-L)/(H-L)>0.5 AND (MIN(O,C)-L)/C>=0.05;
XG0:= REF(COUNT(长阴短柱,2),1) AND 长腿;
XG : COUNT(XG0,N) AND DYNAINFO(8)>0;

2、缩倍量选股公式

CLOSE>REF(CLOSE,1) AND REF(CLOSE,1)>REF(CLOSE,2) AND VOL/REF(VOL,1)<0.5;

 

3、主图精准线

 

 MA1:MA(CLOSE,5);
MA2:MA(CLOSE,24);
IF(MA2>REF(MA2,1),MA2,DRAWNULL),COLORYELLOW,LINETHICK2;
IF(MA2<REF(MA2,1),MA2,DRAWNULL),COLORGREEN,LINETHICK2;
水平面:MA(CLOSE,72);
IF(水平面>REF(水平面,1),水平面,DRAWNULL),COLORRED,LINETHICK2;
IF(水平面<REF(水平面,1),水平面,DRAWNULL),COLORFFA2FF,LINETHICK2;
V2:=IF(CURRBARSCOUNT=1,VOL*240/FROMOPEN/REF(VOL,1)-1,VOL/REF(VOL,1)-1);
STICKLINE(V2>=1,O,C,2,0),COLORYELLOW;
MAMA13:=MA(CLOSE,13);
X1:=(C+L+H)/3;
BB13:=ATAN(EMA(X1,13)-REF(EMA(X1,13),1))*3.1416*10;
EMAEMA8:=EMA(C,8);
A1:=MIN(O,C);
B1:=ABS(O-C);
T1:=FILTER(BB13>1 AND EMA(X1,13)>REF(EMA(X1,8),1),10);
STICKLINE(T1,A1,A1+B1/4,2,0),COLOR007575;
STICKLINE(T1,A1+B1/4,A1+B1/2,2,0),COLORFF0000;
STICKLINE(T1,A1+B1/2,A1+B1*3/4,2,0),COLOR007575;
STICKLINE(T1,A1+B1*3/4,A1+B1,2,0),COLORFF0000;
LC:=REF(CLOSE,1);
RSI:=((SMA(MAX((CLOSE - LC),0),3,1) / SMA(ABS((CLOSE - LC)),3,1)) * 100);
FF:=EMA(CLOSE,3); MA15:=EMA(CLOSE,21);
STICKLINE(CROSS(FF,MA15),A1,A1+B1/2,2,0),COLOR7F017F;
STICKLINE(CROSS(88,RSI),A1+B1,A1+B1/2,2,0),COLORGREEN;
BBI:=(MA(CLOSE,3)+MA(CLOSE,6)+MA(CLOSE,12)+MA(CLOSE,24))/4;
T2:=COUNT(CROSS(BBI,3),3)=1 AND CROSS(C,BBI);
STICKLINE(T2,O,C,2,0),COLORRED;

{精准线}
N:=3;
L0:=0.00;{点位差参数}
{底精准线}
LA1:=ABS(L-REF(L,1))<=L0;
LA2:=ABS(L-REF(L,2))<=L0;
LA3:=ABS(L-REF(L,3))<=L0;
LA4:=ABS(L-REF(L,4))<=L0;
LA5:=ABS(L-REF(L,5))<=L0;
精准线首次:=LA1 OR LA2 OR LA3 OR LA4 OR LA5;
精准左:=FILTER(精准线首次,N) ;
天数:=BARSLAST(精准左);
LTS:=REF(L,天数);
精准右:=ABS(L-LTS)<=L0;
STICKLINE(精准左,L,L,50,-1),COLORMAGENTA;
DRAWLINE(精准左,L,精准右,LTS,1),COLORMAGENTA;
{顶精准线}
G1:=ABS(H-REF(H,1))<=L0;
G2:=ABS(H-REF(H,2))<=L0;
G3:=ABS(H-REF(H,3))<=L0;
G4:=ABS(H-REF(H,4))<=L0;
G5:=ABS(H-REF(H,5))<=L0;
精准线首次1:=G1 OR G2 OR G3 OR G4 OR G5;
精准左1:=FILTER(精准线首次1,N) ;
天数1:=BARSLAST(精准左1);
GTS:=REF(L,天数1);
精准右1:=ABS(H-GTS)<=L0;
STICKLINE(精准左1,H,H,50,-1),COLORGREEN;

 

4、百日地量＋倍量选牛股

 

 

{BRDLBLXG}
ZTS:=1;ZTFD:=9.90;ZTZQ:=300;
ST1:=IF(NAMELIKE('ST'),0,1);
ST2:=IF(NAMELIKE('*ST'),0,1);
ST3:=IF(NAMELIKE('S*ST'),0,1);
ST4:=IF(NAMELIKE('SST'),0,1);
ST5:=IF(NAMELIKE('S'),0,1);
ST6:=IF(NAMELIKE('N'),0,1);
XGX1:=ST1 AND ST2 AND ST3 AND ST4 AND ST5 AND ST6; 
TP:=(DYNAINFO(4)=0);
XGX2:=NOT (TP);
ZT:=((C-REF(C,1)))/REF(C,1)*100>ZTFD;
YYZT:=COUNT(ZT=1,ZTZQ);
XGX3:=YYZT>ZTS;
XGX4:=VOL>REF(VOL,1)*2;
XGX5:=REF(VOL,1)=REF(LLV(VOL,100),1);
XGX:XGX1 AND XGX2 AND XGX3 AND XGX4 AND XGX5;

 

5、量柱公式(通达信软件直观显示真黄金柱)

{VOL_量柱}

{看图说明：黄色为倍量柱，白色为并肩平量柱，紫色为缩倍柱，
绿色为１０天低量柱，蓝色为５０天低量柱，灰色为百日低量柱，
高量柱容易看无标记，！为长阴短柱, 内有红实线为假阴柱。
红色箭头(的前三天)为黄金柱。次黄金柱难判,不标记}

{=====================================================}

绿低量:=10;{WWW.178448.COM WEN98编制}

蓝低量:=50;

灰低量:=100;

H_L:=0.1*CONST(HHV(VOL,240));

{MAV10:MA(V,10),COLORYELLOW;}

异动135:MA(V,135),COLORMAGENTA;

洗盘40:MA(V,40),COLORBLUE;

启动5:MA(V,5),COLORWHITE;

VVOL:=IF(CURRBARSCOUNT=1 AND PERIOD=5,VOL*240/FROMOPEN,DRAWNULL);{模拟量}

STICKLINE(CURRBARSCOUNT=1 AND PERIOD=5,VVOL,0,1,-1),COLOR00C0C0;

量:VOL,VOLSTICK,COLORLIGRAY;

换手: VOL*10000/FINANCE(7),NODRAW,COLORGREEN; {DYNAINFO(37)*100}

全换手周期: SUMBARS(V,CAPITAL),NODRAW,COLORLIGREEN;{求完全换手到现在的周期数}

量比: V/REF(MA(V,5),1),COLORBROWN,NODRAW;

几倍: V/REF(V,1),COLORYELLOW,NODRAW;

倍数:=1.9;

倍量: VOL>=REF(V,1)*倍数 AND (IF(C<O,C>REF(C,1),1)),COLORYELLOW,NODRAW;

倍缩: REF(V,1)>=VOL*倍数,COLORMAGENTA,NODRAW;

平量: RANGE(V/REF(V,1),0.97,1.03) AND BARSCOUNT(V)>=2,COLORWHITE,NODRAW;

低量10: VOL=LLV(VOL,绿低量) AND BARSCOUNT(V)>=绿低量,COLORGREEN,NODRAW;

低量50: VOL=LLV(VOL,蓝低量) AND BARSCOUNT(V)>=蓝低量,COLORBLUE,NODRAW;

地量: VOL=LLV(VOL,灰低量) AND BARSCOUNT(V)>=灰低量,COLORGRAY,NODRAW;

V1:=VOL*0.95;{图标位置}

V2:=VOL*0.85;

STICKLINE(倍量, 0,V1,1,0),COLORYELLOW;

STICKLINE(平量,0,V1,1,0),COLORWHITE;

STICKLINE(低量10,0,V2,1,0),COLORLIGREEN;

STICKLINE(低量50,0,V2,1,0),COLORBLUE;

STICKLINE(地量,0,V2,1,0),COLORGRAY;

STICKLINE(倍缩,0,V*0.45,1,0),COLORMAGENTA;

STICKLINE(C<O AND C>REF(C,1),0,V1,0,0),COLORRED;{假阴柱}

真阳或假阴:=C>O OR C>REF(C,1);

收阳:= REF(真阳或假阴,3);

倍量1:=REF(倍量,3);

高量:=REF(V,3)>=HHV(V,7);

三日不破:= LLV(C,3)>=REF(L,3);

价升:=COUNT(C>=REF(C,1),3)=3;{收盘价逐升}

量缩:=COUNT(V<=REF(V,1),3)=3;

连阳:= COUNT(真阳或假阴,3)=3;

倍量将军柱:= 倍量1 AND 三日不破 AND 收阳;

高量将军柱:= 高量 AND 三日不破 AND 收阳;

将军柱:= 倍量将军柱 OR 高量将军柱;

黄金柱:= 将军柱 AND 价升 AND 量缩 AND 连阳 ;{标准黄金柱}

STICKLINE(黄金柱,0.3*V,0.7*V,1,0),COLORRED; {红柱}

DRAWICON(黄金柱,V*1.5,1);

V100:= V<=LLV(V,100)*1.2 AND V>0 AND BARSCOUNT(V)>=100;

百日地量群:=COUNT(V100,5)>=3;

DRAWTEXT(FILTER(百日地量群,4),V+3*H_L,'地量群'),COLORGRAY;

长阴短柱:=C/REF(C,1)<=0.96 AND V<HHV(V,30)/1.9;

DRAWTEXT(长阴短柱 ,V+1.6*H_L,'！'),COLORLICYAN;

6、倍量过左峰选股公式

{倍量过左峰XG}

{自设参数:TS(3,100,10),前高虚实(0,1,0)}

过滤条件:= NAMELIKE('ST') OR NAMELIKE('*')

{OR CODELIKE('3')}{创业板}

OR BARSCOUNT(V)<=100{次新}

OR DYNAINFO(9)=0{停牌}

OR CAPITAL>1000000*5{<5亿小盘};

倍量:=VOL/REF(VOL,1)>=1.9;

HC:=IF(前高虚实=0,H,MAX(C,O));

TS1:=TS;{波峰两边的周期}

T1:=BARSLAST(FILTER(BACKSET(FILTER(REF(HC,TS1)=HHV(HC,2*TS1+1),TS1),TS1+1),TS1));

左峰高:=REF(HC,T1);

前凹:=REF(HHV(HC,T1),1)<=左峰高;

BL:=1.03;{超过左峰顶3%}

XG: CROSS(C,左峰高*BL) AND 前凹 AND 倍量 AND 过滤条件=0 ;