本文总结了4种实现全盘搜索指定文件获取其完整路径的bat批处理文件源码，有需要的朋友可以参考下 废话不多说，直接上代码，额，想用的话，自己保存成bat文件即可。 【方案一】for /f + dir
1 2 3 4 5 6 7 8 9 10 11 12 13 | @echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，请稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
if exist %%a:\ (
for /f "delims=" %%b in ('dir /a-d /s /b "%%a:\*%FileName%" 2^>nul') do (
if /i "%%~nxb" equ "%FileName%" (
echo,%%b
)
)
)
)
|
【方案二】for /r（比 for /f + dir 效率高，但不会遍历隐藏文件）
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 | @echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，请稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
if exist %%a:\ (
pushd %%a:\
for /r %%b in (*%FileName%) do (
if /i "%%~nxb" equ "%FileName%" (
echo,%%b
)
)
popd
)
)
|
【方案三】WMIC（Win2000/WinXP HOME版、WinXP 精简版可能不支持）
1 2 3 4 5 6 7 8 9 10 11 12 | @echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，请稍候...
for %%a in ("%FileName%") do (
set "nName=%%~na"
set "xName=%%~xa"
)
set "xName=%xName:~1%"
for /f "skip=1 delims=" %%a in ('wmic datafile where "filename='%nName%' and Extension='%xName%'" get name') do (
echo,%%a
)
|
【方案四】使用 Windows7 系统自带的 where 命令
1 2 3 4 5 6 7 8 9 10 11 12 13 | @echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，请稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
if exist %%a:\ (
for /f "delims=" %%b in ('where /r %%a: "%FileName%" 2^>nul') do (
if /i "%%~nxb" equ "%FileName%" (
echo,%%b
)
)
)
)
|
|
