【原】通达信井喷式买入副图选股公式（附源码破译和源码）

编程思路破译

RSV赋值:(收盘价-30日内最低价的最低值)/(30日内最高价的最高值-30日内最低价的最低值)*100-50

KV赋值:RSV的3日[1日权重]移动平均

DV赋值:KV的3日[1日权重]移动平均

JV赋值:3*KV-2*DV

ZDZK1赋值:JV的6日指数移动平均

ZDZK2赋值:1日前的ZDZK1

输出做多:如果ZDZK1>=ZDZK2,返回ZDZK1+2,否则返回ZDZK2,,画红色

输出做空:如果ZDZK2-ZDZK1,返回ZDZK2,否则返回ZDZK1,,COLOR334499

XW1赋值:如果开盘价<=1日前的开盘价,返回0,否则返回(最高价-开盘价)和(开盘价-1日前的开盘价)的较大值

XW2赋值:如果开盘价>=1日前的开盘价,返回0,否则返回(开盘价-最低价)和(开盘价-1日前的开盘价)的较大值

XW3赋值:XW1的21日累和

XW4赋值:XW2的21日累和

XW5赋值:如果XW3>XW4,返回(XW3-XW4)/XW3,否则返回如果XW3=XW4,返回0,否则返回(XW3-XW4)/XW4

RS赋值:收盘价-1日前的收盘价和0的较大值的14日[1日权重]移动平均/收盘价-1日前的收盘价的绝对值的14日[1日权重]移动平均*100

ZD赋值: RS的7日指数移动平均的3日指数移动平均的3日指数移动平均

ZD1赋值:(ZD-1日前的ZD)/1日前的ZD*15

当满足条件ZD1>=0时,在0和ZD1*50位置之间画柱状线,宽度为4,0不为0则画空心柱.,COLOR0000BE

当满足条件ZD1<=0时,在0和ZD1*50位置之间画柱状线,宽度为4,0不为0则画空心柱.,COLORCDFF88

Y1赋值:成交额(元)/成交量(手)/100

Y2赋值:(3*最高价+最低价+开盘价+2*收盘价)/7

Y3赋值:100*(以1.1*收盘价元价格计算的获利盘比例-以0.9*收盘价计算的获利盘比例)

Y4赋值:成交额(元)的13日累和/Y1/100

Y5赋值: 以成交量(手)/Y4为权重Y2的动态移动平均

Y6赋值:(收盘价-Y5)/Y5*100

Y7赋值:(Y3< 10) AND (Y6<=-10)

Y8赋值:收盘价-1.5日前的收盘价和0的较大值的6日[1日权重]移动平均/收盘价-1.5日前的收盘价的绝对值的6日[1日权重]移动平均*100

输出重亏:当满足条件Y6<=-10ANDZD1<0时,在ZD1*55和ZD1*45位置之间画柱状线,宽度为6,0不为0则画空心柱.,COLORFF89B2

输出全亏:当满足条件Y6<=-16ANDZD1<0时,在ZD1*60和ZD1*55位置之间画柱状线,宽度为6,1不为0则画空心柱.,画蓝色

输出超跌:当满足条件Y7ANDZD1<0时,在ZD1*65和ZD1*60位置之间画柱状线,宽度为6,0不为0则画空心柱.,COLORFFFFFF

JCT赋值:100*(收盘价-获利盘为10%的成本分布)/获利盘为10%的成本分布

如果收盘价,返回如果JCT<0,返回JCT,否则返回0*3,否则返回0,画白色

ZDD1赋值:(21日内最高价的最高值-收盘价)/(21日内最高价的最高值-21日内最低价的最低值)*100-10

ZDD2赋值:(收盘价-21日内最低价的最低值)/(21日内最高价的最高值-21日内最低价的最低值)*100

ZDD3赋值:ZDD2的13日[8日权重]移动平均

ZDD4赋值:ZDD3的13日[8日权重]移动平均的向上舍入

ZDD5赋值:ZDD1的21日[8日权重]移动平均

XH1赋值:收盘价-2日前的收盘价和0的较大值的7日[1日权重]移动平均/收盘价-2日前的收盘价的绝对值的7日[1日权重]移动平均*100

XH2赋值:ZDD4-ZDD5< -65 AND XH1< 12

输出备战区:当满足条件XH2时,在0位置画12号图标,COLOR006EFF

当满足条件XH2时,在0和ZD1*20位置之间画柱状线,宽度为4,0不为0则画空心柱.,COLOR006EFF

XX1赋值:最低价的2日简单移动平均*0.96

XX2赋值:最低价的26日简单移动平均*0.85

XX3赋值: 1日前的XX1< XX2 AND 1日前的XX1< XX1 AND 1日前的XX1< 2日前的XX1

当满足条件XX3时,在0和ZD1*16位置之间画柱状线,宽度为4,0不为0则画空心柱.,COLOR006EFF

当满足条件XX3时,在0位置画12号图标

C0赋值:2日前的收盘价*0.865

C1赋值:13日前的收盘价*0.772

DSY赋值:100*成交量(手)/当前流通股本(手)

当满足条件(收盘价-C0和C1的较小值)/收盘价<0.1ANDSUM(DSY,5)/5<1.8时,在0和ZD1*25位置之间画柱状线,宽度为4,0不为0则画空心柱.,COLOR006EFF

当满足条件(收盘价-C0和C1的较小值)/收盘价<0.1ANDSUM(DSY,5)/5<1.8时,在0位置画12号图标

WW1赋值: 收盘价的10日简单移动平均的9日累和/10.110

WW2赋值:收盘价上穿WW1

当满足条件WW2时,在0和ZD1*26位置之间画柱状线,宽度为4,0不为0则画空心柱.,COLOR006EFF

当满足条件WW2时,在0位置画12号图标

VW1赋值:以成交量(手)的5日累和/3/当前流通股本(手)为权重收盘价的12日指数移动平均的动态移动平均

VW2赋值:10日前的最高价/收盘价>1.35

VW3赋值:(获利盘为20%的成本分布-收盘价)/收盘价>0.15

VW4赋值:最高价>最低价*1.051

VW5赋值:VW4 AND 统计5日中满足VW4的天数>1

VW6赋值:(((收盘价-VW1)/VW1*100< -30) OR VW2) AND VW3 AND VW5

当满足条件VW6时,在0和ZD1*40位置之间画柱状线,宽度为4,0不为0则画空心柱.,COLOR0000FF

当满足条件VW6时,在0位置画6号图标

XL1赋值:最低价的2日简单移动平均*0.96

XL2赋值:最低价的26日简单移动平均*0.85

XL3赋值:1日前的XL1< XL2 AND 1日前的XL1< XL1 AND 1日前的XL1< 2日前的XL1

当满足条件XL3时,在0和15位置之间画柱状线,宽度为4,0不为0则画空心柱.,COLORF8B7F0

当满足条件XL3时,在25位置书写文字,COLORF8B7F0

JJP1赋值:1日前的大盘的收盘价

JJP2赋值:(大盘的收盘价-JJP1)/JJP1>0.03ANDZDZK1>=ZDZK2的7日过滤

当满足条件JJP2时,在0和-15位置之间画柱状线,宽度为4,0不为0则画空心柱.,COLORFF00FF

当满足条件JJP2时,在-15位置书写文字,COLORFF00FF

程序源码

RSV:=(C-LLV(L,30))/(HHV(H,30)-LLV(L,30))*100-50;

KV:=SMA(RSV,3,1);

DV:=SMA(KV,3,1);

JV:=3*KV-2*DV;

ZDZK1:=EMA(JV,6);

ZDZK2:=REF(ZDZK1,1);

做多:IF(ZDZK1>=ZDZK2,ZDZK1+2,ZDZK2),,COLORRED;

做空:IF(ZDZK2-ZDZK1,ZDZK2,ZDZK1),,COLOR334499;

XW1:=IF(O<=REF(O,1),0,MAX((H-O),(O-REF(O,1))));

XW2:=IF(O>=REF(O,1),0,MAX((O-L),(O-REF(O,1))));

XW3:=SUM(XW1,21);

XW4:=SUM(XW2,21);

XW5:=IF(XW3>XW4,(XW3-XW4)/XW3,IF(XW3=XW4,0,(XW3-XW4)/XW4));

RS:=SMA(MAX(C-REF(C,1),0),14,1)/SMA(ABS(C-REF(C,1)),14,1)*100;

ZD:= EMA(EMA(EMA(RS,7),3),3);

ZD1:=(ZD-REF(ZD,1))/REF(ZD,1)*15;

STICKLINE(ZD1>=0,0,ZD1*50,4,0),COLOR0000BE;

STICKLINE(ZD1<=0,0,ZD1*50,4,0),COLORCDFF88;

Y1:=AMOUNT/V/100;

Y2:=(3*H+L+O+2*C)/7;

Y3:=100*(WINNER(1.1*C)-WINNER(0.9*C));

Y4:=SUM(AMOUNT,13)/Y1/100;

Y5:= DMA(Y2,V/Y4);

Y6:=(C-Y5)/Y5*100;

Y7:=(Y3< 10) AND (Y6<=-10);

Y8:=SMA(MAX(C-REF(C,1.5),0),6,1)/SMA(ABS(C-REF(C,1.5)),6,1)*100;

重亏:STICKLINE(Y6<=-10 AND ZD1< 0,ZD1*55,ZD1*45,6,0),COLORFF89B2;

全亏:STICKLINE(Y6<=-16 AND ZD1< 0,ZD1*60,ZD1*55,6,1),COLORBLUE;

超跌:STICKLINE(Y7 AND ZD1< 0,ZD1*65,ZD1*60,6,0),COLORFFFFFF;

JCT:=100*(C-COST(10))/COST(10);

IF(C,IF(JCT< 0,JCT,0)*3,0),COLORWHITE;

ZDD1:=(HHV(H,21)-C)/(HHV(H,21)-LLV(L,21))*100-10;

ZDD2:=(C-LLV(L,21))/(HHV(H,21)-LLV(L,21))*100;

ZDD3:=SMA(ZDD2,13,8);

ZDD4:=CEILING(SMA(ZDD3,13,8));

ZDD5:=SMA(ZDD1,21,8);

XH1:=SMA(MAX(C-REF(C,2),0),7,1)/SMA(ABS(C-REF(C,2)),7,1)*100;

XH2:=ZDD4-ZDD5< -65 AND XH1< 12;

备战区:DRAWICON(XH2,0,12),COLOR006EFF;

STICKLINE(XH2,0,ZD1*20,4,0),COLOR006EFF;

XX1:=MA(LOW,2)*0.96;

XX2:=MA(LOW,26)*0.85;

XX3:= REF(XX1,1)< XX2 AND REF(XX1,1)< XX1 AND REF(XX1,1)< REF(XX1,2);

STICKLINE(XX3,0,ZD1*16,4,0),COLOR006EFF;

DRAWICON(XX3,0,12);

C0:=REF(C,2)*0.865;

C1:=REF(C,13)*0.772;

DSY:=100*VOL/CAPITAL;

STICKLINE((C-MIN(C0,C1))/C< 0.1 AND SUM(DSY,5)/5< 1.8,0,ZD1*25,4,0),COLOR006EFF;

DRAWICON((C-MIN(C0,C1))/C< 0.1 AND SUM(DSY,5)/5< 1.8,0,12);

WW1:= SUM( MA(C,10),9)/10.110;

WW2:=CROSS(C,WW1);

STICKLINE(WW2,0,ZD1*26,4,0),COLOR006EFF;

DRAWICON(WW2,0,12);

VW1:=DMA(EMA(C,12),SUM(V,5)/3/CAPITAL);

VW2:=REF(H,10)/C>1.35;

VW3:=(COST(20)-C)/C>0.15;

VW4:=H>L*1.051;

VW5:=VW4 AND COUNT(VW4,5)>1;

VW6:=(((C-VW1)/VW1*100< -30) OR VW2) AND VW3 AND VW5;

STICKLINE(VW6,0,ZD1*40,4,0),COLOR0000FF;

DRAWICON(VW6,0,6);

XL1:=MA(LOW,2)*0.96;

XL2:=MA(LOW,26)*0.85;

XL3:=REF(XL1,1)< XL2 AND REF(XL1,1)< XL1 AND REF(XL1,1)< REF(XL1,2);

STICKLINE(XL3,0,15,4,0),COLORF8B7F0;

DRAWTEXT(XL3,25,'←买'),COLORF8B7F0;

JJP1:=REF(INDEXC,1);

JJP2:=FILTER((INDEXC-JJP1)/JJP1>0.03 AND ZDZK1>=ZDZK2,7);

STICKLINE(JJP2,0,-15,4,0),COLORFF00FF;

DRAWTEXT(JJP2,-15,'←井喷买'),COLORFF00FF;

该公式包含未来函数:WINNER
未发现:LWINNER...
未发现:PWINNER...
该公式包含未来函数:COST
该公式包含未来函数:CAPITAL

注：

       馆内各种公式为学习编程而保存，实战使用前一定要看其中是否有未来函数并自己亲自测试成功率，决不能依据公式名称的描述和形容去投资，据此入市造成投资损失由投资者自己承担。

       发文不易，如获益，欢迎赞赏，赞赏必复！