delphi IdHTTP实现Get方法下载文件，断点续传

delphi IdHTTP实现Get方法下载文件，断点续传

标签： IndyTCPdelphi断点续传HTTP

2016-06-06 12:08 527人阅读 评论(0) 收藏 举报

分类：

delphi Indy（3）

版权声明：本文为博主原创文章，转载请标明出处并事先取得博主同意

因为项目需要，想实现从网络上下载文件，最好能实现断点续传。

搜索了下，发现下载文件还是很简单的，用IdHTTP的Get方法直接写入文件流中就可以了。

不过断点续传就麻烦了，网上是有蛮多demo的。但是几乎都是在续传的时候文件大小会变大，并不是真正的断点续传。

经过各种查找资料和实验，终于发现了问题。

一个是因为很多demo都直接设置

IdHttp.Response.ContentRangeStart 和 IdHttp.Response.ContentRangeEnd 属性来设置需要下载的文件范围，但我试了发现这种方法并不起作用，服务器还是会从头开始传送文件。然后发现直接设置IdHttp.Request.Range属性才可以。

还有是因为要是直接让IdHttp存入文件流

[delphi] view plain copy

print?

1. IdHTTP.Get(aURL,FileStream);  

的话即使你中途暂停，下载一半的文件也会把整个文件的空间占了，然后就没法通过读文件大小得知已下载多少了，当然这可以通过保存配置文件得知已下载大小。

然后最后参考一些资料就想到可以一小段一小段的下载文件到内存流中然后在一段一段的存入文件流来使得文件大小能够慢慢增大并实现断点续传。

建个窗体。我这里建的是FMX的窗体，所以这个demo也是可以在移动端用的，不过在Android好像ProgressBar没有实现，反正自己看着改改就行。然后随便拖个Edit两个button和个ProgressBar来显示进度。

顺便说下，Indy是阻塞式的，也就是说调用Indy里的方法，在执行完前界面是会卡住的，想了解Indy的机制的可以点这里看我翻译的Indy入门文档，在VCL下有个TIdAntiFreeze控件可以防止用户界面卡住，而FMX没有，所以要通过其他方式比如多线程来防止界面卡住，这里为了简单，模仿TIdAntiFreeze的实现，通过不停调用Application.ProcessMessages来放弃控制权，给用户界面刷新的时间。

然后按照之前的思想，这是“开始下载”按钮的代码

[delphi] view plain copy

print?

1. procedure THttpGetFileForm.StartButtonClick(Sender: TObject);  
2. var  
3.   aURL: string;  
4.   MemStream: TMemoryStream;  
5.   FileStream: TFileStream;  
6.   FilePosition: Int64;  
7.   FileSize: integer;  
8.   Filename: string;  
9.   IdHttp: TIdHttp;  
10. begin  
11.   // 防止多次按按钮  
12.   StartButton.Enabled := False;  
13.   IdHttp := TIdHttp.Create(self);  
14.   Try  
15.     // 设置flag  
16.     Stop := False;  
17.     aURL := FileURLEdit.Text;  
18.     // 处理重定向  
19.     IdHttp.HandleRedirects := True;  
20.     IdHttp.Request.Range := '';  
21.     IdHttp.Head(aURL);  
22.     // 获取重定向后的URL  
23.     aURL := IdHttp.URL.URI;  
24.     // 获取文件名  
25.     Filename := GetURLFileName(aURL);  
26.     // 创建文件流，如果存在，则打开并把指针放文件末尾，否则创建  
27.     if FileExists(Filename) then begin  
28.       try  
29.         FileStream := TFileStream.Create(Filename, fmOpenWrite);  
30.         FileStream.Seek(0, soEnd); // 指针移到末尾  
31.       except  
32.         Showmessage(Format('打开文件 "%s" 失败!', [Filename]));  
33.         exit;  
34.       end;  
35.     end else begin  
36.       FileStream := TFileStream.Create(Filename, fmCreate);  
37.     end;  
38.     // 创建内存流  
39.     MemStream := TMemoryStream.Create;  
40.     // 得到文件大小  
41.     FileSize := IdHttp.Response.ContentLength;  
42.     FilePosition := FileStream.Position;  
43.     // 设置进度条  
44.     ProgressBar.Max := FileSize;  
45.     try  
46.       // 循环下载，每次判断是否暂停  
47.       while (FilePosition < FileSize) and (not Stop) do begin  
48.         // 方法1：不可用  
49.         // IdHttp.Response.ContentRangeStart := FilePosition;  
50.         // IdHttp.Response.ContentRangeEnd   := FilePosition + 1024;  
51.         // 方法2：可用  
52.         IdHttp.Request.Range := IntToStr(FilePosition) + '-';  
53.         // 每次下载10240B的文件块，当然可以改成其他大小  
54.         if FilePosition + 10240 < FileSize then  
55.           IdHttp.Request.Range := IdHttp.Request.Range +  
56.             IntToStr(FilePosition + 10239);  
57.         IdHttp.get(aURL, MemStream); // 每段分别存入内存流  
58.         MemStream.SaveToStream(FileStream);  
59.         inc(FilePosition, MemStream.Size);  
60.         // 更新进度条  
61.         ProgressBar.Value := FilePosition;  
62.         // 情况内存流  
63.         MemStream.Clear;  
64.         // 通过调用这个方法防止界面卡死  
65.         Application.ProcessMessages;  
66.       end;  
67.       // 不是由于按了停止而结束的循环说明下载完成了  
68.       if (not Stop) then  
69.         Showmessage(Format('下载文件 "%s" 成功!', [Filename]));  
70.     finally  
71.       MemStream.DisposeOf;  
72.       FileStream.DisposeOf;  
73.     end;  
74.   Finally  
75.     // 最后要记得让按钮可按  
76.     StartButton.Enabled := True;  
77.     IdHttp.DisposeOf;  
78.   End;  
79. end;  

Stop: Boolean;是个全局变量，设在Form的private或public里无所谓
然后停止键其实只干了一件事：把Stop设为了True；

[delphi] view plain copy

print?

1. procedure THttpGetFileForm.StopBtnClick(Sender: TObject);  
2. begin  
3.   Stop := True;  
4. end;  

奥，还有一个获取文件名的函数，其实很多demo里都用了这个函数

[delphi] view plain copy

print?

1. function THttpGetFileForm.GetURLFileName(aURL: string): string;  
2. var  
3.   i: integer;  
4.   s: string;  
5. begin  
6.   s := aURL;  
7.   i := Pos('/', s);  
8.   while i <> 0 do begin  
9.     Delete(s, 1, i);  
10.     i := Pos('/', s);  
11.   end;  
12.   Result := s;  
13. end;  

其实最后还有个问题，这样下载的文件即使没有下完，除了文件大小和下完的不一样，在资源管理器里完全和下好的一模一样没有区别，然后就明白了为什么迅雷下载东西的时候要先存为临时文件，下载完成了后再改回去，所以对以上代码稍微进行修改：

[delphi] view plain copy

print?

1. procedure THttpGetFileForm.StartButtonClick(Sender: TObject);  
2. var  
3.   aURL: string;  
4.   MemStream: TMemoryStream;  
5.   FileStream: TFileStream;  
6.   FilePosition: Int64;  
7.   FileSize: integer;  
8.   Filename: string;  
9.   IdHttp: TIdHttp;  
10. begin  
11.   // 防止多次按按钮  
12.   StartButton.Enabled := False;  
13.   IdHttp := TIdHttp.Create(self);  
14.   Try  
15.     // 设置flag  
16.     Stop := False;  
17.     aURL := FileURLEdit.Text;  
18.     // 处理重定向  
19.     IdHttp.HandleRedirects := True;  
20.     IdHttp.Request.Range := '';  
21.     IdHttp.Head(aURL);  
22.     // 获取重定向后的URL  
23.     aURL := IdHttp.URL.URI;  
24.     // 获取文件名  
25.     Filename := GetURLFileName(aURL);  
26.     // 如果文件已存在说明下载完成了  
27.     if FileExists(Filename) then begin  
28.       Showmessage(Format('下载文件 "%s" 成功!', [Filename]));  
29.       exit;  
30.     end;  
31.     // 创建文件流，如果存在临时文件，则打开并把指针放文件末尾，否则创建  
32.     if FileExists(Filename + '.tmp') then begin  
33.       try  
34.         FileStream := TFileStream.Create(Filename + '.tmp', fmOpenWrite);  
35.         FileStream.Seek(0, soEnd); // 指针移到末尾  
36.       except  
37.         Showmessage(Format('打开文件 "%s" 失败!', [Filename + '.tmp']));  
38.         exit;  
39.       end;  
40.     end else begin  
41.       FileStream := TFileStream.Create(Filename + '.tmp', fmCreate);  
42.     end;  
43.     // 创建内存流  
44.     MemStream := TMemoryStream.Create;  
45.     // 得到文件大小  
46.     FileSize := IdHttp.Response.ContentLength;  
47.     FilePosition := FileStream.Position;  
48.     // 设置进度条  
49.     ProgressBar.Max := FileSize;  
50.     try  
51.       // 循环下载，每次判断是否暂停  
52.       while (FilePosition < FileSize) and (not Stop) do begin  
53.         // 方法1：不可用  
54.         // IdHttp.Response.ContentRangeStart := FilePosition;  
55.         // IdHttp.Response.ContentRangeEnd   := FilePosition + 1024;  
56.         // 方法2：可用  
57.         IdHttp.Request.Range := IntToStr(FilePosition) + '-';  
58.         // 每次下载10240B的文件块，当然可以改成其他大小  
59.         if FilePosition + 10240 < FileSize then  
60.           IdHttp.Request.Range := IdHttp.Request.Range +  
61.             IntToStr(FilePosition + 10239);  
62.         IdHttp.get(aURL, MemStream); // 每段分别存入内存流  
63.         MemStream.SaveToStream(FileStream);  
64.         inc(FilePosition, MemStream.Size);  
65.         // 更新进度条  
66.         ProgressBar.Value := FilePosition;  
67.         // 情况内存流  
68.         MemStream.Clear;  
69.         // 通过调用这个方法防止界面卡死  
70.         Application.ProcessMessages;  
71.       end;  
72.       // 不是由于按了停止而结束的循环说明下载完成了,修改文件名  
73.       if (not Stop) then begin  
74.         FreeAndNil(FileStream);  
75.         RenameFile(Filename + '.tmp', Filename);  
76.         Showmessage(Format('下载文件 "%s" 成功!', [Filename]));  
77.       end;  
78.     finally  
79.       MemStream.DisposeOf;  
80.       if Assigned(FileStream) then  
81.         FileStream.DisposeOf;  
82.     end;  
83.   Finally  
84.     // 最后要记得让按钮可按  
85.     StartButton.Enabled := True;  
86.     IdHttp.DisposeOf;  
87.   End;  
88. end;  

此段代码在XE10，Windows下测试通过。

其实把这段再修改下，再创建个配置文件，然后把文件按需要分块，多个IdHttp分别下载各个小块然后最后拼起来，就很类似迅雷那种分块下载了。

如果要在移动平台使用，需要在文件名处加上文件路径，然后调整下显示进度的方式。

实际使用时会用多线程的方式在后台下载，过些天有时间了写个用多线程的多平台的demo上来。

需要完整的demo工程的点这里下载，稍微收个1分0.0。