|
除非注明，文章均为 战战如疯 原创，转载请保留链接: http://www./cat4/212.html，VBA交流群273624828。
今天我们继续来看VBA操作Word的相关方法。假设我们有一大批已经完成的Word报告，但是现在由于一些原因要将报告中特定的词给替换掉。如果我们要替换的都是相同的词那很简单，直接用我们在上一篇“VBA批量生成Word报告”中的方法将该内容替换即可。但是如果我们要替换的内容在所有的Word中都是不一样的，只是位置相同，那我们就不能简单的替换了。比如在一些理财公司的报告中，本来联系方式那里留的是理财经理的电话，现在想要将理财经理电话替换成公司的电话，由于每个理财经理电话不一样，所以也就不能找到内容然后替换了。前面说过位置是一样的，所以我们这里就先找电话所在的位置，之后再替换。
看下面的例子，还是我们之前用过的那个理财公司的月度报告，现在要将其替换成我的QQ449217002，这里提供两种思路。思路一是找到“联系电话：”这几个字然后将向后数11位的内容替换掉，因为电话都是11位的，所以这种方法是可行的。代码如下
Sub TEST1()
Dim mypath, myfile, wApp, myrange
mypath = ThisWorkbook.Path & "\"
myfile = Dir(mypath & "*.docx")
Do While myfile <> ""
Set wApp = CreateObject("word.application")
wApp.documents.Open mypath & myfile
Set myrange = wApp.activedocument.Content
myrange.Find.Execute findtext:="联系电话:", Forward:=True 'myrange定位到“联系电话：”
'从myrange结束的到myrange后面的11个字符替换成相应内容
wApp.activedocument.Range(Start:=myrange.End, End:=myrange.End + 11).Text = "449217002@qq.com"
wApp.activedocument.Save
wApp.Quit
myfile = Dir
Loop
Set wApp = Nothing
End Sub
思路很简单，找到位置并替换该位置后面相应长度的内容即可。但是如果我们要替换的内容位置虽然一样，但是其长度并不相同呢？比如原来留的是QQ号，有的是11位，有的是8位，现在想要统一成我的QQ449217002，这下不能替换固定长度了。好办，我们只要替换相应内容之间夹的那部门就可以了，这里就替换“联系电话：”和“，有任何问题请”之间的内容，这就是思路二。看代码
Sub TEST2()
Dim mypath, myfile, wApp, myrange1, myrange2, i, j
mypath = ThisWorkbook.Path & "\"
myfile = Dir(mypath & "*.docx")
Do While myfile <> ""
Set wApp = CreateObject("word.application")
wApp.documents.Open mypath & myfile
Set myrange1 = wApp.activedocument.Content
myrange1.Find.Execute findtext:="联系电话:", Forward:=True
i = myrange1.End '记录下起始位置
Set myrange2 = wApp.activedocument.Content
myrange2.Find.Execute findtext:="，有任何问题请", Forward:=True
j = myrange2.Start '记录下结束位置
wApp.activedocument.Range(Start:=i, End:=j).Text = "449217002@qq.com" '替换两个位置之间的内容
wApp.activedocument.Save
wApp.Quit
myfile = Dir
Loop
Set wApp = Nothing
End Sub
这里只不过是先将起始位置和结束位置提前取出来而已，其实两个思路并无太大区别，第二个思路适用更广泛一些。
本节示例文件下载地址：http://pan.baidu.com/s/1kTuWELD。
|
