【新提醒】读取硬盘的MBR引导扇区（Windows各系统通用）,Win32汇编语言案例解析,典型案例解析（VIP免费）,鱼C论坛

知识普及：

硬盘的引导扇区位于 0 磁道 0 磁头 1 扇区位置，该扇区存放着系统的引导程序和硬盘的分区表等重要信息。另外小甲鱼八卦一下，该扇区常常是病毒的重点攻击目标！

实现要求：读取硬盘引导扇区并保存为boot.ini文件

实现原理：

上节课小甲鱼不是说会告诉大家如何在用户模式下直接访问硬盘么？嗯，而且承诺绝对简单通俗。好吧，事实上，硬盘内核驱动程序将硬盘作为一个文件，文件名为："\\.\\physicaldrive0"

我们可以利用这个鲜为人知的文件名，通过 CreateFile, ReadFile, WriteFile 和 DeviceIoControl API 来进行访问硬盘。

代码及详细注释：

本帖隐藏的内容

1. ;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
   
2. ; by 小甲鱼, http://www.
   
3. ;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
   
4. ; 功能：读取硬盘引导扇区并保存于boot.ini文件中
   
5. ;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
   
6.         .386
   
7.         .model flat,stdcall
   
8.         option casemap:none
   
9. 
   
10. include windows.inc
    
11. include comdlg32.inc
    
12. include user32.inc
    
13. include kernel32.inc
    
14. includelib comdlg32.lib
    
15. includelib user32.lib
    
16. includelib kernel32.lib
    
17. 
    
18.     .data
    
19. szFileName  db  '\\.\\physicaldrive0', 0            ; 硬盘设备名
    
20. 
    
21.     .data?
    
22. szBuffer        db  512 dup (?)
    
23. @hFile          dd  ?
    
24. @dwBytesRead    dd  ?
    
25. @szLogFile      db  MAX_PATH dup (?)
    
26. 
    
27.     .const
    
28. szNewFile       db  'boot.ini', 0
    
29. szErrOpenFile   db  '无法打开硬盘文件!', 0
    
30. szErrCreateFile db  '无法创建boot.ini文件！', 0
    
31. szSuccess       db  '成功读取硬盘引导区并写入boot.ini文件！', 0   
    
32. szCaption       db  '鱼C工作室', 0   
    
33.    
    
34.     .code
    
35. start:
    
36.     invoke CreateFile,              ; 打开或创建文件
    
37.         addr szFileName,            ; 文件的名字
    
38.         GENERIC_READ,               ; 允许读访问
    
39.         FILE_SHARE_READ,            ; 允许对文件进行共享访问
    
40.         0,                          ; 指向一个SECURITY_ATTRIBUTES结构的指针
    
41.         OPEN_EXISTING,              ; 文件必须存在
    
42.         FILE_ATTRIBUTE_NORMAL,      ; 默认属性
    
43.         0
    
44.    
    
45.     .if eax == INVALID_HANDLE_VALUE ; 打开文件错误
    
46.         invoke MessageBox,
    
47.             NULL,
    
48.             addr szErrOpenFile,
    
49.             addr szCaption,
    
50.             MB_OK
    
51.             
    
52.         jmp exit
    
53.     .endif
    
54.    
    
55.     mov @hFile, eax                 ; 返回文件句柄，这时候硬盘被看成是一个文件的哦~
    
56.    
    
57.     invoke ReadFile,                ; 从文件中读取数据
    
58.         @hFile,                     ; 文件句柄
    
59.         addr szBuffer,              ; 用于保存读入数据的缓冲区
    
60.         sizeof szBuffer,            ; 需要读入的字符数
    
61.         addr @dwBytesRead,          ; 实际读入的字节数
    
62.         0
    
63.    
    
64.     invoke CloseHandle, @hFile      ; 小甲鱼温馨提醒：记得文件打开后要擦屁股->关闭文件，否则造成内存泄漏
    
65.    
    
66.     invoke lstrcpy,                 ; 拷贝字符串
    
67.         addr @szLogFile,
    
68.         addr szNewFile
    
69.    
    
70.     invoke CreateFile,              ; 创建boot.ini文件
    
71.         addr @szLogFile,            
    
72.         GENERIC_WRITE,              
    
73.         FILE_SHARE_READ,            
    
74.         0,                          
    
75.         CREATE_ALWAYS,              
    
76.         FILE_ATTRIBUTE_NORMAL,      
    
77.         0
    
78.    
    
79.     .if eax != INVALID_HANDLE_VALUE
    
80.         mov @hFile, eax
    
81.         
    
82.         invoke WriteFile,           ; 将数据写入boot.ini文件
    
83.             @hFile,
    
84.             addr szBuffer,
    
85.             sizeof szBuffer,
    
86.             addr @dwBytesRead,
    
87.             0
    
88.    
    
89.         invoke CloseHandle, @hFile  ; 擦屁股
    
90.         
    
91.         invoke wsprintf,            ; 这个事实上常用的函数，如果有问题的鱼油可以在论坛搜索下，有篇文章中小甲鱼已经做好了详细的解释给大家。
    
92.             addr szBuffer,
    
93.             addr szSuccess
    
94.          
    
95.         invoke MessageBox,
    
96.             NULL,
    
97.             addr szBuffer,
    
98.             addr szCaption,
    
99.             MB_OK
    
100.             
     
101.     .else
     
102.         invoke MessageBox,
     
103.             NULL,
     
104.             addr szErrCreateFile,
     
105.             addr szCaption,
     
106.             MB_OK
     
107.     .endif   
     
108.         
     
109. exit:
     
110.     invoke ExitProcess, NULL
     
111.         
     
112.     end start

复制代码