低风险低位大跌股池v1.0

在已发表的文章《我的交易体系：迷雾寻踪》里，提出了一种选股策略：低风险、低位的个股，某天出现了放量大跌。其中低风险可以通过股东性质（国有）、所在行业（价值型）、市值与上市时间、限定选股范围等方面加以控制，当然大跌也是在释放风险；放量表明有多方力量在（低位）承接。

这个选股策略放到交易体系的背景中去思考，像是逆向投资。不过我的意图是做反弹，所以更像是一种策略交易，逆向投资并不确切。

通过编制通达信公式，可以实现高效选股，得到一个初级股票池。如果把A股所有股票视为一个最大的股票池，那么我们要做的就是想办法缩小这个股票池。

初级股票池中的个股并不能直接采用，需要对基本面进行研究。还需要了解清楚大跌的原因，不能有逻辑方面的硬伤，如果是公布的业绩不及预期，很可能已经体现在股价上了，此时挖坑反而是机会。

对初级股票池中的个股进行筛选后，就可以制定交易计划了，包括买点、止盈、止损、仓位等。

公式名称：双低大跌。公式如下：

K2:= 1.1; {一般固定取1.1}

K3:= 1; {涨跌幅度系数，1.0~3.0}

K4:= 1; {成交量系数，0.5~3.0}

K21:= 1; {可以取1, 1.5, 2。数值大则选股结果少}

N:= 5; {用于第2单元，可以取3,4,5}

M:= 250*K21; {用于第2单元，最低价对应的时间长度}

{}{}{}{}{}{}

{第1单元。规定上市时间、流通市值}

A11:= BARSCOUNT(C)>250*3; {上市3年以上}

A12:= FINANCE(40); {流通市值}

A13:= 10000*10000; {1亿}

A14:= A12>= 50*A13 AND A12 <= 3000*A13; {流通市值50亿和3000亿之间}

C1:= A11 AND A14;

{}{}{}{}{}{}

{第2单元。规定股价处于某个低位}

{第2-1单元}

A21:= REF(LLV(L, (M-N)), N); { N日前的(M-N)日内 最低价的最小值}

C2:= LLV(L,N) <= A21*K2; {最近N日内 最低价的最小值 小于等于 A21 的K2倍，即，最近N日内至少有1日的最低价小于等于 A21 的K2倍。当K2等于1时，表示创新低}

{第2-2单元}

C2:= LLV(L,N) <= LLV(L,M)*K2; {最近N日内 最低价的最小值 小于等于 最近M日内 最低价的最小值 的K2倍；即，最近N日内至少有1日的最低价 小于等于 最近M日内 最低价的最小值 的K2倍。当K2等于1时，表示创新低}

{第2-3单元}

A21:= CONST( REF(LLV(L, (M-N)), N) ); { N日前的(M-N)日内 最低价的最小值；将CONST去掉，结果相同，保险起见予以保留}

C2:= COUNT(L<=A21*K2 ,N) >= 1; {最近N日内，至少有1日的最低价小于等于 A21 的K2倍}

{}{}{}{}{}{}

{第3单元。规定下跌幅度，大跌}

A31:= (CLOSE - REF(CLOSE, 1))/ REF(CLOSE, 1);

A32:= IF(CLOSE < REF(CLOSE, 1) ,A31, 0); {筛选出收跌时的涨跌幅度，剔除收涨时的涨跌幅度}

C3:= A31<=REF(LLV(A32,10),1)*K3; {当日跌幅大于1日前的10日内下跌日最大跌幅的K3倍}

{}{}{}{}{}{}

{第4单元。规定成交量，放量}

A41:= IF(CLOSE < REF(CLOSE, 1) ,V, 0); {当日收跌时返回当日成交量，否则返回0；筛选出收跌时的成交量，剔除收跌时的成交量}

C4:= VOL>=REF(HHV(A41,10),1)*K4; {当日成交量大于1日前的10日内 下跌日 最大成交量的K4倍}

{}{}{}{}{}{}

{条件综合}

C1 AND C2 AND C3 AND C4;

其中第2单元有3种实现方式，任选一种即可（需要将其它两种删除），选股结果是相同的。

以上公式仅是一个框架，需要完善。从实践的角度，最重要的是看图，找出经典的图，在图中寻找灵感，总结出特征，将其体现进公式中。从理论的角度，则要探究现象背后的市场意义。

选股结果（220902）：

详细结果：

结果举例：