|
有许多实现Excel工作簿合并的方法，在《将多个工作簿中的数据合并到一个工作簿》中介绍过合并工作簿的示例。下面再列举几个示例，供有兴趣的朋友参考。
例如，需要将多个Excel工作簿中的工作表合并到一个工作簿。这里假设需要合并的工作簿在“D:\示例\数据记录\”文件夹中，含有两个工作簿test1.xls、test2.xls（当然，可以不限于两个），在test1.xls工作簿中含有三张工作表，在test2.xls工作簿中含有两张工作表，现在使用一段VBA代码合并这两个工作簿到一个新工作簿中，合并到新工作簿中的工作表分别以原工作簿名加索引值命名。代码如下：
Sub CombineWorkbooks()
Dim strFileName As String
Dim wb As Workbook
Dim ws As Object
'包含工作簿的文件夹,可根据实际修改
Const strFileDir As String = "D:\示例\数据记录\"
Application.ScreenUpdating = False
Set wb = Workbooks.Add(xlWorksheet)
strFileName = Dir(strFileDir & "*.xls*")
Do While strFileName <> vbNullString
Dim wbOrig As Workbook
Set wbOrig = Workbooks.Open(Filename:=strFileDir & strFileName, ReadOnly:=True)
strFileName = Left(Left(strFileName, Len(strFileName) - 4), 29)
For Each ws In wbOrig.Sheets
ws.Copy After:=wb.Sheets(wb.Sheets.Count)
If wbOrig.Sheets.Count > 1 Then
wb.Sheets(wb.Sheets.Count).Name = strFileName & ws.Index
Else
wb.Sheets(wb.Sheets.Count).Name = strFileName
End If
Next
wbOrig.Close SaveChanges:=False
strFileName = Dir
Loop
Application.DisplayAlerts = False
wb.Sheets(1).Delete
Application.DisplayAlerts = True
Application.ScreenUpdating = True
Set wb = Nothing
End Sub |
示例文档下载：
下面是合并多个Excel工作簿的另一种情形，也是《Excel VBA实战技巧精粹》中<技巧91：汇总多个工作簿的工作表>所介绍的方法，即合并汇总。
有四个工作簿，分别为：汇总工作簿.xls、一月.xls、二月.xls、三月.xls，其中一月.xls、二月.xls、三月.xls均只含有一张工作表且工作表中的数据均自单元格A1开始，现在要求将它们合并至“汇总工作簿.xls”中。
在“汇总工作簿.xls”中打开VBE，并输入下列代码：
Sub ConsolidateWorkbook()
Dim RangeArray() As String
Dim bk As Workbook
Dim sht As Worksheet
Dim WbCount As Integer
WbCount = Workbooks.Count
ReDim RangeArray(1 To WbCount - 1)
For Each bk In Workbooks '在所有工作簿中循环
If Not bk Is ThisWorkbook Then '非代码所在工作簿
Set sht = bk.Worksheets(1) '引用工作簿的第一个工作表
i = i + 1
RangeArray(i) = "'[" & bk.Name & "]" & sht.Name & "'!" & _
sht.Range("A1").CurrentRegion.Address(ReferenceStyle:=xlR1C1)
End If
Next
Worksheets(1).Range("A1").Consolidate _
RangeArray, xlSum, True, True
End Sub |
运行上述代码前，必须打开所有的工作簿。运行代码后，将自动汇总所有工作表中的值并将相应单元格的值求和。
示例文档下载：
下面是汇总多个工作簿的又一种情形，也是一名网友提出的问题：在同一文件夹中有多个工作簿，其中有一个用于汇总的工作簿，要求将除该汇总工作簿外的其它工作簿中的第一张工作表的数据汇总到该汇总工作簿中。代码如下：
Sub UnionWorksheets()
Application.ScreenUpdating = False
Dim lj As String
Dim dirname As String
Dim nm As String
lj = ActiveWorkbook.Path
nm = ActiveWorkbook.Name
dirname = Dir(lj & "\*.xls*")
Cells.Clear
Do While dirname <> ""
If dirname <> nm Then
Workbooks.Open Filename:=lj & "\" & dirname
Workbooks(nm).Activate
'复制新打开工作簿的第一个工作表的已用区域到当前工作表
Workbooks(dirname).Sheets(1).UsedRange.Copy _
Range("A65536").End(xlUp).Offset(1, 0)
Workbooks(dirname).Close False
End If
dirname = Dir
Loop
End Sub |
相关文章- 2009年05月20日 从已关闭的工作簿中取值 (4)
经常有人提出关于如何从已关闭（或未打开）的工作簿中取值的问题，我将自已收集整理的一些代码辑录于此，供参考。
示例代码1：
Sub testGetValuesFromClosedWorkbook()
GetValuesFromAClosedWorkbook "C:", "Book1.xls", "Sheet1", "A1:G20"
End Sub
Sub GetValue... - 2009年05月19日 判断指定的工作簿是否已打开 (0)
下面整理归纳了一些实用函数代码，其功能都是用来判断指定的工作簿是否打开，如果已打开则返回True，否则返回False。
实用代码1：
Function IsWorkbookOpen(wbk As String) As Boolean
Dim wbT As Excel.Workbook
Err.Clear
On Error Resume Next
... - 2009年05月18日 Workbook对象应用大全 (1)
Workbook对象代表一个工作簿，Workbooks集合对象则代表同一Excel进程中打开的所有工作簿对象。
[应用1] 创建新工作簿（Add方法）
使用Add方法在Workbooks集合中创建新工作簿，所创建的工作簿为活动工作簿。其语法为：
Workbooks.Add(Template)
参数Template可选，决定如何创建新工作簿。如果将该参数设置为已存在的Excel模板文件... - 2009年05月9日 将多个工作簿中的数据合并到一个工作簿 (1)
在MSDN文档资料库中，Microsoft Office Excel MVP Ron de Bruin提供了一些非常好的代码示例，用于将同一文件夹里的多个工作簿中某一工作表的数据合并到一个工作簿中。下面，来介绍这些实用代码，也通过这些代码来学习VBA。当然，您可以适当修改代码，使代码满足自已想要的功能。
查找单元格区域中的最后一个单元格、最后一行或最后一列
这是后面示例中要用到的通用代码... - 2009年05月3日 从Excel中导出图片（一种较简单的方法） (1)
在以前的一篇文章中，介绍了两种从Excel中导出图片的方法，即《从Excel中导出图片》。所介绍的代码都使用了Windows API，较为繁锁。前几天看到John Walkenbach先生的一个VBA技巧，很巧妙地将工作簿中的图片导出，并且代码也很简单，特在此与大家分享。
我们知道，将Excel工作簿保存为网页文件（HTML格式）时，除了主文件外，还会创建一个包含有图形、图表、样式等文件的...
|
