【原】Excel查找时最常用的4个案例，全都会写算你牛！

与 30万 读者一起学Excel

查找基本上任何人都会接触到，通过某某查找某某，很神奇的一个功能。

1.明细表是泸州老窖的出货情况，想知道最后一天出货的产品及规格、数量，该如何查找？

使用公式：

=LOOKUP("座",C2:C13)

=LOOKUP(9E+307,F2:F13)

这个9E+307跟“座”是什么意思？

先来看看下面几条公式

=LOOKUP(2000,{105;135;54;49;300;900;360;140;400;1500;201;200})

返回200。

=LOOKUP(5000,{105;135;54;49;300;900;360;140;400;1500;201;200})

返回200。

=LOOKUP(10000,{105;135;54;49;300;900;360;140;400;1500;201;200})

返回200。

通通都返回最后一个数字200，也就是说，LOOKUP函数查找到最后一个满足条件的值，在数字不确定的情况下，查找的值越大也能保证查找到的值得准确性。9E+307一个很大很大的数字，Excel允许最大的数字不能超过15位，而9E+307是9乘以10的307次方，比最大值还要大，查找最后一个值是相当的保险。而座是一个接近最大的文本，虽然还有比“座”还大的文本，但正常情况不会出现，所以写“座”就能查找到最后一个文本。

如果要想获取查找文本或者数字的通用公式，可以利用LOOKUP函数的经典查找模式。

=LOOKUP(1,0/(C2:C13<>""),C2:C13)

2.姓名或者工号查找工资，很多时候我们能记住的就是其中一个而已。

常规法就是用VLOOKUP进行两次查找，第一次查找不到对应值，再进行一次查找。

=IFERROR(VLOOKUP(E2,B:C,2,),VLOOKUP(E2,A:C,3,))

当然我们也可以动点脑筋，姓名跟工号都是在同一行，只要知道行号，再嵌套个INDEX函数也可以获取对应值。可以让区域A$2:B$10跟E2进行比较，只要两列有一列符合条件就显示本身行号，输入公式后，按Ctrl+Shift+Enter三键结束。

=MAX((A$2:B$10=E2)*ROW($2:$10))

最后公式为，按Ctrl+Shift+Enter三键结束。

=INDEX(C:C,MAX((A$2:B$10=E2)*ROW($2:$10)))

3.是每个目的地的价钱明细，现在如何跨表查询各个区间的价钱。

查询表

第一想法肯定是判定目的地，然后进行查询，如池州。

=IF(B$1="池州",VLOOKUP(A4,池州!A:B,2,))

同理每个目的地就设置一个VLOOKUP函数，虽然这样可以解决问题，但非常繁琐，还容易出错。

B$1="池州"，就在池州这个工作表查找，也就是引用这个工作表名，因为单元格是变动的，直接间接引用，INDIRECT函数引用数据就是间接引用的。

=INDIRECT(B$1&"!A1")

就是间接引用池州这个工作表的A1单元格。

最终公式为：

=VLOOKUP(A4,INDIRECT(B$1&"!A:B"),2,)

4.查找还有一个很有趣的功能，就是查找图片。根据花名查找图片。

Step 01 使用名称引用动态图片，定义一个叫花的名称。单击“公式”选项卡中的“定义名称”按钮。在“名称”文本框输入“动态数据源”，“引用位置”输入下面的公式，最后单击“确定”按钮。

=INDEX(Sheet1!$A:$A,MATCH(Sheet1!$D$2,Sheet1!$B:$B,))

Step 02 选择D2单元格，单击“数据”选项卡中的“数据验证”按钮，弹出“数据验证”对话框。在“允许”下拉菜单中选择“序列”命令，在“来源”编辑框中引用下面的区域，单击“确定”按钮。

=$B$2:$B$4

Step 03 插入任意一张图片，在编辑栏输入公式“=花”，回车后图片就会自动改变，最后再稍微调整下图片的位置及大小。

以上案例，你全都会吗？

一次报名成为VIP会员，所有课程永久免费学，采用录制视频+微信答疑的形式学习，仅需888元，待你加入。

推荐：厉害了，lookup还能这样玩

上篇：真伤脑，这份考勤表整理了2个小时，头痛！

在查找的时候，你还遇到过什么问题？

作者：卢子，清华畅销书作者，《Excel效率手册 早做完，不加班》系列丛书创始人，个人公众号：Excel不加班（ID：Excelbujiaban）