草叶子 / 股票指标 / 条件选股公式的添加和使用

   

条件选股公式的添加和使用

2014-09-14  草叶子

                                               条件选股公式的添加和使用

条件选股公式的添加和使用 - 来生缘 - 来生缘

     1.条件选股公式的添加:公式管理器—条件选股公式—其他类型—新建—公式名称用4个字简写—确定。

条件选股公式的添加和使用 - 来生缘 - 来生缘

   2.条件选股公式的使用:通达信选股器—条件选股—在条件选股公式栏找到自己需要的公式—加入条件—选股入板块,确定即可。

条件选股公式的添加和使用 - 来生缘 - 来生缘

通达信条件选股公式

使用:选股公式指标可以单独用,也可以合并用合并用时每个条件中间加上AND,

表达结束时句尾用;

K线:

最高价:HIGH简写H

收盘价:CLOSE简写C

最低价:LOW简写L

开盘价:OPEN简写O

成交量:VOL简写V


换手率大于3 DYNAINFO(37)>3 

量比大于3   DYNAINFO(17)>3

跳空高开  O>REF(C,1)*1.02 

昨日收阴线 REF(C,1)<REF(O,1) 

今天跳空低开 REF(C,1)>C 

今日最低价高于昨日最低价  L>REF(L,1) 

成交量:今日缩量至昨日的一半   V<REF(V,1)/2;

当前流通股本(手)>2000000     CAPITAL>2000000 

当前流通股本(手)<10000000    CAPITAL<10000000 

筹码获利比例95%  WINNER(C)*100>95

低开高走收阳(可参阅学K线:游资手法:定价权争夺区

REF(C,1)>REF(O,1) AND O<REF(C,1) AND C>O AND C>REF(H,1);


60日线:XG:C>MA(C,60);
百日地量: V<=LLV(V,100); 
倍量:  倍量:=V>REF(V,1);
大阴缩量:L=REF(L,1) AND V<REF(V,1)/2;
获利筹码大于95  高高在上 :WINNER(C)*100>95;
低开高走:O<REF(L,1) AND CROSS(C,REF(L,1));
跳空高开:O>REF(C,1)*1.00 AND  DYNAINFO(7)>DYNAINFO(4);
高开假阴线:OPEN>REF(CLOSE,1)*1.03 AND CLOSE>REF(CLOSE,1) AND OPEN>CLOSE  AND  OPEN>CLOSE AND CLOSE>MA(CLOSE,20) AND MA(CLOSE,30)>MA(CLOSE,60) AND MA(CLOSE,60)>MA(CLOSE,120);

长阴短柱
N:=20;
ZF:=(C-REF(C,1))/REF(C,1);
XG: ((C-O)/C<=-0.04 OR ZF<=-0.04) AND V/HHV(V,N)<=0.6  AND COUNT(ZF>=0.07,N) AND C<0.9*HHV(H,240) AND DYNAINFO(9)>100;



阴阳相同
T1:=REF(C,1)<REF(O,1);
T2:=C>O;
T3:=V<REF(V,1);
T4:=L=REF(L,1);
T1 AND T2 AND T3 AND T4;

20日3同价
AA:=COUNT(L=REF(L,1),2)=2;
D1:=COUNT(AA,20)>=1;
AA AND D1;

 
跳空高开, 量比>1.5
O>REF(C,1)*1.02 AND DYNAINFO(17)>1.5 AND DYNAINFO(7)>DYNAINFO(4);

跳空高开
O>REF(C,1)*1.00 AND  DYNAINFO(7)>DYNAINFO(4);


昨天阴线,今天阳线,且两天的最低价相等。阳线的成交量小于阴线的。
t1:=ref(c,1)<ref(o,1);
t2:=c>o;
t3:=v<ref(v,1);
t4:=l=ref(l,1);
t1 and t2 and t3 and t4;
 
昨日大阴今日缩量(这样选出的股票不论今日阴阳线都在昨日大阴线内)
L=REF(L,1) AND V<REF(V,1)/2;


百日低量
 倍量:=v>ref(v,1);
 v<=llv(v,100); 




单峰密集
A1:=COST(85); 
A2:=COST(15);
A3:=A1-A2; 
A4:=(A1+A2)/2; 
单峰密集:A3/A4*100<14.45,LINETHICK0;

分时横盘
X1:=ABS(MA(C,10)/MA(C,20)-1)<0.01;{取1%振幅内粘合}
X2:=ABS(MA(C,5)/MA(C,10)-1)<0.01;
X3:=ABS(MA(C,5)/MA(C,20)-1)<0.01;
AA:=MA(C,5)>REF(MA(C,5),1);BB:=MA(C,10)>REF(MA(C,10),1);CC:=MA(C,5)>MA(C,10);{均线勾头向上}
CDJZ:=ABS(MA(C,20)-MA(C,120))/MA(C,120)<0.4;{长短均线距离绝对值越小越好}
MA(C,5)>REF(MA(C,5),1) AND X1 AND X2 AND X3
AND CDJZ AND AA AND BB AND CC;

站到5日线
MA5:=MA(C,5);
MA10:=MA(C,10);
MA30:=MA(C,30);
AA:=CROSS(C,MA5);
ZM:MA5>MA10 AND MA10>MA30 AND MA5>REF(MA5,1) AND MA10>REF(MA10,1) AND MA30>REF(MA30,1) AND AA;

尖三兵
(REF(C,2)>REF(C,3) AND C>REF(H,1) AND  (C-REF(C,1))/REF(C,1)*100>=3 AND
(REF(H,1)-MAX(REF(C,1),REF(O,1)))>1.5*ABS(REF(O,1)-REF(C,1)));  

待入线
A:=REF(C,1)<REF(O,1);
B:=O<REF(C,1);
CC:=C<=REF(O,1);
A AND B AND CC AND C>O;


均线粘合选股公式
均线粘合很少有百分百相等的情况,可以取1%振幅内粘合,并且一般是3条均线。
源码如下:
X1:=ABS(MA(C,10)/MA(C,20)-1)<0.01;
X2:=ABS(MA(C,5)/MA(C,10)-1)<0.01;
X3:=ABS(MA(C,5)/MA(C,20)-1)<0.01;
MA(C,5)>REF(MA(C,5),1) AND X1 AND X2 AND X3;

5弯10:
EVERY(MA(C,5)>MA(C,10),10) AND DOWNNDAY(MA(C,5)-MA(C,10),3); 


 3日粘合
 M1:=MA(C,5); 
M2:=MA(C,10); 
M3:=MA(C,20); 
上:=MAX(M1,MAX(M2,M3)); 
下:=MIN(M1,MIN(M2,M3)); 
三线粘合:LLV((上-下)/下*100<0.5,3) AND M1>REF(M1,1); 

5日和10日线粘合
 M5:=MA(C,5); 
M10:=MA(C,10); 
ABS(M5-M10)<0.001;


平台突破
A1:=C=HHV(C,21); 
A2:=BARSLAST(A1); 
A3:=IF(A2>0,REF(C,A2),REF(C,A2)); 
A4:=CROSS(C,REF(A3,1)); 
XG: A4   AND  COUNT(A4,5)=1;

准备买入    
买入:=(DCLOSE-REF(C,1))/REF(C,1)*100;
XG:CROSS(买入,20) OR CROSS(买入,18);
STICKLINE(XG,IF(C>=O,O,C),IF(C>=O,O,C),100,0);
DRAWTEXT(XG,L,'准备买入'),COLORMAGE




天下
A1:=REF(O,2)<REF(C,2) AND REF((H-C),2)/REF(C,20)<0.03; 
A2:=REF(V,1)<REF(V,2) AND REF(C,1)>REF(MA(C,80),1);
A3:=REF(C,1)<REF(O,1) AND REF(C,1)<REF(O,1)<1.02;
A4:=C>REF((O+C)/2,1);
A5:=DYNAINFO(17)>1;
A6:=CAPITAL/1000000<90;

     



1.公式管理器—条件选股公式—其他类型—新建—确定。
2.选股器—条件选股—在条件选股公式中找到需要的公式即可。

 

N天涨停(可以找到几天以前涨停的股票)
参数   最小   最大    缺省
 N     1.00   30.00   1.00 
CN:=REF(C,N);
CM:=REF(C,N+1);
SG:=H>CN;
J:="KDJ.J"<103;
ZT:=IF((CN-CM)*100/CM>=(10-0.01*100/CM),1,0);
V5:=MA(V,5);
V10:=MA(V,10);
WOL:=IF(CURRBARSCOUNT=1 AND PERIOD=5,VOL*240/FROMOPEN,DRAWNULL);
LS:=WOL>=V5 OR WOL>=V10;
ZDXG:SG AND J AND ZT AND LS;
 

N天前涨停

参数   最小   最大    缺省
 N    1.00   100.00   3.00
CN:=REF(C,N);
CM:=REF(C,N-1);
涨停:IF((CM-CN)*100/CN>=(10-0.01*100/CN),1,0);

 

N天内出现涨停
参数  最小    最大    缺省
  N     1.00   100.00   20.00
EZT:=HIGH>REF(CLOSE,1)*1.1; { 出现过涨停 }
EZTO:EXIST(EZT,N); { N天内存在过涨停 };

 

均线多头排列

       通俗点说均线多头排列,就是说5日线在最上面,其次是10日线,20日线.30日线,所有的均线都是向上趋势,多头排列表明现在持有这个股票的人几乎都是获利的。多头排列的股票肯定是上涨的。
       对短线操作来说,更是如此.不论是追涨还是抓突破性买入机会,主要考虑的因素就是市场态势及个股的均线排列形态.一定要回避盘整走势,重点选择各周期均线完全多头排列的品种参与,中长期均线至少要处于走平状态.


参数  最小   最大    缺省
 N1   2.00  200.00   5.00
 N2   2.00  200.00  10.00
 N3   2.00  200.00  20.00
 N4   2.00  200.00  30.00
A1:=MA(CLOSE,N);
A2:=MA(CLOSE,N1);
A3:=MA(CLOSE,N2);
A4:=MA(CLOSE,N3);
CLOSE>A1 AND A1>A2 AND A2>A3 AND A3>A4 AND CLOSE>OPEN;

 

 多头排列

XG:C>MA(C,5) AND MA(C,5) >MA(C,10) AND MA(C,10) > MA(C,30)  AND MA(C,30) >MA(C,60); 

价托

参数  最小   最大    缺省
 N1   2.00  200.00   5.00
 N2   2.00  200.00  10.00
 N3   2.00  200.00  20.00
MA1:=MA(CLOSE,N1);
MA2:=MA(CLOSE,N2);
MA3:=MA(CLOSE,N3);
TUO:=COUNT(CROSS(MA1,MA2),21)=1 AND CROSS(MA2,MA3) AND
COUNT(CROSS(MA1,MA3),21)=1 AND
BARSLAST(CROSS(MA1,MA2))>BARSLAST(CROSS(MA1,MA3)) AND
BARSLAST(CROSS(MA1,MA3))>BARSLAST(CROSS(MA2,MA3)) AND
MA1>REF(MA1,1);
 
均线金叉
参数   最小   最大     缺省
N      5.00  100.00   20.00
MA5:=MA(C,5);
MA10:=MA(C,10);
MA20:=MA(C,20);
股价穿三均线:IF(CROSS(C,MA5) AND CROSS(C,MA10) AND CROSS(C,MA20),1,0),COLORRED;

 
老鸭头

MA5:=MA(CLOSE,5);
MA10:=MA(CLOSE,10);
MA60:=MA(CLOSE,60);
PDAY1:=BARSLAST(CROSS(MA5,MA60));{5日均线上穿60日均线}
PDAY2:=BARSLAST(CROSS(MA10,MA60));{10日均线上穿60日均线,至此形成鸭颈部}
PDAY3:=BARSLAST(HIGH=HHV(HIGH,PDAY2));{形成头部,要下跌}
PDAY4:=BARSLAST(CROSS(MA10,MA5));{下跌后,5日均线和10日均线死叉}
PDAY5:=BARSLAST(CROSS(MA5,MA10));{回落不久,5日均线和10日均线形成金叉,形成嘴部}
A1:= PDAY1>PDAY2 AND PDAY2>PDAY3 AND PDAY3>PDAY4 AND PDAY4>PDAY5 AND PDAY5<5;
A2:= COUNT(CROSS(MA10,MA5),PDAY2)=1;
A1 AND A2;


 尖三兵     尖三兵:捕捉疯牛绝胜K线战法
         K线理论已经有200年的历史,既然K线能成为各种软件的主图;说明在技术分析的领域占有极其重要的位置。有的人说看K线没有用,我承认现在主力的手法变化莫测,各种骗线、震仓让人头晕目眩,但我们可以利用均线、成交量辅助分析;有经验的朋友可以结合盘口观察来操作。
        K线组合尖三兵又叫多头三兵,尖三兵不是我们常说的红三兵,红三兵是起步初升,而尖三兵是拉升,作为做短线时间短、收益高是我们追求的目标;尖三兵是我短线选股的方法之一,在股票书籍上是看不到的。
       K线组合:尖三兵 
    “尖三兵”由3根K线组合而成:第一天为阳线;第二天为长上影线的阳线(阴线也可);第三天为大中阳线,要求第三天阳线的收盘价格必须高于第二天K线的最高价。
       “尖三兵”的市场意义为:某股经过一段时间的缩量下跌,以阳线止跌起稳,然后主力试盘兼洗盘,主力目的达到后主力继续吃货形成放量的大阳线,第三天阳线的收盘价格高于第二天K线的最高价说明主力做多意愿坚决。当你发现这种K线组合买入后很快就有不菲的收益。提示:认真分析该股近段时间的消息与基本面以及市场环境,防止主力骗线。

 (ref(c,2)>ref(c,3) and c>ref(h,1) and  (c-ref(c,1))/ref(c,1)*100>=3 and

(ref(h,1)-max(ref(c,1),ref(o,1)))>1.5*abs(ref(o,1)-ref(c,1)));  

 
三串阴
STAR:EVERY(CLOSE<OPEN,3);
 
缩量

VOL/REF(VOL,1)<0.5;
 
共振
{15分钟,30分钟,60分钟,日线MACD共振}
DIF:= EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:= EMA(DIF,9);
MACD:=2*(DIF-DEA);
DIF60:=MACD.DIF#MIN60(12,26,9);
DIF30:=MACD.DIF#MIN30(12,26,9);
DIF15:=MACD.DIF#MIN15(12,26,9);
DEA60:=MACD.DEA#MIN60(12,26,9);
DEA30:=MACD.DEA#MIN30(12,26,9);
DEA15:=MACD.DEA#MIN15(12,26,9);
选股:CROSS(DIF,DEA) AND CROSS(DIF60,DEA60)AND CROSS(DIF30,DEA30) AND CROSS(DIF15,DEA15);
 
MACD

VAR1:=(EMA(C,12)-EMA(C,26))*100+50;
VAR2:=EMA(VAR1,9);
VAR3:=((HHV(H,21)-C)/(HHV(H,21)-LLV(L,21)))*100-10;
VAR4:=((C-LLV(L,21))/(HHV(H,21)-LLV(L,21)))*100;
VAR5:=SMA(VAR4,13,8);
VAR6:=SMA(VAR3,21,8);
VAR7:=MA(C,80)-MA(C,10)/7;
VAR8:=EMA(C,5);
VAR9:=MA((LLV(C,9))*1.1,14);
VAR10:=2*VAR9-VAR8-C*0.1;
VAR11:=IF(((VAR8-VAR10)*5>0),(POW((VAR8-VAR10)*5,2))/10,(-1*(POW((VAR8-VAR10)*(5),2)))/(10));
VAR12:=IF((VAR11>0),VAR11-0,12);
VAR13:=SMA(MAX(C-REF(C,2),0),7,1)/SMA(ABS(C-REF(C,2)),7,1)*100; 
趋势:=CEILING(SMA(VAR5,13,8));
看底:趋势-VAR6<-65;
 
MACD,KDJ金叉
DIF:=(EMA(CLOSE,12)-EMA(CLOSE,26))*100;
DEA:=EMA(DIF,9);
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=SMA(RSV,9,1);
D:=SMA(K,9,1);
B4:CROSS(DIF,DEA) AND CROSS("KDJ.K"(9,3,3),"KDJ.D"(9,3,3));

 
六脉神剑

DIFF:=EMA(CLOSE,8)-EMA(CLOSE,13);
DEA:=EMA(DIFF,5);
A1:=DIFF>DEA;
RSV1:=(CLOSE-LLV(LOW,8))/(HHV(HIGH,8)-LLV(LOW,8))*100;
K:=SMA(RSV1,3,1);
D:=SMA(K,3,1);
A2:=K>D;
LC:=REF(CLOSE,1);
RSI1:=(SMA(MAX(CLOSE-LC,0),5,1))/(SMA(ABS(CLOSE-LC),5,1))*100;
RSI2:=(SMA(MAX(CLOSE-LC,0),13,1))/(SMA(ABS(CLOSE-LC),13,1))*100;
A3:=RSI1>RSI2;
RSV:=-(HHV(HIGH,13)-CLOSE)/(HHV(HIGH,13)-LLV(LOW,13))*100;
LWR1:=SMA(RSV,3,1);
LWR2:=SMA(LWR1,3,1);
A4:=LWR1>LWR2;
BBI:=(MA(CLOSE,3)+MA(CLOSE,6)+MA(CLOSE,12)+MA(CLOSE,24))/4;
A5:=CLOSE>BBI;
MTM:=CLOSE-REF(CLOSE,1);
MMS:=100*EMA(EMA(MTM,5),3)/EMA(EMA(ABS(MTM),5),3);
MMM:=100*EMA(EMA(MTM,13),8)/EMA(EMA(ABS(MTM),13),8);
A6:=MMS>MMM;
涨买入:IF((A1 AND A2 AND A3 AND A4 AND A5 AND A6) AND REF(A1 AND A2 AND A3 AND A4 AND A5 AND A6,1)=0,7,0);
 
 
股价站到10日线上(数字10可任意修改) 
CROSS(MA(C,1),MA(C,10));
 
 
均线收阴或是多头阴线
MA(C,5)>MA(C,10) AND MA(C,10)>MA(C,30) AND MA(C,30)>MA(C,60) AND O>C;
 
跌破5日线
A1:=MA(CLOSE,5);
A2:=MA(CLOSE,10);
A3:=MA(CLOSE,20);
A4:=MA(CLOSE,60);
A1>A2 AND A2>A3 AND A3>A4 AND CLOSE<A1;
 
主升浪
参数   最小   最大    缺省
 N    2.00   100.00   10.00
VAR1:=LLV(LOW,10);
VAR2:=HHV(HIGH,25);
AA:= EMA((CLOSE-VAR1)/(VAR2-VAR1)*4,4);
BB:=C>O AND ((C-REF(C,1))/REF(C,1))>0.03;
DME:=HHV(MA(HIGH,3),2);
STI:=LLV(MA(HIGH,3),1);
DIF:=(STI-DME);
CC:=ABS(STI-DME)<0.1 AND (ABS(REF(DIF,1))>ABS(DIF));
主升浪选股:AA<2.5 AND DYNAINFO(4)>0 AND BB AND CC;
 
老鼠仓
AA1:=AMOUNT/V; 
BB1:=L<AA1*0.9; 
CC1:=(C-REF(C,1))/REF(C,1)*100>1.2; 
DD1:=L<MA(C,5)*0.921; 
EE1:=V<MA(V,5)*1.5; 
FF1:=BB1 AND CC1 AND DD1 AND EE1; 
DRAWTEXT(FF1,(LOW* 0.97),'老鼠仓'),COLOR4080FF; 
 

盘中横盘
BETWEEN(ABS((C-DYNAINFO(11))/C),0,0.02) AND 
BETWEEN(ABS((C-DYNAINFO(4))/C),0,0.02) AND 
HIGH<=DYNAINFO(4)*1.02 AND
LOW>=DYNAINFO(4)*0.98 AND
DYNAINFO(4)>=DYNAINFO(3);
 
均线量线
参数   最小   最大    缺省
 N    2.00   100.00   10.00
M1:=MA(CLOSE,5);
M2:=MA(CLOSE,10);
MA1:=MA(VOL,5);
MA2:=MA(VOL,10);
DIF:=EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:=EMA(DIF,9);
A1:=DEA;
F1:=DIF;
K1:="KDJ.K";
J1:="KDJ.J";
金叉1:=CROSS(M1,M2);
金叉2:=CROSS(MA1,MA2);
金叉3:=CROSS(F1,A1);
金叉4:=CROSS(J1,K1);
选1:=金叉1 AND 金叉2 AND 金叉3 AND 金叉4;
选2:=金叉1 AND 金叉2 AND 金叉3;
选3:=金叉2 AND 金叉3 AND 金叉4;
选4:=金叉1 AND 金叉2 AND 金叉4;
选5:=金叉1 AND 金叉3 AND 金叉4;
选股:选1 OR 选2 OR 选3 OR 选4 OR 选5; 
  
均量线
V1:=CROSS(MA(V,10),MA(V,20)); 
V2:=CROSS(C,MA(C,20));
V3:=COUNT(CROSS(MA(V,5),MA(V,10)),5)=1; 
V4:=MA(C,5)>REF(MA(C,5),1) AND REF(MA(C,5),1)<REF(MA(C,5),2) AND
C>MA(C,5);
均价量线XG:IF(V1 AND V2 AND V3 AND V4,1,0);
 
底背离黑马
DIFF:=EMA(DCLOSE,12)-EMA(DCLOSE,26);
DEA:=EMA(DIFF,9),COLORFFFF00;
A1:=BARSLAST(REF(CROSS(DIFF,DEA),1));
底背离:=REF(CLOSE,A1+1)>CLOSE AND DIFF>REF(DIFF,A1+1) AND CROSS(DIFF,DEA);
DEA0:=EMA(DIFF*100,9);
MACD0:=2*(DIFF*100-DEA0);
黑马:=(MACD0>REF(MACD0,1)*2.5 AND MACD0>15);
底背离 AND 黑马;
 
四线合一
参数   最小   最大    缺省
 N    2.00   100.00   2.00
MA5:=MA(CLOSE,5);
MA24:=MA(CLOSE,24);
A1:=MA(VOL,5);
A2:=MA(VOL,60);
四线合一:CROSS(MA5,MA24) AND CROSS(A1,A2);
 
四线粘合
MA1:=MA(C,5);
MA2:=MA(C,10);
MA3:=MA(C,20);
MA4:=MA(C,30);
P2:=ABS(MA1-MA2)+ABS(MA2-MA3)+ABS(MA1-MA4)
+ABS(MA2-MA4)+ABS(MA3-MA4)+ABS(MA1-MA3);
四线粘合:IF(P2/C<6/100 AND MA1>REF(MA1,1) AND MA2>REF(MA2,1),666,0)COLORYELLOW,LINETHICK;
 
均线量线金叉见底
DIFF1:=EMA(CLOSE,12)-EMA(CLOSE,26);
DEA1:=EMA(DIFF1,9);
MACDD:=CROSS(DIFF1,DEA1);
均线1:=CROSS(MA(C,5),MA(C,10));
量线1:=CROSS(MA(V,5),MA(V,10));
DRAWICON(MACDD AND 均线1 AND 量线1,L-0.20,9);{同时金叉显示9号图标};
 
黄金买卖
AA:=(O+H+L+C)/4;
B1:=HHV(AA,60);
B2:=LLV(AA,60);
B3:=B1-B2;
B4:=EMA((AA-B2)/B3,2)*100;
中期:=B4;
XG:FILTER(中期>REF(中期,1)AND 中期<5 AND C>REF(C,1),5);
 
梅开二度
MA60:=MA(VOL,60); 
TJ1:=VOL=HHV(VOL,10) AND VOL>1.7*REF(VOL,1) AND C>=REF(C,1) AND C>=O AND VOL<=MA135*3.5;
LJL:=FILTER(TJ1,3);
TJ3:=IF(BARSLAST(LJL)=1 AND CLOSE>REF(LOW,3),1,0);
ST:=TJ3=1;
CL:=FILTER(ST,3);
STICKLINE(LJL,OPEN,CLOSE,1,0),;  
 

低阳倍量
BLZ:=VOL>REF(V,1)*1.9;
倍量柱:=BLZ,COLORYELLOW;
HJZ:=(3*C+H+L+O)/6;
HJZ2:=(8*HJZ+7*REF(HJZ,1)+6*REF(HJZ,2)+5*REF(HJZ,3)+4*REF(HJZ,4)+3*REF(HJZ,5)+2*REF
(HJZ,6)+REF(HJZ,8))/36;
黄金柱:=VOL=HHV(VOL,10) AND VOL>2*REF(VOL,1) AND CLOSE>HJZ2 AND C>O;
倍量黄金柱:=倍量柱 AND 黄金柱;
REF(倍量黄金柱,3);
 
复合顾比
K1:=EMA(C,5);
K2:=EMA(C,10);
K3:=EMA(C,20) ;
K4:=EMA(C,30);
K5:=EMA(C,60) ;
K6:=EMA(C,120);
K7:=EMA(C,250);
K1>K2 AND K2>K3 AND K3>K4 AND K4>K5 AND K5>K6 AND K6>K7;
 
涨停公式
T:=IF((BARSCOUNT(C) > 7),(100)*((MA(C,7))/(LLV(MA(C,7),7)) - 1),1);
N:=IF((T > 0.35),6,65);
W:=((-((100)*(HHV(H,N) - C))/(HHV(HIGH,N) - LLV(L,N))));
RV:=(CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100;
RG:=(CLOSE-LLV(LOW,5))/(HHV(HIGH,5)-LLV(LOW,5))*100;
J0:=(HIGH+LOW)/2;
QJ:=EMA(J0,3);
J1:=IF(CLOSE>QJ,VOL,0);
J2:=IF(CLOSE<QJ,VOL,0);
BB:=MA(SUM(J1-J2,22),3);
累加:=21*BB+20*REF(BB,1)+19*REF(BB,2)+18*REF(BB,3)+17*REF(BB,4)
+16*REF(BB,5)+15*REF(BB,6)+14*REF(BB,7)+13*REF(BB,8)+12*REF
(BB,9)+11*REF(BB,10)+10*REF(BB,11)+9*REF(BB,12)+8*REF(BB,13)
+7*REF(BB,14)+6*REF(BB,15)+5*REF(BB,16)+4*REF(BB,17)+3*REF
(BB,18)+2*REF(BB,19)+REF(BB,20);
WM:=累加/(21+1)/21*2;
CC:=WM;
VAR3:=(BB-CC);VAR4:=SMA(RV,3,1);
VAR5:=SMA(VAR4,3,1);
KK:=EMA(SMA(RG,3,1),2);
DD:=SMA(KK,3,1);
涨停100%:CROSS(W,-2) AND CROSS(VAR4,VAR5) AND CROSS(KK,DD);
 
双阴阳
JX:=EVERY(MA(C,5)<REF(MA(C,5),1),3);
DF:=(C-REF(C,1))/REF(C,1)*100;
SY:=REF(C>O AND C>REF(C,1),1) AND C>O AND O<REF(C,1) AND C/REF(C,1)<1.02;
XG:JX AND REF(DF,2)<-2 AND SY;
 
倍量过左峰
{1.黄金柱}
JJ:=(3*C+H+L+O)/6;
VAR1:=(8*JJ+7*REF(JJ,1)+6*REF(JJ,2)+5*REF(JJ,3)+4*REF(JJ,4)+3*REF(JJ,5)+2*REF(JJ,6)+REF(JJ,8))/36;
TJ1:=VOL=HHV(VOL,10) AND VOL>2*REF(VOL,1) AND CLOSE>VAR1 AND C>REF(C,1);
LJL:=FILTER(TJ1,3);
黄金线:=REF(LOW,BARSLAST(LJL));
黄金柱:=FILTER(TJ1,3);
{2.倍量过左峰}
SR1:=REF(HIGH,10)=HHV(HIGH,2*10+1); 
SR2:=FILTER(SR1,10); 
SR3:=BACKSET(SR2,10+1); 
HD:=FILTER(SR3,10); 
前高:=REF(H,BARSLAST(HD));
倍量:=(VOL/REF(VOL,1)>2 AND COUNT(CLOSE>OPEN,1)) OR (LOW>REF(HIGH,1) AND COUNT(OPEN>CLOSE,1) AND VOL/REF(VOL,1)>2);
突破前高:=CROSS(C,前高);
倍量过左峰:= 突破前高 AND 倍量;
{3.凹口起柱}
T7:=REF(VOL,6)/REF(VOL,7)>=2;
T6:=REF(VOL,5)/REF(VOL,6)>=2;
T5:=REF(VOL,5)/REF(VOL,4)>=1.5;
T4:=REF(VOL,4)/REF(VOL,3)>=1.5;
T3:=REF(VOL,2)/REF(VOL,3)>=1.5;
T1:=V/REF(VOL,1)>2;
T0:=C>O AND C>REF(C,1);
凹口起柱:= T7 AND T1 AND T0 OR T6 AND T1 AND T0 OR T5 AND T1 AND T0 OR T4 AND T1 AND T0
OR T3 AND T1 AND T0 ;
{凹口起柱}
AKQZ:= 黄金柱 AND 凹口起柱;
{4.前高低位}
X:=21;
TTY:=H;
AAT:=REF(TTY,X)=HHV(TTY,2*X+1);
BBT:=FILTER(AAT,X);
CCT:=BACKSET(BBT,X+1);
HD10T:=FILTER(CCT,X);
AA1T:=REF(TTY,X)=LLV(TTY,2*X+1);
BB1T:=FILTER(AA1T,X);
CC1T:=BACKSET(BB1T,X+1);
LD10T:=FILTER(CC1T,X);
前期高位:=REF(H,BARSLAST(HD10T));
前期低位:=REF(L,BARSLAST(LD10T));
{突破前高}
TPQG:= 黄金柱 AND 倍量过左峰 AND C>前期高位;
{选股}
XG: (COUNT(TPQG,10) OR COUNT(AKQZ,10)) AND COUNT(CROSS(黄金线*1.01,L),3)>0 AND L>=黄金线 AND C>REF(C,1) AND REF(C,2)>REF(C,1) AND COUNT(LJL,3)=0;



 
均线多头排列超强选股法

    通俗点说均线多头排列,就是说5日线在最上面,其次是10日线,20日线.30日线,所有的均线都是向上趋势,多头排列表明现在持有这个股票的人几乎都是获利的。多头排列的股票肯定是上涨的。
    对短线操作来说,更是如此.不论是追涨还是抓突破性买入机会,主要考虑的因素就是市场态势及个股的均线排列形态.一定要回避盘整走势,重点选择各周期均线完全多头排列的品种参与,中长期均线至少要处于走平状态.
 
通达信均线多头排列选股公式
N   1   500   5
N1   1  500   10
N2   1  500   20
N3   1  500   30
A1:=MA(CLOSE,N);
A2:=MA(CLOSE,N1);
A3:=MA(CLOSE,N2);
A4:=MA(CLOSE,N3);
CLOSE>A1 AND A1>A2 AND A2>A3 AND A3>A4 AND CLOSE>OPEN;
A1赋值:收盘价的N日简单移动平均
A2赋值:收盘价的N1日简单移动平均
A3赋值:收盘价的N2日简单移动平均
A4赋值:收盘价的N3日简单移动平均
收盘价>A1 AND A1>A2 AND A2>A3 AND A3>A4 AND 收阳线
均线系统呈多头排列,多方占据一定优势.
 
极品【DDE均线多头选股公式】  通达信
{DDE均线多头选股公式}
JUJ:=(HIGH+LOW+CLOSE)/3;
QUJ0:=VOL/IF(HIGH=LOW,4,HIGH-LOW);
QUJ1:=IF(CAPITAL=0,QUJ0*(JUJ-MIN(CLOSE,OPEN)),QUJ0*IF(HIGH=LOW,1,(MIN(OPEN,CLOSE)-LOW)));
QUJ2:=IF(CAPITAL=0,QUJ0*(MIN(OPEN,CLOSE)-LOW),QUJ0*IF(HIGH=LOW,1,(JUJ-MIN(CLOSE,OPEN))));
QUJ3:=IF(CAPITAL=0,QUJ0*(HIGH-MAX(OPEN,CLOSE)),QUJ0*IF(HIGH=LOW,1,(HIGH-MAX(OPEN,CLOSE))));
QUJ4:=IF(CAPITAL=0,QUJ0*(MAX(CLOSE,OPEN)-JUJ),QUJ0*IF(HIGH=LOW,1,(MAX(CLOSE,OPEN)-JUJ)));
QUJ5:=QUJ1+QUJ2;
QUJ6:=QUJ3+QUJ4;
DD:=(QUJ5-QUJ6)/(QUJ5+QUJ6)*100;
DDZ:=DD*17;
DDX:=((QUJ1+QUJ2)-(QUJ3+QUJ4))/IF(CAPITAL=0,1000000,10000);
DX:=MA(DDX,5)*20;
DDX1:=SMA(DX,3,1);
DDX2:=SMA(DDX1,3,1);
DDX3:=EMA(DDX2,5);
DDY:=((QUJ2+QUJ4)-(QUJ1+QUJ3))/IF(CAPITAL=0,1000000,10000);
DY:=MA(DDY,5)*22;
DDY1:=SMA(DY,3,1);
DDY2:=SMA(DDY1,3,1);
DDY3:=EMA(DDY2,5);
CC:=ABS(REF(CLOSE,1)-CLOSE)/CLOSE*100;
JJ:=CC>0 AND CC<3;
AA:=DDX1>DDX2 AND DDX2>DDX3 AND DDX1>DDX3;
BB:=DDY1>DDY2 AND DDY2>DDY3 AND DDY1>DDY3;
HH:=AA>0 AND BB>0 AND DDZ>300 AND JJ>0;
HH>0;
 
短期均线多头排列 通达信
A1:=MA(CLOSE,5);
A2:=MA(CLOSE,10);
A3:=MA(CLOSE,20);
A4:=MA(CLOSE,30);
CLOSE>A1 AND A1>A2 AND A2>A3 AND A3>A4 AND CLOSE>OPEN;
 
多头双阴回打5-10日均线多头双阴回打选股
MA5:=MA(C,5);MA10:=MA(C,10);
A1:=MA5>=REF(MA5,1) AND MA5>=MA10;
A2:=C<O AND REF(C,1)<REF(O,1);
A3:=BETWEEN(C,MA10,MA5*1.01);
A1 AND A2 AND A3;
 
均线多头粘合选股的公式
参数可以自行设置:D为均线多头排列天数,N1,N2,N3为涨幅限制,可根据自己需要设置!
MA5:=MA(CLOSE,5);
MA10:=MA(CLOSE,10);
MA20:=MA(CLOSE,20);
MA30:=MA(CLOSE,30);
A1:=MA5>MA10 AND MA10>MA20 AND MA20>MA30 AND ALL((MA5>MA10 AND MA10>MA20 AND MA20>MA30),D);
A2:=((MA5-MA10)/MA5)*100<N1 AND ((MA10-MA20)/MA10)*100<N2 AND ((MA20-MA30)/MA20)*100<N3;
A3:=A1 AND A2;
FILTER(A3,5);

股价涨幅不大,找放量的
C/REF(C,3)<1.4 AND C/REF(C,5)<1.5  AND C/REF(C,10)<1.6  AND C/REF(C,20)<2 AND C/REF(C,60)<3 AND C/REF(C,120)<3;




  选股小技能(含公式源码)

  1,30个交易日内,股价跌幅达到一半的股票:
xg:(hhv(c,30)-c)/hhv(c,30)>0.5;
 2,今天的量  是5天平均的 2倍以上  
xg:v>ma(v,5)*2;
 缩量
vol/ma(vol,10)<0.3;
 3,两天内,累计下跌等于或超过20%选股.
 xg:(ref(c,2)-c)/c>0.2;
 4,股价是25天以来新低. 
 xg:c<ref(llv(c,25),1);
5,选股:EXPMA 5日与10日金叉 并且第二天的收盘价在EXPMA的5日线以上.
cross(ref(ema(c,5),1),ref(ema(c,10),1)) and c>ema(c,5);
 6,请编买入公式:
1. 将BIAS指标的参数设置为24日,将KD指标的参数设置为9;3;3。
2. BIAS指标要小于-6,这只是确认该股超跌的初选条件。
3. KD指标产生黄金交叉,K线上穿D线。
4. KD交叉同时,KD指标中的D值要小于16。
BIAS3 :=(CLOSE-MA(CLOSE,24))/MA(CLOSE,24)*100,colorff00ff;
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=SMA(RSV,3,1),COLORWHITE;
D:=SMA(K,3,1),COLORYELLOW;
xg:BIAS3<-6 and cross(k,d) and d<16;
 7,要求是量大、换手率达到3左右,涨幅>7个点。
xg:v/capital*100>3 and (c/ref(c,1)>1.07;
 8,个股分时图上都有一条黄线,叫做均价线
 a/capital*100;
9,"阴转阳"的公式(也就是昨天收阴线,今天收阳线)
 xg:ref(c,1)<ref(o,1) and c>o;
 10,股价回抽20日均线选股公式
 xg:ref(c,1)>ma(c,20) and cross(ma(c,20),c);
 11,一根大阳线,至少有5个点以上,再连着出现二根振幅不大于5的十字星或是小K线
 xg:(ref(c,3)-ref(c,4))/ref(c,3)>0.05 and count((h-l)/l<0.05,2)=2;
12,行情信息里的“涨幅”的原码
 (c-ref(c,1))/c*100;
13,kdj的J从上向下穿越O轴发出信号
 RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=SMA(RSV,3,1),COLORWHITE;
D:=SMA(K,3,1),COLORYELLOW;
J:=3*K-2*D,COLORFF00FF;
xg:cross(0,j);
 14,股价4天中有两天在10日线上
count(c>ma(c,10),4)=2;
15,选出10天内出现了涨停的个股
 count(c/ref(c,1)>1.1,10)>0;
 又:
今涨停:=C/REF(C,1)>1.09;
选股:count(今涨停,n);
 16,一阳上穿10,20,30日线,量能是前一天3倍。
 xg:cross(c,ma(c,10)) and cross(c,ma(c,20)) and cross(c,ma(c,30)) and v>ref(v,1)*3;
 17,共三根K线,第一根K线为阴线;第二根K线为阴线线,最高价低于第一根K线,最低价高于第一根K线;第三根K线阴阳不限,最高价低于第二根K线,最低价高于第二根K线。满足后发出信号~
w1:=ref(c,2)<ref(o,2);
w2:=ref(h,2)>ref(h,1) and ref(l,2)<ref(l,1);
w3:=ref(h,1)>h and ref(l,1)<l;
xg:w1 and w2 and w3;
 18, 选出今日成交量大于昨日成交量一成的股票。
 xg:v>ref(v,1)*1.1;
 19, 连续5天,当日的5日均线减前一天的5日均线差值小于1.
 count((ma(c,5)-ref(ma(c,5),1))<1,5)=5;
 20,股价上穿5周均线:
xg:cross(c,ma(c,5));
注意:选股时用周线
 21,上穿30日均线的公式
xg:cross(c,ma(c,30));
22,两笔阴线中间夹着一根阳线或数根K线,其中两笔阴线最低点相等
 xg:ref(l,2)=l;
 23,量比大于1 同时换手大于2的公式
 xg:v/ref(v,1)>1 and AMOUNT/CAPITAL*100>2;
 24,换手:VOL*100/CAPITAL;
     周期换手:SUM(换手,10);
 25,流通盘小于4000万的选股公式 
 xg:CAPITAL/100<4000;
26,涨停开盘跌停收盘选股
xg:h/ref(c,1)>1.1 and ref(c,1)/l>1.1;
 27,当天开盘价与收盘价相等的选股公式
 xg:c=o;
28,5日均线向上 流通盘小于5000万 换手率大于3的选股公式 
 lt:CAPITAL/100<5000;
换手:=VOL*100/CAPITAL<3;
w1:ma(c,5)>ref(ma(c,5),1);
xg:lt and 换手 and w1;
29,收下影线
 xg:c>l;
30, o=l就没有下引线了,那就:
xg:c>l and o>l;
 31,当日收盘下穿5日均价
 xg:cross(ma(c,5),c);
 32,最低价小于前一日的最低价但收盘后为阳线。
xg:l<ref(l,1) and c>o;
 33,30日内到本日收盘价下跌20%的公式
 xg:hhv(c,30)/c>1.2;
 34,选周线跳空缺口的个股。
 xg:HIGH<REF(LOW,1) OR
LOW>REF(HIGH,1);
周期选周线
35,30日均线走平或走高的个股
 xg:ma(c,30)>ref(ma(c,30),1);
 36,连续4天的收盘价格波动幅度在3%之内连续走平或向上
 count(abs(c-ref(c,1)/ref(c,1))<0.03 and c>ref(c,1),3)=3;
 37,下影线长于上影线 
 (c-l)>(h-c);
 38, 收盘价+收盘价的10%
(c+c*0.1);
 39,今天高开的公式
 c>o;
  40,今天的量大于等于昨天量的2倍,股价上涨
xg:v>ref(v,1)*2 and c>ref(c,1);
 41,今天的量小于昨天量的2倍以上,股价上涨
xg:v<ref(v,1)*2 and c>ref(c,1);
  42,大部分股票跌到43日均线时就会反弹,如果在43日均线附近买入,短线成功率占90%以上,即时选出还差几分钱就跌到43日均线的股票。
xg:abs(c-ma(c,43))/ma(c,43)<0.01;
 43,{选出每天换手5%-15%之间的股票}
Var1:=100*VOL/CAPITAL;
w1:=var1>5;
w2:=var1<15;
xg:w1 and w2;
 44,换手率10天80%以上的选股公式
sum(VOL/CAPITAL*100,10)>80;
 45,60个交易日内,涨幅大于9.9%(涨停)的天数
 count(c/ref(c,1)>1.099,60);
 46,昨天跌幅大于3%,今天开盘高开2%以上的选股公式。
 xg:ref(c,1)/ref(c,2)<0.97 and o/ref(c,1)>1.02;
 47,选出周换手率小于10%的股票
 sum(VOL/CAPITAL*100,5)<10;
 48,成交量创20日新低,并且股价也创20日新低
 xg:v=llv(v,20) and c=llv(c,20);
  49,5日不涨,绿线收盘选票指标
 count(c<o,5)=5;
  50,"今日MACD等于昨天的MACD  ,且macd>0"  的指标
DIFF:=EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
xg:macd=ref(macd,1) and macd>0
  51,连续2天收盘价跌破30日均线,就显示"卖出"信号
 a1:count(c<ma(c,30),2)=2;
drawtext(a1,c,'卖出'),colorgreen;
 52,股票在这条均线上在8天以上,上下幅度不大,
 a1:abs((c-ma(c,120))/ma(c,120))<0.1;
xg:count(a1,8)=8;
 53, 连续三天高开高走的选股公式
count(o>ref(c,1) and c>o,3)=3;
  54,n天内曾经有m个涨停
 count(c/ref(c,1)>1.09,n)>m;
  55,股价比昨天的高,量比昨天小,放量。
xg:c>ref(c,1) and v<ref(v,1) and ref(v,1)>ref(v,2)*2;
 56,连续3天每天的最低价都比前一天高
count(l>ref(c,1),3)=3;
  57,周量缩小50%或40%或n%
 a1:vol/capital*100;
xg:a1/ref(a1,1)<n/100;
  58,股价超过五日均价的15%以上,并给出卖出信号
 卖出:c/ma(c,5)>1.15;
 59,连收两个十字星的选股公式
 count(abs((c-o)/o<0.01),2)=2;
60,n横盘天数,n1横盘的上下幅度
REF(((HHV(H,N)-LLV(L,N))/LLV(L,N)),1)<=(n1/100)
and ref(v,1)<ref(ma(v,5),1) and cross(v,ma(v,5)) and cross(v,ma(v,10));
 61,收盘价连续8天都站在5日均线的股票。
 count(c>ma(c,5),8)=8;
 62,振幅大于5%,收盘价大于3.5小于15元,三日均线大于昨日的三日均线,去掉ST股。
 a1:=h/l>1.05;
a2:=c>3.5 and c<15;
a3:=ma(c,3)>ref(ma(c,3),1);
xg:a1 and a2 and a3;
63,收盘价下有60天前的远期获利盘n%。
{60天前的远期获利盘:=ppart(60)*100;} 
 aa:WINNER(ref(c,60 ))*100;
 64,连续三日收阳后日收盘高于前日且每日收于当日最高价附近每日涨幅不大于4%
选股:count(c>o and c>ref(c,1) and abs((h-c)/c)<0.01 and c/ref(c,1)<1.04,3)=3;
 65,昨日收阴, 今日收阳,的K线组合。
 C>O AND REF(C,1)<REF(O,1);
 66,股价突破5ma买入,跌破5ma卖出。买入和卖出用箭头表示(副图)
a1:cross(c,ma(c,5));
a2:cross(ma(c,5),c);
drawtext(a1,low*0.98,'↑'),colorred;
drawtext(a2,h*1.02,'↑'),color00ffff;
 67,今天的250平均线大于昨天的昨天的250平均线
 ma(c,250)>ref(ma(c,250),1);
 68,历史高点到前一高点画线
 POLYLINE(h>=hhv(c,0),h);
  69,均线中增加一根线,这根线的价格是5日线的1.2倍
aa:ma(c,5)*1.2;
  70,20天均线向上的股
 xg:ma(c,20)>ref(ma(c,20),1);
 71,连续3天收盘全是阴线。
 count(c<ref(c,1),3)=3;
 72,今天收盘价在昨天收盘价-2%~2%之间
c/ref(c,1)>0.98 and c/ref(c,1)<1.02;
  73,收盘价在5日均线以上5天
 count(c>ma(c,5),5)=5;
 74,N天前换手率大于8%  
REF(VOL/CAPITAL*100,N)>8;
 75,一条均线18MA  股价上涨后“缩量”回调到18MA
  XG:COUNT(V<REF(V,1) AND C<O,N)=N AND C>MA(C,18);
N  “缩量”回调的天数
 76,1。昨日量是n天以来最低量,(n可调);2。今日量是昨日量的m倍,(m可调);3。今日k线收阳线;
 xg:ref(v,1)=llv(ref(v,1),n) and v>ref(v,1)*m and c>o;
 77,第一天收阴,第二天,第三天,第四天,收出红三兵
 XG:REF(C,3)<REF(C,4) AND COUNT(C>O,3)=3;
 78,月k线十字星收盘  并且5月线拐点向上。
 XG:ABS(C-O)/O<0.02 AND MA(C,5)>REF(MA(C,5),1);
用月线选股
 79,最近3天(包括昨天.前天)股价突破250日均线
COUNT(C>MA(C,250),3)=3;
 80,跳高大阴线,条件: 1 开盘跳空4%以上2 大阴线实体6%以上.
O/REF(C,1)>1.04 AND C/REF(C,1)<0.94;
 81,条件:1: 假设大前天创最近新高,要求这天涨幅是超过7%的大阳线,且创最近一个月的新高.
         2: 那么前天,昨天,今天都收小K线,要求小K线实体
xg:ref(c,3)/ref(c,4)>1.07 and ref(c,3)=hhv(c,20) and count(abs((c-ref(c,1))/ref(c,1)<0.02,3)))=3;
  82,60与120均线距离在n%内
 XG:ABS((MA(C,60)-MA(C,120))/MA(C,120))<N/100;
 83,5日均线倾角大于60度
X:(ATAN((MA(C,5)/REF(MA(C,5),1)-1)*100)*180/3.1415926)>60;
也可以这样:
X:(ATAN((EMA(C,5)/REF(EMA(C,5),1)-1)*100)*180/3.1415926)>60;
利用指标排序:
X:(ATAN((MA(C,5)/REF(MA(C,5),1)-1)*100)*180/3.1415926);
84,“中阴之后,跳拉阳”
c/ref(c,1)>1.05;
 85,count(x,n) 意思是n天内出现过信号的,假设n=10,那么就是10天内出现信号(包括今天),如果不加这个的话,就是限定在今天出信号才选出来,以前的不管。
86, 今天涨停的公式
C/REF(C,1)>1.09;
 87,10日内有涨停的公式
今涨停:=C/REF(C,1)>1.09;
选股:count(今涨停,10);
 88,昨日前日涨停的
REF(C,1)/REF(C,2)>1.095;
 89,近5日K线最高价和最低价格波动在10%以内,成交量是昨日2倍,收盘涨5%
XG:(HHV(C,5)-LLV(C,5))/LLV(C,5)<0.1 AND V>REF(V,1)*2 AND C/REF(C,1)>1.05;
90,60与120均线距离在n%内
XG:ABS((MA(C,60)-MA(C,120))/MA(C,120))<N/100;
 91,“中阴之后,跳拉阳”
c/ref(c,1)>1.05;
  92,能在图上提示个股(不含S或ST股)出现过的涨跌停板日期的公式
w1:if((c-ref(c,1))/ref(c,1)>0.1,date-1000000,c);
  93,涨幅≤2%
 (c-ref(c,1)/ref(c,1)*100<2;
  94,5日,10日,30日贴近公式,越贴越好
m1:=ma(close,5);
m2:=ma(close,10);
m3:=ma(close,20);
m4:=ma(close,30);
y1:=max(max(max(m1,m2),m3),m4);
x1:=min(min(min(m1,m2),m3),m4);
黏合:y1/x1<n;
n越小越黏合(n,1.01-----1.05)
 95,(1)换手率均线DMA(c ,v/CAPITAL );
(2)20天以来的任意天期(n),换手率均线正负波动值<=p%;
AA:=DMA(c ,v/CAPITAL );
ab:=(aa-ref(aa,1))/ref(aa,1)*100<p;
bb:count(ab,20)>=n;
96, 30天线拐头向上出现提示
ma(c,30)>ref(ma(c,30),1);
97,今天的换手率大于前天的一倍以上
w1:=v*100/capital;
w1>ref(w1,2)*2;
98,K线沿着5日均线往上爬的选股公式
w1:ma(c,5);
w2:abc(c-w1)/w1<0.01;
xg:count(w1>ref(w1,1),5)=5 and w2;
 99,20日均线,上穿62日均线
xg:cross(ma(c,20),ma(c,62));
  100,平台整理的公式,整理时间和整理幅度可调
COUNT(CLOSE,0)>N AND
(HHV(CLOSE,N)-LLV(CLOSE,N))/LLV(CLOSE,N)<=(N1/100);
N整理时间,N1整理幅度
101,选出当日收盘价突破10日均线5%的个股
cross(c,ma(c,10)*1.05);
 102,选出当日最低价在10日均线上下0.05%内,收盘价在均线上方的个股
abs(l-ma(c,10))<0.005 and c>ma(c,10);
 103,第一天股票涨停,第二天成交量是第一天成交量的1倍,并超过10%.那第三天就是买点
w1:=ref(c,2)/ref(c,3)>1.1;
w2:=ref(v,1)/ref(v,2)>2;
xg:w1 and w2;
104,放量2倍突破300日线的选股指标
cross(c,ma(c,300)) and v>ref(v,1)*2;
105,3日均线上穿10日均线,KDJ有效金叉
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=SMA(RSV,3,1);
D:=SMA(K,3,1);
J:=3*K-2*D;
w1:=cross(ma(c,3),ma(c,10));
xg:w1 and cross(k,d);
  106,30日均线拐头向上
 ma(c,30)>ref(ma(c,30),1);
 107,连续3-5天,每天的收盘价涨跌幅不超过1%.
 w1:abs(c-o)<0.01;
xg:count(w1,5)>=3;
 108,K线收十字星
 abs(c-o)/o<0.01;
 109,MACD在8天以内两次金叉
DIFF:=(EMA(CLOSE,12) - EMA(CLOSE,26));
DEA:=EMA(DIFF,9),COLORBLUE,LINETHICK0;
MACD:=2*(DIFF-DEA);
w1:cross(DIFF,dea);
xg:count(w1,8)>=2;
 110,昨天升降幅在-n%----n%之间
w1:abs(ref(c,1)-ref(c,2))/ref(c,2)*100<n;
 111,于20日均线相差2个百分点的
w1:abs(c-ma(c,20)/ma(c,20)*100<2;
N日均线相差M个百分点的公式.
w1:abs(c-ma(c,n)/ma(c,n)*100<m;
n:N日 m:M个百分点
  112,60MA由向下调头向上
 ma(c,60)>ref(ma(c,60),1);
 113, 股价回调到14日均线的选股
abs(c-ma(c,14))/ma(c,14)<0.005;
 114,历史第5根K线到第30根K线之间的最高价
hhv(ref(c,5),25);
115,MACD的拐点公式
DIFF:=(EMA(CLOSE,12) - EMA(CLOSE,26));
DEA:=EMA(DIFF,9),COLORBLUE,LINETHICK0;
MACD:=2*(DIFF-DEA);
拐点:ref(macd,2)>ref(macd,1) and ref(macd,1)<macd;
 116,跳空高开收阳线
LOW>REF(HIGH,1) and c>o;
 117,涨停过300日线的选股公式
 c/ref(c,1)>1.09 and cross(c,ma(c,300));
  118,成交量是前5天中其他任何一天的10天均量线的3.5倍以上
 w1:=llv(ma(v,10),5);
xg:v>w1*3.5;
 119,股价N天内连续沿着5天线走,且每天收盘价与5天线的距离不超过2%的选股公式
 w1:=abs(c-ma(c,5))/ma(c,5)<0.02;
xg:count(w1,n)=n;
 120,跳空高开后,三天内没有回补缺口
 ref(LOW,2)>REF(HIGH,3) and l>ref(LOW,2);
 121,日涨幅小于3%
C>0    AND    C/REF(C,1)  >1.03;
122, 股价创30个交易日的新高
H>ref(H,30);
123,连续n天收阳线
UP:=CLOSE>OPEN;
COUNT(UP,N)=N;
 124, {5日内第二大量}
zdl:=hhv(v,5);
v0:=IF(v>=zdl,0,v);
v1:=IF(ref(v,1)>=zdl,0,ref(v,1));
v2:=IF(ref(v,2)>=zdl,0,ref(v,2));
v3:=IF(ref(v,3)>=zdl,0,ref(v,3));
v4:=IF(ref(v,4)>=zdl,0,ref(v,4));
第二大量:MAX(MAX(MAX(MAX(v0,v1),v2),v3),v4);
DRAWTEXTABS( 0,10 ,'第一大量 '+ zdl+'  第二大量'+第二大量);
同理可求出第三大、第四大和最小量.实行简单的排列.
这个公式好比是一件完整产品中的一个零部件,解决了一个思路问题.
 125,{5日均线倾角大于60度}
X:(ATAN((MA(C,5)/REF(MA(C,5),1)-1)*100)*180/3.14115926)>60;
 126,连续三涨停
A:=C/REF(C,1)>1.095;
XG:EVERY(A,3);
 127,30日线开始上翘
MA30:MA(C,30);
(MA30>REF(MA30,1)) AND (REF(MA30,1)<=REF(MA30,2));
 128,当收盘价大于10均线时,主图背景是黄色的,小于的时候是绿色的
ma10:=ma(c,10);
DRAWGBK(c>=ma10),colorred;
DRAWGBK(c<ma10),colorgreen;
 129,日涨幅小于3%
C>0  AND  C/REF(C,1)  >1.03;
 130,股价创30个交易日的新高
H>ref(H,30)
 131,3根阳线,并且第二根阳线的量比第一根小,第三根的量比第二根小
EY:=CLOSE>OPEN;
ZL:=VOL<REF(VOL,1);
XG:SUM(EY,3)=3 AND SUM(ZL,3)=3;
或者这样:
EY:=CLOSE>OPEN;
ZL:=VOL<REF(VOL,1);
XG:COUNT(EY,3)=3 AND COUNT(ZL,3)=3;
132,昨天的量为阴量,或昨天量比前天量要小(缩量)
SL:REF(VOL,1)<REF(VOL,2) AND REF(CLOSE,1)<REF(OPEN,1);
 133,只要交换金叉时均线前后的位置,就变成死叉的写法了:
死叉:CROSS(MA(C,10),MA(C,5));
 134,macd后金叉高于前金叉:
DIFF:=EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
JC:=CROSS(DIFF,DEA)AND DEA<0;
JJ:=BARSLAST(JC);
QC:=CROSS(DIFF,DEA)AND COUNT(JC,30)=2;
REF(DEA>REF(DEA,JJ),1)AND QC;
REF(DEA<REF(DEA,JJ),1) AND QC;
135,计算N日均线斜率:
JX:=REF(EMA(C,N),1);
斜率:(EMA(C,N)-JX)/JX*100;
136,开盘N小时内,股价一直大于均价:
IF(OPENMINUTES(HOUR<N),C>DYNAINFO(11),0);
137,N天内跌幅超过X:
N:=20;X:=30;
IF(SUM((1-C/REF(C,1))*100,N)>X,1,0);
138,macd二次金叉:
DIFF:=EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
JC:=COUNT(CROSS(DIFF,DEA),BARSLAST(DEA>=0));//首先界定金叉条件:
选股:CROSS(DIFF,DEA) AND DEA<0 AND JC=2; //定位金叉的次数:
139,M天内、曾经N次涨停:
连续涨停:=COUNT(C/REF(C,1)>1.099,N)=N;
所有个股:COUNT(连续涨停,M)=1;
140,N天内跌幅超过X:
N:=20;X:=30;
IF(SUM((1-C/REF(C,1))*100,N)>X,1,0);
 141,2阳夹1阴
REF(C,2)>REF(O,2) AND REF(C,1)<REF(O,1) AND
  C>O AND C>=REF(O,1);
 142,昨天大涨今收阴十字星大于昨收盘:
昨天大涨:=REF(C,1)/REF(C,2)>1.05;
阴十字星:=H/L>1.015 AND O>C AND H>O AND C>L AND O/C<1.005;
大于昨收盘:=C>REF(C,1);
选股:昨天大涨 AND 阴十字星 AND 大于昨收盘; 
 143,全天涨停:
全天涨停:(LOW>REF(HIGH,1)) AND (HIGH=LOW);
 144,跳空高开的选股公式
o>ref(h,1);
 145,{靠近年线}
a1:(c-ma(c,250))/ma(c,250);
0;
 146,10日内的K线实体的幅度(不管是阴是阳)全部小于3%的选股公式:
选:count((abs(c-o)/min(c,o)*100)<3,10)=10;
147,公式条件:
1.换手率大于3%;
2.量比大于2倍;
3.现价小于10元;
4.流通盘小于2亿股;
5.每股收益大于0.1元;
6.涨幅大于3%;
7.MACD的DIFF上穿DEA,金叉;
X1:=DYNAINFO(37)>0.03;
X2:=DYNAINFO(17)>2;
X3:=C<10;
X4:=CAPITAL/1000000<2;
X5:=FINANCE(33)>0.1;
X6:=(C-REF(C,1))/REF(C,1)>0.03;
X7:=CROSS(MACD.DIF,MACD.DEA);
XG:X1 AND X2 AND X3 AND X4 AND X5 AND X6 AND X7;
148,股价涨停.在K线图上画黄色
STICKLINE(C/REF(C,1)>=1.099,O,C,1,0),COLORYELLOW;
 149,今收盘对于N日内最低收盘价的涨幅(%)
  
  (C-LLV(C,N))/LLV(C,N)*100; 
  150,今收盘对于N日内最高收盘价的跌幅(%)
   (HHV(C,N)-C)/HHV(C,N)*100;
 151,股价在过去N日内运行空间的相对位置
    (C-LLV(L,N))/(HHV(H,N)-LLV(L,N))*100;
 152,股价上方N1%至N2%处的筹码(%)
    AA:=WINNER(C+C*N2/100)*100;
  BB:=WINNER(C+C*N1/100)*100;
  AA-BB 
  153,股价下方N1%至N2%处的筹码(%)
    (WINNER(C-C*N1/100)-WINNER(C-C*N2/100))*100;
  154,收盘价N%处的套牢盘
    100-(WINNER(C*N/100))*100;
155,收盘价N%处的获利盘
    WINNER(C*N/100)*100;
156下影线
    (MIN(C,O)-L)/(H-L);
157,上影线
    (H-MAX(C,O))/(H-L)
158,本周期的涨跌幅
    (C-REF(C,1))/REF(C,1)*100;
159,振幅
    (H-L)/L*100; 
 160,均线金叉
    CROSS(MA(C,N),MA(C,M));{N< M}
   161,均线死叉
    CROSS(MA(C,M),MA(C,N));{N< M}
162,均线多头排列
    A1:=MA(C,N1);
  A2:=MA(C,N2);
  A3:=MA(C,N3);
  A4:=MA(C,N4);
  COUNT(A1>A2 AND A2>A3 AND A3>A4,3);
  163,均线空头排列
  A1:=MA(C,N1);
  A2:=MA(C,N2);
  A3:=MA(C,N3);
  A4:=MA(C,N4);
  COUNT(A1< A2 AND A2< A3 AND A3< A4,3);
164,N日均线向下
    AA:=MA(C,N);
  BB:=REF(AA,1);
  AA< BB
165,N日均线向上
    AA:=MA(C,N);
  BB:=REF(AA,1);
  AA>BB
166,N日均线走平
    AA:=MA(C,N);
  BB:=REF(AA,1);
  AA=BB
167,向前N日至M日出现过均线死叉(P1< P2)
    AA:=MA(C,P1);
  BB:=MA(C,P2);
  CC:=REF(CROSS(BB,AA),N);
  COUNT(CC,M); 
 168,今日成交量大于N日以来的均量
    VOL>MA(VOL,N);
169,低位密集
    A1:=COST(85);
  A2:=COST(15);
  A3:=A1-A2;
  A4:=(A1+A2)/2;
  A5:=A3/A4*100<10;
  B1:=HHV(H,120);
  B2:=LLV(L,120);
  B3:=B1-B2;
  B4:=(A4-B2)< B3/2;
  A5 AND B4; 
 170,换手率
    VOL/CAPITAL*100
171,N日盈亏
    V1:=VOL/SUM(VOL,N);
  V2:=DMA(CLOSE,V1);
  V3:(CLOSE-V2)/V2*100;
172,均线粘合:
设均线为a1,a2,a3
ff:=max(max(a1,a2),a3);
bb:=min(min(a1,a2),a3);
zz:=(ff/bb-1)*100<1;
count(zz,3)=3;
173,连续3涨停
COUNT(c/ref(c,1)>1.094 ,4)=4;
 174,大智慧公式短语
1间隔点:
20,colorred,pointdot,linethick2;
80,colorred,pointdot,linethick2;
50,colorred,pointdot,linethick2;
2间隔线
20,colorred,linethick2;
80,colorred,linethick2;
50,colorred,linethick2;
3信号字
DRAWTEXT(RSI1<10,RSI1,'买'),Colorlime;
DRAWTEXT(RSI1>85,RSI1,'卖'),Colorlime;
4笑哭脸
DRAWICON(VR24<25,VR24,1),ColorFF0000;
DRAWICON(VR24>350,VR24,2),ColorFF0000;
5一线提示
cross("kdj.j"(9,3,3),"kdj.d"(9,3,3)) and "kdj.j"(9,3,3)<20,colorred
6一柱顶天
IF(VAR4=50,50,0),stick,linethick2;
7小人作怪
多头卒:Var3,LINETHICK2, COLORf00ff0;
空头卒:Var4,LINETHICK2, COLORYELLOW;
DRAWICON(Var9,Var9,1);
DRAWICON(Var10,Var10,2);
8小人
买入:Var1 AND Var2,stick,linethick2,colorred;
卖出:CROSS(80,Var4),stick,linethick2,colorgreen;
drawicon(卖出,1.1,2);
drawicon(买入,1.1,1);



如何自己写股票条件选股公式源码
         写公式其实很简单,只是看不懂的人比较复杂而已,比如昨天收盘价大于今天收盘价,公式就是REF(C,1)>C,其中ref(c,1)就是昨天收盘价,c就是收盘价,如果把c改成o,o是开盘价,那么ref(o,1)就是昨天开盘价,括号里面还有一个1字,1表示向前一天的意思,如果把它改成2,那么就是前天也就是往前两天的意思。写公式的函数各个软件都不一样,但都差不多,而且你每点一下函数软件上都有解释函数的用法解释。
    再举个例子一只股票涨停板了,要选出涨停板的股就是c>=ref(c,1)×0.1+ref(c,1)其中0.1是百分之十的意思就是10÷100=0.1的意思,c是今天的收盘价、或者说是现价。整句意思就是说现价大于或等于昨天收盘价的百分之10加上昨天收盘价,用数据来打个比方:昨天收盘价是10元,那么整个算式是这样的:c(现在价钱)要大于或等于10×0.1+10.也就是C>=11.
有些涨停板达不到百分之十(四舍五入)有些只有百分之9.8,那么这时候就要将0.1改成0.098才能将所有涨停板的股票都找出来。
    初学者可以先用最简单的方法写好了就测试,比如c=10,那么选出来的都是股价等于10块钱的。条件选股只能是一个输出比如下面这个简单的公式:
A1:=MA(CLOSE,5);{5日均线}A2:=MA(CLOSE,10);{10日均线}A3:=MA(CLOSE,30);{30日均线}
B1:=A1>REF(A1,1);{5日均线往上翘}
B2:=A2>REF(A2,1);{10日均线往上翘}
B3:=A3>REF(A3,1);{30日均线往上翘}
AA:=A1>A2 AND A2>A3{多头排列也就是说5日线在10日线之上和10日线在30日线之上}
XG:AA AND B1 AND B2 AND B3;{这句是总结上面所有需要输出的意思}
    这公式中上7行中都有个‘=’号这个等于号是不输出的意思,如果都去掉了就会出现软件提示“条件选股只能一个输出”的字眼。记住开头冒号,结尾分号。
    好了说到这里你应该会做简单的条件选股公式了吧?会简单的写公式然后照着思路慢慢研究更深层的公式吧。

    本站是提供个人知识管理的网络存储空间,所有内容均由用户发布,不代表本站观点。如发现有害或侵权内容,请点击这里 或 拨打24小时举报电话:4000070609 与我们联系。

    0条评论

    发表

    请遵守用户 评论公约

    类似文章 更多
    喜欢该文的人也喜欢 更多

    ×
    ×

    ¥.00

    微信或支付宝扫码支付:

    《个图VIP服务协议》

    全部>>