红牛2008 / 主图公式 / 童牧野鬼变脸主图通达信指标公式源码

分享

   

童牧野鬼变脸主图通达信指标公式源码

2015-06-19  红牛2008

童牧野鬼变脸主图----太极圈原创

 

缘由:在网上看到所谓的鬼变脸源码,与童牧野之规则

相差甚远,可谓误人误己,贻笑大方。

某以为,在中国股市里混,什么波浪,江恩等理论太过模糊,

难以应对瞬息万变之市场。要想自己不过早成为烈士,鬼变脸

不可不学。童牧野先生在《庄家克星》中谈及防震仓之军规,

若能真正做到如此操盘,可谓心态极佳。

 

其规则如下:

第一,鬼变脸红色且5天均线上行,看多做多

(可追多,不惜帮庄家抬轿)。

第二,鬼变脸红色但5天均线走平或下行,看多不做多

(有筹码的继续与狼共舞,没筹码的观望不进)。

第三,鬼变脸绿色且5天均线下行,看空做空

(对准接盘杀跌,不计盈亏)。

第四,鬼变脸绿色但5天均线走平或上行,看空不做空

(没筹码的观望不进,有筹码的即使套牢也暂不割肉)。

------------------------------------------------------------------

闲话不表,希望有缘者深习之,勤悟之,运用之妙,存乎一心!

说明一下:本人能力有限,所编之通达信鬼变脸主图与真正的鬼变脸

仍然有所偏差,主要在于出现四平顶(底)之后,目前之思路难以克服,

虽然如此,仍然优于目前所见之版本。 

T:=BARSCOUNT(C)+1;
STICKLINE(C,H,L,5,0),COLORBLACK;
C,LINETHICK;
STICKLINE(T=1 AND C>=O,O,C,3,1),COLORRED;
STICKLINE(T=1 AND C<O,O,C,3,0),COLOR00CC00;
C1:=REF(C,1);
C2:=REF(C,2);
XH:=C1>=C2 AND C>C1;    {二红}
LH:=C1<C2  AND C>C2;       {绿变红}
HP:=C1>=C2 AND C<=C1 AND C>=C2;   {红平}
HL:=C1>=C2 AND C<C2;     {红变绿}
XL:=C1<C2 AND C<C1;      {二绿}
LP:=C1<C2 AND C>=C1 AND C<=C2;   {绿平}
STICKLINE(T=2 AND XH,C1,C,3,0),COLORRED;  {二红}
STICKLINE(T=2 AND HP,C1,C,3,0),COLORRED;  {红平}
STICKLINE(T=2 AND HL,C1,C2,3,1),COLORRED; 
STICKLINE(T=2 AND HL,C2,C,3,0),COLOR00CC00;  {红变绿}
STICKLINE(T=2 AND XL,C1,C,3,0),COLOR00CC00;  {二绿}
STICKLINE(T=2 AND LP,C1,C,3,0),COLOR00CC00;  {绿平}
STICKLINE(T=2 AND LH,C1,C2,3,1),COLOR00CC00;
STICKLINE(T=2 AND LH,C2,C,3,0),COLORRED;     {绿变红} 
  {第三天开始18变}
昨红今红:=REF(XH,1)=1 AND C>C1;
昨红今平:=REF(XH,1)=1 AND C<=C1 AND C>=C2;
昨红今绿:=REF(XH,1)=1 AND C<C2;
昨红平今红:=REF(HP,1)=1 AND C>C2;
昨红平今红平:=REF(HP,1)=1 AND C<=C2 AND C>=C1;
昨红平今变绿:=REF(HP,1)=1 AND C<C1;
BS:=IF(REF(HL,1)=1 OR REF(LH,1)=1 AND T=3,REF(O,2),REF(C,3));
HP2:=REF(LH,1)=1 AND C<=C1 AND C>=BS;
HP3:=(REF(HP,1)=1 OR REF(HP2,1)=1) AND C>=C1 AND C<=C2;   {3红平}
三红平:=HP3;
昨变绿今变红:=REF(HL,1)=1 AND C>BS;
昨变绿今绿平:=REF(HL,1)=1 AND C<=BS AND C>=C1;
昨变绿今续绿:=REF(HL,1)=1 AND C<C1;
昨绿今绿:=REF(XL,1)=1 AND C<C1;
昨绿今平:=REF(XL,1)=1 AND C<=C2 AND C>=C1;
昨绿今红:=REF(XL,1)=1 AND C>C2;   
昨绿平今绿:=REF(LP,1)=1 AND C<C2;
昨绿平今绿平:=REF(LP,1)=1 AND C<=C1 AND C>=C2;
昨绿平今变红:=REF(LP,1)=1 AND C>C1;
LP2:=REF(HL,1)=1 AND C>=C1 AND C<=BS;
LP3:=(REF(LP2,1)=1 OR REF(LP,1)=1) AND C<=C1 AND C>=C2;    {3绿平}
三绿平:=LP3;
昨变红今续红:=REF(LH,1)=1 AND C>C1;
昨变红今变绿:=REF(LH,1)=1 AND C<BS;
昨变红今红平:=REF(LH,1)=1 AND C>=BS AND C<=C1;
STICKLINE(T=3 AND 昨红今红,C1,C,3,1),COLORRED;  
STICKLINE(T=3 AND 昨红今平,C1,C,3,1),COLORRED; 
STICKLINE(T=3 AND 昨红今绿,C1,C2,3,1),COLORRED;  
STICKLINE(T=3 AND 昨红今绿,C,C2,3,0),COLOR00CC00;  {昨红今绿}
STICKLINE(T=3 AND REF(HP,1)=1 AND C>C2,C2,C,3,1),COLORRED;  {昨红平今红}
STICKLINE(T=3 AND REF(HP,1)=1 AND C<=C2 AND C>=C1,C2,C,3,1),COLORRED; 
 {昨红平今红平}
STICKLINE(T=3 AND REF(HP,1)=1 AND C<C1,C1,C2,3,1),COLORRED;  
STICKLINE(T=3 AND REF(HP,1)=1 AND C<C1,C,C1,3,0),COLOR00CC00; 
{昨红平今变绿}
STICKLINE(T=3 AND REF(HL,1)=1 AND C>BS,BS,C,3,1),COLORRED;   {昨变绿今变红}
STICKLINE(T=3 AND REF(HL,1)=1 AND C>BS,C1,BS,3,0),COLOR00CC00; 
STICKLINE(T=3 AND REF(HL,1)=1 AND C<=BS AND C>=C1,C1,C,3,0),COLOR00CC00; 
 {昨变绿今绿平}
STICKLINE(T=3 AND REF(HL,1)=1 AND C<C1,C,C1,3,0),COLOR00CC00; 
 {昨变绿今续绿}
STICKLINE(T=3 AND REF(XL,1)=1 AND C<C1,C1,C,3,0),COLOR00CC00; {昨绿今绿}
STICKLINE(T=3 AND REF(XL,1)=1 AND C<=C2 AND C>=C1,C1,C,3,0),COLOR00CC00; 
{昨绿今绿平}
STICKLINE(T=3 AND REF(XL,1)=1 AND C>C2,C1,C2,3,0),COLOR00CC00;   
STICKLINE(T=3 AND REF(XL,1)=1 AND C>C2,C,C2,3,1),COLORRED; {昨绿今变红}     
STICKLINE(T=3 AND REF(LP,1)=1 AND C<C2,C2,C,3,0),COLOR00CC00;
 {昨绿平今绿}
STICKLINE(T=3 AND REF(LP,1)=1 AND C<=C1 AND C>=C2,C2,C,3,0),COLOR00CC00;
{昨绿平今绿平}
STICKLINE(T=3 AND REF(LP,1)=1 AND C>C1,C1,C2,3,0),COLOR00CC00;  
STICKLINE(T=3 AND REF(LP,1)=1 AND C>C1,C,C1,3,1),COLORRED;
 {昨绿平今变红}
STICKLINE(T=3 AND REF(LH,1)=1 AND C>C1,C,C1,3,1),COLORRED; {昨变红今续红}
STICKLINE(T=3 AND REF(LH,1)=1 AND C<BS,BS,C1,3,1),COLORRED; 
STICKLINE(T=3 AND REF(LH,1)=1 AND C<BS,C,BS,3,0),COLOR00CC00; {昨变红今变绿}
STICKLINE(T=3 AND REF(LH,1)=1 AND C>=BS AND C<=C1,C1,C,3,1),COLORRED; 
{昨变红今红平}
BSW:=IF(REF(昨红今红,1)=1 OR REF(昨绿平今变红,1)=1
       OR REF(昨变红今续红,1)=1,MIN(C1,C2),
     IF(REF(昨红今绿,1)=1 OR REF(昨红平今红,1)=1 
       OR REF(昨绿今红,1)=1 OR REF(昨绿平今绿,1)=1,BS,
     IF(REF(昨红今平,1)=1 OR REF(三红平,1)=1 
       OR REF(昨变绿今绿平,1)=1 OR REF(昨绿今平,1)=1 
       OR REF(三绿平,1)=1 OR REF(昨变红今红平,1)=1,C1,
     IF(REF(昨红平今变绿,1)=1 OR REF(昨变绿今续绿,1)=1 
       OR REF(昨绿今绿,1)=1,C2,
     IF(REF(昨变绿今变红,1)=1 
       OR REF(昨变红今变绿,1)=1,REF(BS,1),DRAWNULL)))));
QHX:=IF(REF(昨红今红,1)=1 OR REF(昨绿平今变红,1)=1
       OR REF(昨变红今续红,1)=1 OR REF(昨红今绿,1)=1
       OR REF(昨红平今红,1)=1   OR REF(昨绿今红,1)=1 
       OR REF(昨绿平今绿,1)=1   OR REF(昨红平今变绿,1)=1
       OR REF(昨变绿今变红,1)=1 OR REF(昨变红今变绿,1)=1
       OR REF(昨变绿今续绿,1)=1 OR REF(昨绿今绿,1)=1,C1,
     IF(REF(三红平,1)=1 OR REF(三绿平,1)=1,REF(C,3),
     IF(REF(昨变绿今绿平,1)=1 OR REF(昨绿今平,1)=1,MIN(C1,C2),
     IF(REF(昨红今平,1)=1 OR REF(昨变红今红平,1)=1,MAX(C1,C2),DRAWNULL))));
HX:=SIGN(QHX-BSW); 
TH:=MAX(QHX,BSW);
TL:=MIN(QHX,BSW);
STICKLINE(HX=0 AND C>TH,C,TH,3,1),COLORRED;
STICKLINE(HX=0 AND C<=TH AND C>=TL,C,TH,3,1),COLORRED;
STICKLINE(HX=0 AND C<TL,TH,TL,3,1),COLOR0000AA;
STICKLINE(HX=0 AND C<TL,TL,C,3,0),COLOR00CC00;
STICKLINE(HX=1 AND C>TH,C,TH,3,1),COLORRED;
STICKLINE(HX=1 AND C<=TH AND C>=TL,C,TH,3,1),COLORRED;
STICKLINE(HX=1 AND C<TL,TH,TL,3,1),COLORRED;
STICKLINE(HX=1 AND C<TL,TL,C,3,0),COLOR00CC00;
STICKLINE(HX=0-1 AND C>BSW,QHX,BSW,3,0),COLOR00CC00;
STICKLINE(HX=0-1 AND C>BSW,C,TH,3,1),COLORRED;
STICKLINE(HX=0-1 AND C<=TH AND C>=TL,C,TL,3,0),COLOR00CC00;
STICKLINE(HX=0-1 AND C<TL,TL,C,3,0),COLOR00CC00;
M5:MA(C,5);
IF(M5<REF(M5,1),M5,DRAWNULL),COLORWHITE;
童牧野鬼变脸主图通达信指标公式源码.rar

    本站是提供个人知识管理的网络存储空间,所有内容均由用户发布,不代表本站观点。如发现有害或侵权内容,请点击这里 或 拨打24小时举报电话:4000070609 与我们联系。

    0条评论

    发表

    请遵守用户 评论公约

    类似文章 更多
    喜欢该文的人也喜欢 更多

    ×
    ×

    ¥.00

    微信或支付宝扫码支付:

    开通即同意《个图VIP服务协议》

    全部>>