关于评分公式

很多同学反映的情况是，主图没有显示评分。

这里有两点考量：

1.评分公式是特定时期模仿的低位假阳康桥。也就是说，低位假阳康桥批量出现涨停板的时候，评分公式才有用武之地。

2.安装困难

可不可以加上？

当然可以

主图指标上加上这一段：

评分:短线评分.PF,NODRAW;

另外需要说明的是评分指标需要单独安装：

ZF:=C=ZTPRICE(REF(C,1),0.1)  AND NOT(CODELIKE('688')) AND  NOT(CODELIKE('300'));

ZE:=C=ZTPRICE(REF(C,1),0.2) AND NOT(CODELIKE('00')) AND  NOT(CODELIKE('60'));

{ZTB:=C=ZTPRICE(REF(C,1),0.1);}

ZTB:=ZF OR ZE;

YZB:=H=L AND C>REF(C,1);

近有板:=EXIST(ZTB,8);{8交易日内有板}

百高:=V=HHV(V,100);

百高涨停:=ZTB AND 百高;

板后百高:=百高 AND REF(ZTB,1) AND NOT(ZTB);

假阳:=C>O AND C<REF(C,1);{此处假阴是否显性即可？是否要求缩量？}

百高后假阳:=假阳 AND EXIST(板后百高,5);

倍量过二四:=V>REF(V,1)*1.95 AND C>MA(C,24) AND REF(C,1)<MA(REF(C,1),24);

{此处倍量上穿24包含了假阴和阳线穿越}

百高前过二四:=板后百高 AND EXIST(倍量过二四,24);{百高前8天内出现倍量过24线}

收阳:=C>REF(C,1);{含阳线或假阴}

收阴:=C<REF(C,1);{含阴线或假阳}

{连阴:=收阴 AND REF(收阴,1);}

破阳:=收阴 AND (REF(收阴,1) OR REF(收阴,2));

大阴:=收阴 AND C<REF(C,2);

八连阳普:=COUNT(收阳,7)>5 AND NOT(EXIST(破阳,8)) AND NOT(EXIST(大阴,8)) AND REF(收阳,6)

AND (REF(收阳,7) OR (REF(L,6)>REF(C,7) AND REF(C,7)>REF(O,7) AND REF(C,7)<REF(C,8)))

AND 收阳 AND NOT(EXIST(ZTB,8));

七连阳特:=COUNT(收阳,6)>4 AND NOT(EXIST(破阳,7)) AND NOT(EXIST(大阴,7)) AND REF(收阳,5)

AND (REF(收阳,6) OR (REF(L,5)>REF(C,6) AND REF(C,6)>REF(O,6) AND REF(C,6)<REF(C,7)))

AND 收阳 AND REF(收阳,1) AND NOT(EXIST(ZTB,7));

七连阳阴:=REF(七连阳特,1) AND 收阴;

八连阳紧跟:=八连阳普 OR 七连阳阴;

八连阳松跟:=八连阳普 OR (收阳 AND REF(七连阳阴,1) AND NOT(ZTB));

{八连阳:八连阳紧跟 OR 八连阳松跟};

五连阳普:=COUNT(收阳,4)>2 AND NOT(EXIST(破阳,5)) AND NOT(EXIST(大阴,5)) AND REF(收阳,3)

AND (REF(收阳,4) OR (REF(L,3)>REF(C,4) AND REF(C,4)>REF(O,4) AND REF(C,4)<REF(C,5)))

AND 收阳 AND NOT(EXIST(ZTB,5));

四连阳特:=COUNT(收阳,3)>2 AND NOT(EXIST(破阳,4)) AND NOT(EXIST(大阴,4)) AND REF(收阳,2)

AND (REF(收阳,3) OR (REF(L,2)>REF(C,3) AND REF(C,3)>REF(O,3) AND REF(C,3)<REF(C,4)))

AND 收阳 AND REF(收阳,1) AND NOT(EXIST(ZTB,4));

四连阳阴:=REF(四连阳特,1) AND 收阴;

五连阳紧跟:=NOT(八连阳普 OR 七连阳特) AND (五连阳普 OR 四连阳阴);

五连阳松跟:=NOT(八连阳普 OR 七连阳特) AND (五连阳普 OR (收阳 AND REF(四连阳阴,1) AND NOT(ZTB)));

{五连阳:=NOT(八连阳紧跟 OR 八连阳松跟) AND (五连阳紧跟 OR 五连阳松跟);这个地方讨论一下？--分割后便于阅读}

三连阳普:=(COUNT(收阳,3)=3 OR

((REF(C,2)>REF(O,2) AND REF(C,2)<REF(C,3) AND REF(L,1)>REF(C,2)) AND COUNT(收阳,2)=2))

AND NOT(EXIST(ZTB,3));

二连阳特:=COUNT(收阳,2)=2 OR (收阳 AND REF(C,1)>REF(O,1) AND REF(C,1)<REF(C,2) AND

L>REF(C,1)) AND NOT(ZTB);

二连阳阴:=收阴 AND REF(二连阳特,1);

三连阳紧跟:=NOT(八连阳普 OR 七连阳特) AND NOT(五连阳普 OR 四连阳特) AND (三连阳普 OR 二连阳阴);

三连阳松跟:=NOT(八连阳普 OR 七连阳特) AND NOT(五连阳普 OR 四连阳特) AND

(三连阳普 OR (收阳 AND REF(二连阳阴,1) AND NOT(ZTB)));

破阴:=收阳 AND (REF(收阳,1) OR REF(收阳,2));

大阳:=收阳 AND C>REF(C,2);

八连阴普:=COUNT(收阴,7)>5 AND NOT(EXIST(破阴,8)) AND NOT(EXIST(大阳,8)) AND REF(收阴,6)

AND (REF(收阴,7) OR REF(C,7)<REF(O,7)) AND 收阴;

七连阴特:=COUNT(收阴,6)>4 AND NOT(EXIST(破阴,7)) AND NOT(EXIST(大阴,7)) AND REF(收阴,5)

AND (REF(收阴,6) OR REF(C,6)<REF(O,6)) AND REF(收阴,1) AND 收阴;

七连阴阳:=收阳 AND REF(七连阴特,1);

八连阴:=八连阴普 OR (收阴 AND REF(收阴,1) AND REF(七连阴阳,2));

{如果7连阴后面跟单阳，则必须后续2根均为阴线才可以确认是9连阴，同时也符合8连阴

如果7连阴后面跟单阳再跟单阴，智能确认7连阴}

五连阴普:=COUNT(收阴,4)>2 AND NOT(EXIST(破阴,5)) AND NOT(EXIST(大阳,5)) AND REF(收阴,3)

AND (REF(收阴,4) OR REF(C,4)<REF(O,4)) AND 收阴;

四连阴特:=COUNT(收阴,3)>2 AND NOT(EXIST(破阴,4)) AND NOT(EXIST(大阳,4)) AND REF(收阴,2)

AND (REF(收阴,3) OR REF(C,3)<REF(O,3)) AND REF(收阴,1) AND 收阴;

四连阴阳:=收阳 AND REF(四连阴特,1);

五连阴:=NOT(八连阴) AND (五连阴普 OR (收阴 AND REF(收阴,1) AND REF(四连阴阳,2)));

{三连阴:=NOT(八连阴) AND NOT(五连阴) AND COUNT(收阴,4)>2 AND 收阴 AND NOT(EXIST(大阳,3));}

三连阴普:=COUNT(收阴,3)=3 OR ((REF(C,2)<REF(O,2) AND REF(C,2)>REF(C,3)) AND COUNT(收阴,2)=2);

二连阴特:=收阴 AND (REF(收阴,1) OR (REF(C,1)<REF(O,1) AND REF(C,1)>REF(C,2)));

二连阴阳:=收阳 AND REF(二连阴特,1);

三连阴:=NOT(八连阴) AND NOT(五连阴) AND (三连阴普 OR (收阴 AND REF(收阴,1) AND REF(二连阴阳,2)));

ZTR:=BARSLAST(ZTB);

连阳分:=IF(EXIST(ZTB AND (REF(八连阳紧跟,1) OR EXIST(八连阳松跟,5)),8),2,

IF(EXIST(ZTB AND (REF(五连阳紧跟,1) OR EXIST(五连阳松跟,5)),8),1.5,

IF(EXIST(ZTB AND (REF(三连阳紧跟,1) OR EXIST(三连阳松跟,5)),8),1,0)));

八假阳连阳:=(八连阳紧跟 OR 八连阳松跟) AND REF(假阳,7);

五假阳连阳:=(五连阳紧跟 OR 五连阳松跟) AND REF(假阳,4);

三假阳连阳:=(三连阳紧跟 OR 三连阳松跟) AND REF(假阳,2);

假阳连阳:=八假阳连阳 OR 五假阳连阳 OR 三假阳连阳;

假阳连阳板:=ZTB AND EXIST(假阳连阳,5);

连阴分:=IF(EXIST(ZTB,8) AND EXISTR(八连阴,100+ZTR,ZTR),2,

IF(EXIST(ZTB,8) AND EXISTR(五连阴,100+ZTR,ZTR),1.5,

IF(EXIST(ZTB,8) AND EXISTR(三连阴,100+ZTR,ZTR),1,0)));

百日有板:=EXISTR(ZTB,100+ZTR,ZTR);

跳空:=L>REF(C,1);

板前跳空:=ZTB AND EXISTR(跳空,8,1);

XM1:=近有板;

XM2:=IF(EXIST(百高涨停,8),0.5,IF(EXIST(板后百高,7),1,0));

XM3:=百高后假阳 AND XM1;

XM4:=IF(BARSCOUNT(C)<25,0,EXIST(百高前过二四,8)) AND XM1;

XM5:=连阳分;

XM6:=EXIST(假阳连阳板,8) AND XM1;

XM7:=连阴分;

XM8:=百日有板 AND XM1;

XM9:=EXIST(板前跳空,8) AND XM1;

八内B:XM1;

百高板后:XM2;

百高假阳:XM3;

倍过二四:XM4;

连阳得分:XM5;

假阳连:XM6;

连阴得分:XM7;

百日有B:XM8;

板前缺:XM9;

PF:XM1+XM2+XM3+XM4+XM5+XM6+XM7+XM8+XM9;