第五讲 ADO连接Access，前期绑定与后期绑定方法实例

在上一讲中，讲了几种连接方案，ADO连接时讲了两种方案，一是前期通过引用来绑定ADO,还有一种是后期在代码中绑定，这讲中我将结合实际问题来具体的讲解一下这两种方案的利用。

实际需求：利用VBA打开一个如下面图示的数据库，打开后提示连接成功，并提示ADO版本号。

  

1  后期绑定方法

也就是说在程序中绑定ADO，这种方案代码稍微多些，我们先看代码：

Sub mynzConnection_5()

    Dim cnADO As Object

    Dim strPath As String

    strPath = ThisWorkbook.Path & "\mydata.accdb"

    Set cnADO = CreateObject("ADODB.Connection")

       With cnADO

        .Provider = "Microsoft.ACE.OLEDB.12.0"

        .ConnectionTimeout = 100

        .Open strPath

    End With

    If cnADO.State = 1 Then

        MsgBox "数据库连接成功！" & vbCrLf & _

            vbCrLf & "ADO版本为：" & cnADO.Version & vbCrLf & _

            vbCrLf & "Connection对象提供者名称：" & cnADO.Provider

        cnADO.Close

        Set cnADO = Nothing

    Else

        MsgBox "数据库连接失败！", vbInformation, "连接数据库"

    End If

End Sub

代码截图：

  

代码解析：上述代码是ADO后期绑定的一个典型的代码，大家可以收藏并利用它。

① strPath = ThisWorkbook.Path & "\mydata.accdb"语句把数据库存在的路径放在了变量strPath中。

②下面的语句创建一个ADO连接，并打开。

Set cnADO = CreateObject("ADODB.Connection")

       With cnADO

        .Provider = "Microsoft.ACE.OLEDB.12.0"

        .ConnectionTimeout = 100

        .Open strPath

    End With

③ 如果已经打开就提供ADO的版本号等信息

  If cnADO.State = 1 Then

        MsgBox "数据库连接成功！" & vbCrLf & _

            vbCrLf & "ADO版本为：" & cnADO.Version & vbCrLf & _

            vbCrLf & "Connection对象提供者名称：" & cnADO.Provider

 

 ④ 最后关闭连接

      cnADO.Close

        Set cnADO = Nothing

我们看看实际的运行结果：

  

2  我们再看看前期绑定的时候该如何书写代码

这种方式代码非常的简单：

Sub mynzConnection_5_2()

    Dim cnADO As New ADODB.Connection

    Dim strPath As String

    strPath = ThisWorkbook.Path & "\mydata.accdb"

    cnADO.Open "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & strPath

    If cnADO.State = adStateOpen Then

        MsgBox "数据库连接成功！" & vbCrLf & _

            vbCrLf & "ADO版本为：" & cnADO.Version & vbCrLf & _

            vbCrLf & "Connection对象提供者名称：" & cnADO.Provider

        cnADO.Close

        Set cnADO = Nothing

    Else

        MsgBox "数据库连接失败！"

    End If

End Sub

代码截图：

  

代码讲解,

① 和上述代码不同的是这里用了Dim cnADO As New ADODB.Connection 即声明了一个新的ADO连接

② 这个时候直接打开连接即可：

cnADO.Open "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & strPath

看我们代码的运行：

特别提示：运行前一定要引用上ADO，我这里只是给出截图，如何设置引用在上节已经讲过，这种连接方法和上面的方法都是在实际中可以利用的方法，需要的朋友一定要收藏，不必再去编写代码，测试了，

  代码的运行：

 

上面就是两种绑定方案的讲解。这两种方案可以在实际代码中利用它。