知博陋室自用的操盘主图

  

    {知博陋室 【主图指标】 知博陋室自用的操盘主图}

    {个股MACD【指标参数】SHORT:2 200 6,LONG:2 200 10,MID:2 200 5.}
    {布林副图【指标参数】 N:2 100 26 M:2 100 2}
    {量价走势【指标参数】 N2::2 120 51  M2:2 60 6}

    {5日、10日均线，通子线色块及其它均线}

    MA5:MA(C,5)COLORFFEFD5,LINETHICK1,DOTLINE;
    MA10:=MA(C,10)COLORGREEN,LINETHICK1,DOTLINE;
    MA20:=MA(C,20)COLOR666666;

    X:=(3*C+L+O+H)/6;
    宝塔多空线:=(20*X+19*REF(X,1)+18*REF(X,2)+17*REF(X,3)+16*REF(X,4)+15*REF(X,5)+14*REF(X,6)
    +13*REF(X,7)+12*REF(X,8)+11*REF(X,9)+10*REF(X,10)+9*REF(X,11)+8*REF(X,12)
    +7*REF(X,13)+6*REF(X,14)+5*REF(X,15)+4*REF(X,16)+3*REF(X,17)+2*REF(X,18)+
    REF(X,20))/210,COLORYELLOW,LINETHICK1;

    宝塔多空线1:IF(宝塔多空线>REF(宝塔多空线,1)OR C>(宝塔多空线),宝塔多空线,DRAWNULL)COLORMAGENTA,LINETHICK1;
    宝塔多空线2:IF(宝塔多空线<REF(宝塔多空线,1)OR C<(宝塔多空线),宝塔多空线,DRAWNULL)COLORGREEN,LINETHICK1;

    揽月:=EMA(EMA(EMA(EMA(MA(C,5),2),1),2),1),COLORLICYAN,LINETHICK1;
    捉鳖:=REF(揽月,1)COLORGREEN;{上九天揽月与下五洋捉鳖同为平滑处理过的一组7日均线（组）}
    揽月多:=IF(揽月>REF(揽月,1),揽月,DRAWNULL),COLORRED,LINETHICK2;
    揽月空:=IF(揽月<REF(揽月,1),揽月,DRAWNULL),COLORGREEN,LINETHICK2;

    可交易时段:DRAWTEXT_FIX(CURRBARSCOUNT=1 AND 宝塔多空线>=REF(宝塔多空线,1)AND C>=MA5,0.235,0.07,0,'个股现在正处在多头可交易时段。交易者可以举资入场，持股待涨。')COLORRED;
    宜观望时段:DRAWTEXT_FIX(CURRBARSCOUNT=1 AND 宝塔多空线<REF(宝塔多空线,1)AND C<MA5,0.235,0.07,0,'个股现在正处在空头宜观望时段。交易者当思清仓离场，持币观望。')COLORGREEN;

    通线:=MA(C,17)COLORRED,LINETHICK2;
    子线:=MA(C,26)COLORCYAN,NODRAW;
    通子多空:=通线>=(子线)COLORLICYAN,NODRAW;
    平均成本线:COST(50),COLOR0099FF,DOTLINE,NODRAW;
    中线60:=EMA(CLOSE,60),COLORGREEN,NODRAW;
    半年线:=EMA(CLOSE,120),COLORLICYAN,LINETHICK2,NODRAW;
    年线:EMA(CLOSE,250),COLORBLUE,LINETHICK2,NODRAW;

    {多头符号标识}
    中线钱袋子:=DRAWICON(CROSS(C,中线60),中线60-0.1,9);      {钱袋子}
    半年金手指:=DRAWICON(CROSS(C,半年线),半年线-0.1,11);     {金手指}
    年线露笑脸:=DRAWICON(CROSS(C,年线),年线-0.1,5);          {笑  脸}

    {现价止盈、止损价位}
    现价:DYNAINFO(7)COLORWHITE,NODRAW;
    现价亏3%止损位:REF(现价*0.97,1)COLORGREEN,NODRAW;
    现价赚6%止盈位:REF(现价*1.06,1)COLORRED,NODRAW;

    {庄家成本}
    A:=SUMBARS(V,CAPITAL*1); 
    A01:=SUM(COST(10),A)/A; {在A周期里获利10%的平均价}
    A02:=SUM(COST(20),A)/A; {在A周期里获利20%的平均价}
    A03:=SUM(COST(30),A)/A; {在A周期里获利30%的平均价}
    A04:=SUM(COST(40),A)/A; {在A周期里获利40%的平均价}
    A05:=SUM(COST(50),A)/A; {在A周期里获利50%的平均价}
    庄家成本:(5*A01+4*A02+3*A03+2*A04+A05)/15,DOTLINE,COLORCYAN,NODRAW;
    庄得利:C>=(庄家成本)COLORRED,NODRAW;
    庄差钱:C<(庄家成本)COLORGREEN,NODRAW;

    {日、周、月涨幅}
    日涨幅:=((C-REF(C,1))/REF(C,1))*100,COLORRED,NODRAW;
    周涨幅:((C-REF(C,5))/REF(C,5))*100,COLORYELLOW,NODRAW;
    月涨幅:=((C-REF(C,20))/REF(C,20))*100,COLORGREEN,NODRAW;
    季涨幅:=((C-REF(C,60))/REF(C,60))*100,COLORMAGENTA,NODRAW;
    标识25:STICKLINE(日涨幅>=9.95,O,C,2,0),COLORYELLOW;

    {分钟线首根K线标注}
    分钟线首根K线:HOUR<REF(HOUR,1)COLOR0099FF,NODRAW;
    给首日标注:DRAWICON(分钟线首根K线,H*1.015,41);

    {选股}
    选股:=DRAWICON(CROSS(C,MA5),L-0.05,42); {多头标识}
    选股预警:DRAWTEXT_FIX(CURRBARSCOUNT=1 AND LONGCROSS(C,MA5,3),0.80,0.09,0,'股价上穿5日均  ★★★')COLORMAGENTA;

    {名称代码所属行业及概念板块}
    所属行业:DRAWTEXT_FIX(1,0.02,0.01,0,'所属行业:'),COLORFF6000;
    行业标识:DRAWTEXT_FIX(1,0.059,0.01,0,HYBLOCK),COLORRED;
    地域标识:DRAWTEXT_FIX(1,0.095,0.01,0,DYBLOCK),COLORGREEN;
    名称代码:=STRCAT(STRCAT(STRCAT(STRCAT('名称: ',STKNAME),' 代码: '),CODE),' ' );
    概念板块:=STRCAT('概念板块: ',GNBLOCK);
    名称代码标识:DRAWTEXT_FIX(ISLASTBAR,0.14,0.01,0,STRCAT(名称代码,概念板块)),COLORYELLOW;

    {压力与支撑}
    压力均线画线:=HHV(HIGH,30),COLOR666666,DOTLINE;
    支撑均线画线:=LLV(LOW,30),COLOR666666,DOTLINE;
    压力均线30:=HHV(LOW,30),COLORFFCC00,DOTLINE;
    支撑均线30:=LLV(HIGH,30),COLORFFCC00,DOTLINE;
    向上突破:DRAWICON(FILTERX(CROSS(C,支撑均线30),10),L*0.98,1);
    向上突破支撑:=DRAWTEXT(FILTERX(CROSS(C,支撑均线30),10),L*0.985,'  支撑位')COLORRED;
    向下突破支撑:DRAWICON(FILTERX(CROSS(压力均线30,C),10),H*1.03,2);

    {短线底部关注信号}
    买:=IF("KDJ.J"<0,10,0);
    条件:=CROSS(9.9,买);
    VAR1:=(2*CLOSE+HIGH+LOW)/4;
    VAR2:=LLV(LOW,5);
    VAR3:=HHV(HIGH,5);
    VAR4:=EMA((VAR1-VAR2)/(VAR3-VAR2)*100,5);
    MA1:=MA(VAR4,3);
    AA:=STICKLINE(VAR4>MA1,VAR4,MA1,3,1),COLORRED;
    BBB:=STICKLINE(VAR4>MA1 AND REF(VAR4,1)<30,VAR4,MA1,3,1),COLORYELLOW;
    标识003:=STICKLINE(VAR4<=MA1,VAR4,MA1,3,1),COLORGREEN;
    标识004:DRAWICON(FILTERX(CROSS(9.9,买),5),L*0.98,38)COLORLICYAN;

    {中短期震荡数值}
    短期震荡值:=100*(C-LLV(L,5))/(HHV(C,5)-LLV(L,5))NODRAW,COLORGREEN;
    中期震荡值:=100*(C-LLV(L,10))/(HHV(C,10)-LLV(L,10))NODRAW,COLOR0099FF;
    中长期震荡值:=100*(C-LLV(L,20))/(HHV(C,20)-LLV(L,20))NODRAW,COLORMAGENTA;
    长期震荡值:=100*(C-LLV(L,30))/(HHV(C,30)-LLV(L,30))NODRAW,COLORCYAN,LINETHICK2;
    震荡值预警:DRAWTEXT_FIX(CURRBARSCOUNT=1 AND CROSS(长期震荡值,50),0.70,0.09,0,'震荡值上穿 50   ★★★ + ')COLOR0099FF;
    震荡值提醒:DRAWTEXT_FIX(CURRBARSCOUNT=1 AND 短期震荡值<=(6)AND 中期震荡值<=(6)AND 中长期震荡值<=(6)AND 长期震荡值<=(6),0.90,0.98,0,'短线已然超跌   ★★★')COLORGREEN;

    {多头文字标识}
    中线标识:DRAWTEXT_FIX(CURRBARSCOUNT=1 AND CROSS(REF(中线钱袋子,0),REF(中线钱袋子,1)),0.90,0.03,0,'中线转多头了★★★')COLORRED;
    半年标识:DRAWTEXT_FIX(CURRBARSCOUNT=1 AND CROSS(REF(半年金手指,0),REF(半年金手指,1)),0.90,0.09,0,'半年转多头了★★★')COLORRED;
    年线标识:DRAWTEXT_FIX(CURRBARSCOUNT=1 AND CROSS(REF(年线露笑脸,0),REF(年线露笑脸,1)),0.90,0.15,0,'年线转多头了★★★')COLORRED;

    {个股 MACD 【副图指标】}
    DIF:=EMA(CLOSE,SHORT)-EMA(CLOSE,LONG)COLORGREEN,LINETHICK1;
    DEA:=EMA(DIF,MID)COLORFFFF33,LINETHICK1;
    MACD:=(DIF-DEA)/0.5,COLORSTICK;
    MACD标注:DRAWTEXT_FIX(CURRBARSCOUNT=1 AND MACD>(0),0.382,0.91,0,'个股的 MACD 数值已经大于 0 （20分）')COLORRED;

    {布林线副图【副图指标】参数 N:2 100 26 M:2 100 2}
    CV:=CLOSE;
    BBIBOLL:=(MA(CV,3)+MA(CV,6)+MA(CV,12)+MA(CV,24))/4,COLORLICYAN,;
    UPR:=BBIBOLL+M*STD(BBIBOLL,N)COLOR0099FF,DOTLINE;
    DWN:=BBIBOLL-M*STD(BBIBOLL,N)COLORMAGENTA,DOTLINE;
    布林线多头:=C>=(BBIBOLL);
    布林线多头标注:DRAWTEXT_FIX(CURRBARSCOUNT=1 AND 布林线多头,0.690,0.91,0,'布林线多头（16分）')COLOR0000FF;

    {文字说明、标注}
    平均成本线标注:DRAWTEXT_FIX(CURRBARSCOUNT=1 AND C>=(平均成本线),0.760,0.91,0,'股价已在平均成本线上方运行（16分）')COLORGREEN;
    年线预警5:DRAWTEXT_FIX(CURRBARSCOUNT=1 AND C>=(年线),0.582,0.91,0,'股价已在年线上方运行（16分）')COLORCYAN;
    通子线多头标注:DRAWTEXT_FIX(CURRBARSCOUNT=1 AND 通线>=(子线),0.513,0.91,0,'通子线多头（16分）')COLORYELLOW;
    庄家成本标注:DRAWTEXT_FIX(CURRBARSCOUNT=1 AND C>(庄家成本),0.888,0.91,0,'股价已越过了庄家成本（16分）') COLOR0099FF;
    提示0:DRAWTEXT_FIX(C!=0,0.015,0.91,0,'  个股强弱看积分，60分及格。股指不计“平均成本”、“庄家成本”这二项。(量价区间多头+18分，合计118分。)'),COLORLICYAN;  
    提示1:DRAWTEXT_FIX(C!=0,0.015,0.64,0,'  小阴线和小阳线的波动范围一般在 0.6--1.5% 之间 '),COLOR0099FF;  
    提示2:DRAWTEXT_FIX(C!=0,0.015,0.70,0,'  中阴线和中阳线的波动范围一般在 1.6--3.5% 之间 '),COLOR0099FF;  
    提示3:DRAWTEXT_FIX(C!=0,0.015,0.76,0,'  大阴线和大阳线的波动范围一般在 3.6% 以上 '),COLOR0099FF;  

    {年、月、日、星期}
    D1:=YEAR AND MONTH AND DAY;
    AA1:=STRCAT(CON2STR(YEAR,0),'年');
    AA2:=STRCAT(CON2STR(MONTH,0),'月');
    AA3:=STRCAT(CON2STR(DAY,0),'日');
    AA4:=STRCAT('【',IF(WEEKDAY=1,'一',IF(WEEKDAY=2,'二',IF(WEEKDAY=3,'三',IF(WEEKDAY=4,'四',IF(WEEKDAY=5,'五',IF(WEEKDAY=6,'六','日')))))));
    AA0:=STRCAT(STRCAT(STRCAT(AA1,AA2),STRCAT(AA3,AA4)),'】');
    DRAWTEXT_FIX(D1,0.09,0.07,0,AA0),COLORLIBLUE;

    {三根K线判断走势强弱}
    A1:=REF(H,1);
    A2:=REF(H,2);
    A3:=REF(H,3);
    A4:=REF(H,4);
    B1:=REF(L,1);
    B2:=REF(L,2);
    B3:=REF(L,3);
    B4:=REF(L,4);
    A31:=C>MAX(A1,A2);
    B31:=C<MIN(B1,B2);
    A41:=A31 AND REF(A31,1) AND MAX(A3,MAX(A1,A2));
    B41:=B31 AND REF(B31,1) AND MIN(B3,MIN(B1,B2));
    A51:=A41 AND REF(A41,1) AND MAX(A4,MAX(A3,MAX(A1,A2)));
    B51:=B41 AND REF(B41,1) AND MIN(B4,MIN(B3,MIN(B1,B2)));
    DRAWTEXT(A31 AND ISLASTBAR,H*1.01,'转强'),COLORYELLOW;
    DRAWTEXT(B31 AND ISLASTBAR,L*0.99,'转弱'),COLORGREEN;
    DRAWTEXT(A41 AND ISLASTBAR,H*1.01,'转强转多'),COLORYELLOW;
    DRAWTEXT(B41 AND ISLASTBAR,L*0.99,'转弱转空'),COLORGREEN;
    DRAWTEXT(A51 AND ISLASTBAR,H*1.01,'转强转多涨势'),COLORYELLOW;
    DRAWTEXT(B51 AND ISLASTBAR,L*0.99,'转弱转空跌势'),COLORGREEN;

    {SAR抛物线【指标】}
    持仓:=IF(CLOSE>=SAR(4,2,20),SAR(4,2,20),DRAWNULL),COLORRED;
    空仓:=IF(CLOSE<=SAR(4,2,20),SAR(4,2,20),DRAWNULL),COLORGREEN;
    BS:=STICKLINE(C/REF(C,1)>1.095,O,C,1.5,0),COLORYELLOW;
    SAR持仓标识:DRAWTEXT(CLOSE>=SAR(4,2,20),SAR(4,2,20)-0.3,'●')COLOR0099FF;
    SAR空仓标识:DRAWTEXT(CLOSE<=SAR(4,2,20),SAR(4,2,20)+0.3,'●')COLORFF0033;

    {量价走势}
    量价曲线走势VPT:=SUM(VOL*(CLOSE-REF(CLOSE,1))/REF(CLOSE,1),N2)COLORRED;
    曲线慢线MAVPT:=MA(VPT,M2)COLORYELLOW;
    量价区间多头:=量价曲线走势VPT>=(0)COLORRED;
    量价区间空头:=量价曲线走势VPT<(0)COLORGREEN;
    曲线多头标注:DRAWTEXT_FIX(CURRBARSCOUNT=1 AND 量价区间多头,0.735,0.03,0,'量价区间多头( + 18分) ，量价多头，酌情做票。')COLORRED;
    曲线空头标注:DRAWTEXT_FIX(CURRBARSCOUNT=1 AND 量价区间空头,0.785,0.03,0,'量价区间空头，交易还需谨慎。')COLORGREEN;

    {个股强弱打分}
    满分加:=MACD>(0) && C>=(BBIBOLL) && C>=(庄家成本) && 通线>=(子线) && C>=(年线) && C>=(平均成本线) && 量价曲线走势VPT>=(0);
    满分多头标注:DRAWTEXT_FIX(CURRBARSCOUNT=1 AND 满分加,0.612,0.97,0,'个股，80分以上可以做多，100以上才可以重仓。目前，该股满100分后又填“+”. 计118分。完全可以伺机会予以重仓。')COLORRED;
    通子线色块:=DRAWBAND(通线,RGB(85,26,139),子线,RGB(0,100,0));

    {蓝色K线系列}
    标识02:STICKLINE(CLOSE=OPEN,HIGH,LOW,0,0),COLORCYAN;
    标识03:STICKLINE(CLOSE=OPEN,CLOSE,OPEN,3,0),COLORCYAN;
    标识04:STICKLINE(CLOSE>OPEN,HIGH,CLOSE,0,0),COLORCYAN;
    标识05:STICKLINE(CLOSE>OPEN,LOW,OPEN,0,0),COLORCYAN;
    标识06:STICKLINE(CLOSE>OPEN,OPEN,CLOSE,3,1),COLORCYAN;
    标识07:STICKLINE(OPEN>CLOSE,HIGH,LOW,0,0),COLORCYAN;
    标识08:STICKLINE(OPEN>CLOSE,OPEN,CLOSE,3,0),COLORCYAN;
    标识09:STICKLINE(CLOSE<MA5 AND OPEN>=CLOSE,HIGH,LOW,0,0),COLORCYAN;
    标识10:STICKLINE(CLOSE<MA5 AND OPEN>=CLOSE,OPEN,CLOSE,3,0),COLORCYAN;
    标识11:STICKLINE(CLOSE<MA5 AND OPEN<CLOSE,HIGH,CLOSE,0,0),COLORCYAN;
    标识12:STICKLINE(CLOSE<MA5 AND OPEN<CLOSE,OPEN,LOW,0,0),COLORCYAN;
    标识13:STICKLINE(CLOSE<MA5 AND OPEN<CLOSE,OPEN,CLOSE,3,1),COLORCYAN;
    {红K线系列}
    标识14:STICKLINE(CLOSE>MA5 AND CLOSE>OPEN,HIGH,CLOSE,0,0),COLORRED;
    标识15:STICKLINE(CLOSE>MA5 AND CLOSE>OPEN,LOW,OPEN,0,0),COLORRED;
    标识16:STICKLINE(CLOSE>MA5 AND CLOSE>OPEN,OPEN,CLOSE,3,1),COLORRED;
    标识17:STICKLINE(CLOSE>MA5 AND CLOSE<=OPEN,HIGH,LOW,0,0),COLORRED;
    标识18:STICKLINE(CLOSE>MA5 AND CLOSE<=OPEN,OPEN,CLOSE,3,0),COLORRED;
    标识19:STICKLINE(CLOSE>MA5 AND MA10>REF(MA10,1) AND CLOSE>OPEN,HIGH,CLOSE,0,0),COLORRED;
    标识20:STICKLINE(CLOSE>MA5 AND MA10>REF(MA10,1) AND CLOSE>OPEN,OPEN,LOW,0,0),COLORRED;
    标识22:STICKLINE(CLOSE>MA5 AND MA10>REF(MA10,1) AND CLOSE>OPEN,OPEN,CLOSE,3,1),COLORRED;
    标识23:STICKLINE(CLOSE>MA5 AND MA10>REF(MA10,1) AND CLOSE<=OPEN,HIGH,LOW,0,0),COLORRED;
    标识24:STICKLINE(CLOSE>MA5 AND MA10>REF(MA10,1) AND CLOSE<=OPEN,OPEN,CLOSE,3,0),COLORRED;