指标

J线共振
用法注释：
黄绿相间为长J、红蓝相间是短线、低位共振同色买、变异减仓出手快。
大智慧二代
DRAWTEXTREL(10,2,'黄绿相间为长J、红蓝相间是短线、低位共振同色买、变异减仓出手快。'),COLORMAGENTA;
RSV1:=(CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100;
K1:=SMA(RSV1,5,1);
D1:=SMA(K1,5,1);
J1:=3*K1-2*D1;
AA1:=EMA(J1,5);
AA2:=REF(AA1,1);
STICKLINE(AA1>AA2,AA1,AA2,8,0),COLOR0055AA;{长J}
STICKLINE(AA1>AA2,AA1,AA2,5,0),COLOR0077CC;
STICKLINE(AA1>AA2,AA1,AA2,3,0),COLOR0099DD;
STICKLINE(AA1>AA2,AA1,AA2,1,0),Color01BEE7;
STICKLINE(AA1<=AA2,AA1,AA2,8,0),COLOR006600;
STICKLINE(AA1<=AA2,AA1,AA2,5,0),COLOR009900;
STICKLINE(AA1<=AA2,AA1,AA2,3,0),COLOR00BB00;
STICKLINE(AA1<=AA2,AA1,AA2,1,0),COLOR00CC00;
RSV2:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K2:=SMA(RSV2,3,1);
D2:=SMA(K2,3,1);
J2:=3*K2-2*D2;
BB1:=EMA(J2,5);
BB2:=REF(BB1,1);
STICKLINE(BB1>BB2,BB1,BB2,7,0),COLOR000045;{短J}
STICKLINE(BB1>BB2,BB1,BB2,5,0),COLOR000085;
STICKLINE(BB1>BB2,BB1,BB2,3,0),COLOR0000C5;
STICKLINE(BB1>BB2,BB1,BB2,1,0),COLOR0000E5;
STICKLINE(BB1<=BB2,BB1,BB2,7,0),COLOR353500;
STICKLINE(BB1<=BB2,BB1,BB2,5,0),COLOR555500;
STICKLINE(BB1<=BB2,BB1,BB2,3,0),COLOR757500;
STICKLINE(BB1<=BB2,BB1,BB2,1,0),COLOR858500;
DD:=AA1>AA2 AND BB1>BB2;
注意买入:DD AND NOT(REF(DD,1)) AND (AA1<50 OR BB1<50) ,LINETHICK0;
DRAWICON(注意买入,-5,7),ALIGN0;
注意卖出:REF(DD,1)=1 AND NOT(DD),LINETHICK0;
DRAWICON(注意卖出,105,8),ALIGN0;

通达信KDJ与MACD同图显示
DIF:(EMA(CLOSE,12)-EMA(CLOSE,26))*100;
DEA:EMA(DIF,9);
MACD:(DIF-DEA)*2,COLORSTICK;
DRAWICON(CROSS(DIF,DEA),DEA,1);
DRAWICON(CROSS(DEA,DIF),DEA,2);

IF(DIF<DEA,DIF,DRAWNULL),COLORGREEN;
DD:=C=HHV(C,180);
EE:=DEA< REF(DEA,1) AND REF(DEA< REF(DEA,1),1)=1;
CC:=C> REF(C,1) AND REF(C> REF(C,1),1)=1;
顶背离:=(DD AND EE AND DEA< HHV(DEA,180))*DEA;
A2:=BARSLAST(REF(CROSS(DEA,DIF),1));
{顶背:=REF(CLOSE,A2+1)<CLOSE AND REF(DIF,A2+1)>DIF AND CROSS(DEA,DIF);}
DRAWLINE(A2=0,DEA,顶背离,DEA,0),COLORRED,LINETHICK2;
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:SMA(RSV,9,3),COLORYELLOW;
D:SMA(K,9,3),COLORWHITE;
J:3*K-2*D,COLORMAGENTA;
IF(J<D,J,DRAWNULL),COLORFFEE44;
A1:=BARSLAST(REF(CROSS(DIF,DEA),1));
B1:=REF(C,A1+1)>C AND REF(DIF,A1+1)<DIF AND CROSS(DIF,DEA);
A22:=BARSLAST(REF(CROSS("KDJ.K"(9,3,3),"KDJ.D"(9,3,3)),1));
B2:=REF(C,A22+1)>C AND REF("KDJ.K"(9,3,3),A22+1)<"KDJ.K"(9,3,3) AND CROSS("KDJ.K"(9,3,3),"KDJ.D"(9,3,3));
A3:=BARSLAST(REF(CROSS("RSI.RSI1"(6,12,24),"RSI.RSI2"(6,12,24)),1));
B3:=REF(C,A3+1)>C AND REF("RSI.RSI1"(6,12,24),A3+1)<"RSI.RSI1"(6,12,24) AND CROSS("RSI.RSI1"(6,12,24),"RSI.RSI2"(6,12,24));
DRAWTEXT(B1,DEA-0.20,'▲MACD底背'),COLORWHITE;
DRAWTEXT(B2,D-0.20,'●KDJ底背'),COLORFF00FF;
{DJ:=CROSS(J,D) AND D<20;
DRAWTEXT(DJ,J-0.3,'低金叉'),COLORCYAN;
MDJ:=CROSS(DIF,DEA) AND DEA<0;
DRAWTEXT(MDJ,DEA-0.3,'低金叉'),COLORGREEN;
DRAWTEXT(CROSS(DEA,DIF),DIF+0.3,'死叉'),COLORYELLOW;
DRAWTEXT(CROSS(D,J),J+0.3,'死叉'),COLORRED;}
A:=CROSS(DIF,DEA) AND CROSS(K,D) AND CROSS(J,D);
DRAWICON(A,LOW*0.98,1);
B4:CROSS(DIF,DEA) AND CROSS("KDJ.K"(9,3,3),"KDJ.D"(9,3,3));
DRAWTEXT(B4,L-0.20,'★金叉共振'),COLOR0099FF;

 

    涨停预警(通达信)
    均线82:=REF(C,1)/REF(C,2)<=0.93 AND BETWEEN(C/REF(C,1),1.03,0.97) AND CLOSE/REF(CLOSE,8)<=0.8 AND BETWEEN(REF(C,2)/REF(C,3),1.04,0.96) AND BETWEEN(REF(C,3)/REF(C,4),1.04,0.96),LINETHICK0,COLORYELLOW;
STICKLINE(均线82,0,4,8,0),COLORRED;
选股:均线82,COLORWHITE; 

 

通达信中精确的获取跨周期数据。

另外，公式只能帮助小周期引用大周期的数据（即向上引用），如果要引用小时数据的话，需对程序中的
“DAYS1970:=N*365+N1+(Y-1)*30+YS2+R-X;   {从基准年1月1日开始计算到当前的总天数}”
部分进行修改，可以改成更小时间周期的，只要软件数据支持。

又另，引用公式中的基准年份“1970”好奇怪，为什么不直接取个闰年做基准年份，搞的还要“N-2”那么麻烦，怀疑1970是不是作者的生日。废话多了点！ 下面正式开始

1：周线（引用公式）
N:=YEAR-1970;         {设1970为基准年份，距基准年份有几年}
N1:=INTPART((N-2)/4); {闰年数，注意：计算中不包含当前年份。另：N-2的意思是基准年后2年即1972年是最近的一个闰年}
F:=(N-2)-N1*4;        {当前年份是否闰年}
Y:=MONTH;             {月份。注意：以下月份的天数以30天为准进行修正}
XX:=IF(Y>=3 AND F>=1,2,IF(Y>=3 AND F=0,1,0));               {2月份缺少的天数}
YS2:=IF(Y=2 OR Y=3,1,
        IF(Y=4 OR Y=5,2,
        IF(Y=6 OR Y=7,3,
        IF(Y=8,4,
        IF(Y=9 OR Y=10,5,
        IF(Y=11 OR Y=12,6,
        0))))))-XX;     {有31天的大月的天数修正}
X:=IF(F=0,1,0);   {当前年份是否闰年的修正天数}
R:=DAY;           {当月的日期}
DAYS1970:=N*365+N1+(Y-1)*30+YS2+R-X;   {从基准年1月1日开始计算到当前的总天数}
Z:=((DAYS1970-REF(DAYS1970,1))>(WEEKDAY-REF(WEEKDAY,1))) OR BARSCOUNT(C)=1;  {看两个相邻周期是否跨周}
T:=BARSLAST(Z);
O1:IF(T,REF(O,T),O);
H1:HHV(H,T+1);
L1:LLV(L,T+1);
C1:C;

2：日线显示周线数据
OO:"周线.O1#WEEK";
HH:"周线.H1#WEEK";
LL:"周线.L1#WEEK";
CC:"周线.C1#WEEK";

其实可以在通达信中直接将“周线（引用公式）”源码的最后部分改为
O1:IF(T,REF(O,T),O),NODRAW;
H1:HHV(H,T+1),NODRAW;
L1:LLV(L,T+1),NODRAW;
C1:C,NODRAW;
DRAWKLINE(H1,O1,L1,C1);

然后设为副图指标，在日线图中调出来与日K线对照比较。每一根日K线都有一根相对应的周K线。大家在周K线中会看到一周内日K线对应的周K线开盘价都是一样的，因为从周线的角度来看周K线只能有一个开盘价。周最高最低开盘价的变化与其在一周内出现的早晚对图形产生影响。废话不多说，贴个图来直观的看。
{月K线}
DAYS:=DATETODAY(DATE)-DAY;   {从1990.12.19开始计算到当前的总天数}
Z:=((DAYS-REF(DAYS,1))>(MONTH-REF(MONTH,1))) OR BARSCOUNT(C)=1;  {看两个相邻周期是否跨周}
T:=BARSLAST(Z);
O1:IF(T,REF(O,T),O),NODRAW;
H1:HHV(H,T+1),NODRAW;
L1:LLV(L,T+1),NODRAW;
C1:C,NODRAW;
DRAWKLINE(H1,O1,L1,C1);

{年K线}
N:=YEAR-1970;
N1:=INTPART((N-2)/4);
DAYS:=N*365+N1;
Z:=((DAYS-REF(DAYS,1))>(YEAR-REF(YEAR,1))) OR BARSCOUNT(C)=1;
T:=BARSLAST(Z);
O1:IF(T,REF(O,T),O),NODRAW;
H1:HHV(H,T+1),NODRAW;
L1:LLV(L,T+1),NODRAW;
C1:C,NODRAW;
DRAWKLINE(H1,O1,L1,C1);

看到这些指标图，，我首先想到的是，，当前价格在一周、一月、一年内的相对位置！！！大家好好发挥想象力吧！！！

 

仿写的首富软件压力支撑位指标，正版软件上该指标原名为“YLZCW ”。
我已和正版首富软件的指标对照过了，线型，颜色，包括指标数值的小数，完全和正版指标相同。仿写指标可以在大智慧新一代或通达信上使用。
源码如下：
{YLZCW   主图 即首富压力支撑位 参数N:1,500,13;   M:1,500,55}
RSV13:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
K13:=SMA(RSV13,3,1);
D13:=SMA(K13,3,1);
J13:=3*K13-2*D13;
RSV55:=(CLOSE-LLV(LOW,M))/(HHV(HIGH,M)-LLV(LOW,M))*100;
K55:=SMA(RSV55,3,1);
D55:=SMA(K55,3,1);
J55:=3*K55-2*D55;
YLW:IF(CROSS(J55,J13),HIGH,REF(HIGH,BARSLAST(CROSS(J55,J13)))),COLORRED;
ZCW:IF(CROSS(J13,J55),LOW,REF(LOW,BARSLAST(CROSS(J13,J55)))),COLORBLUE;

初学乍练写公式，前几天斗胆在理想论坛上公布了该源码，得到各位老师的鼓励, 特别是得到了属于偶像级的大庆老杨老师的鼓励，心里非常高兴。许多老师都建议公布源码时最好附上对照的图，其实我也是这么想的。不瞒大家说，我在发贴时发过图，可自以为会发图不难的我, 却始终发不出去，最后只好作罢。今天在理想论坛中看到一篇介绍理想论坛中可行的发图方法的帖子，才知道自己错在哪里。今天特地重发指标，并补上图。就算是新手练习吧。

 

要判断一个股票的底部，我们必须结合指标来判断，最简单的方法有以下几个方面：
（1）KDJ指标的J值在0以下，即负数；
（2）CCI指标的数值在一200附近；
（3）股价在BOLL下轨或者以下；
（4）股价远离5日平均线至少10％以上。
只有满足了上面4个条件，一般情况下股价就面临底部
寂寞先生底部选股阳线买选股公式
TYP:=(HIGH+LOW+CLOSE)/3;
CCI:=(TYP-MA(TYP,14))/(0.015*AVEDEV(TYP,14));
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=SMA(RSV,3,1);
D:=SMA(K,3,1);
J:=3*K-2*D;
BOLL:=MA(CLOSE,20);
UPPER:=BOLL+2*STD(CLOSE,20);
LOWER:=BOLL-2*STD(CLOSE,20);
MA1:=MA(CLOSE,5);
阳线买:CCI<-200  AND J<0 AND CLOSE<LOWER AND CLOSE<MA1/1.1;

 

这个指标是专用于抄底逃顶。
这样使用比较好：红柱后三线是否粘合考虑抄底，绿柱后就走人。

{估抄底F-通用}
RSV1:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
RSV2:=(CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100;
J1:=SMA(RSV1,3,1);J2:=SMA(J1,3,1);
趋势线:3*SMA(RSV2,5,1)-2*SMA(SMA(RSV2,5,1),3,1),LINETHICK2,COLORFF84FF;
K:SMA(RSV2,3,1),LINETHICK2,COLORWHITE;
D:SMA(K,3,1),LINETHICK2,COLORF408F4;
{见顶信号:100,COLORCCFF00;}
买点准备:IF(趋势线<=10,30,0),LINETHICK2,COLORYELLOW;
出点准备: IF(CROSS(J2,J1) AND J2>85,70,100),LINETHICK2,COLOR00FF00;
强弱界线:49,POINTDOT,LINETHICK3,COLOR99AACC;
{以下设置副图显示方式}
STICKLINE(趋势线>88,100,趋势线,4,1),COLORGREEN;
STICKLINE(趋势线<=10,0,趋势线,4,1),COLORYELLOW;
STICKLINE(COUNT(趋势线<REF(趋势线,1) AND 趋势线<10,2)=2,0,20,4,0),COLORRED;
STICKLINE(CROSS(J2,J1) AND J2>85,100,80,4,0),COLORGREEN;
DRAWICON(CROSS(趋势线,49),趋势线,1),COLORRED;
DRAWICON(FILTER(CROSS(D,K) AND D>81,10),D*1.05,2);
DRAWTEXT(CROSS(趋势线,49),47,'转强'),COLORRED;
DRAWTEXT(CROSS(49,趋势线),52,'转弱'),COLORGREEN;

 

TDX
{估抄底F}

STICKLINE(C>0,0,100,15,0),COLOR7C221C;
RSV1:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
RSV2:=(CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100;
WEN:=3*SMA((CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,5,1)-2*SMA(SMA((CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,5,1),3,1);
J1:=SMA(RSV1,3,1);J2:=SMA(J1,3,1);
W1:=SMA(RSV2,3,1);W2:=SMA(W1,3,1);
强弱界线:49,POINTDOT,LINETHICK3,COLOR9966CC;
见顶信号:100,COLORCCFF00;

出点准备: IF(CROSS(J2,J1) AND J2>85,70,100),LINETHICK2,COLOR00FF00;
趋势线: WEN,LINETHICK2;
买点准备:IF(趋势线<=10,30,0),LINETHICK2,COLORYELLOW;
G1:w1,LINETHICK2,COLORWHITE;
G2:w2,LINETHICK2,COLORCYAN;
STICKLINE(趋势线>88,100,趋势线,3,1),COLORGREEN;
STICKLINE(趋势线<=10,0,趋势线,3,1),COLORYELLOW;
STICKLINE(COUNT(趋势线<REF(趋势线,1) AND 趋势线<10,2)=2 ,0,20,3,0),COLORRED;
STICKLINE(CROSS(J2,J1) AND J2>85,100,80,3,0),COLORGREEN;
DRAWICON(CROSS(趋势线,49),趋势线,1);
DRAWICON(FILTER(CROSS(G2,G1) AND G2>81,10),G2*1.05,2);
DRAWTEXT(CROSS(趋势线,49),47,'转强'),COLORRED;
DRAWTEXT(CROSS(49,趋势线),52,'转弱'),COLORGREEN;

FOX
{估抄底F}

DRAWGBK(1,COLORRGB(20,50,50),COLORRGB(30,30,140),1);
RSV1:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
RSV2:=(CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100;
WEN:=3*SMA((CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,5,1)-2*SMA(SMA((CLOSE-LLV
(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,5,1),3,1);
J1:=SMA(RSV1,3,1);J2:=SMA(J1,3,1);
W1:=SMA(RSV2,3,1);W2:=SMA(W1,3,1);
强弱界线:49,POINTDOT,LINETHICK3,COLOR9966CC;
见顶信号:100,COLORCCFF00;

出点准备: IF(CROSS(J2,J1) AND J2>85,70,100),LINETHICK2,COLOR00FF00;
趋势线: WEN,LINETHICK2,COLORFF84FF;
买点准备:IF(趋势线<=10,30,0),LINETHICK2,COLORYELLOW;
G1:W1,LINETHICK2,COLORWHITE;
G2:W2,LINETHICK2,COLORCYAN;
STICKLINE(趋势线>88,100,趋势线,5,1),COLORGREEN;
STICKLINE(趋势线<=10,0,趋势线,5,1),COLORYELLOW;
STICKLINE(COUNT(趋势线<REF(趋势线,1) AND 趋势线<10,2)=2 ,0,20,8,0),COLORRED;
STICKLINE(CROSS(J2,J1) AND J2>85,100,80,8,0),COLORGREEN;
DRAWICON(CROSS(趋势线,49),趋势线,4),COLORRED;
DRAWICON(FILTER(CROSS(G2,G1) AND G2>81,10),G2*1.05,2);
DRAWTEXT(CROSS(趋势线,49),47,'转强'),ALIGN0,COLORRED;
DRAWTEXT(CROSS(49,趋势线),52,'转弱'),ALIGN0,COLORGREEN;

 

DZH
{估抄底F}

RSV1:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
RSV2:=(CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100;
WEN:=3*SMA((CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,5,1)-2*SMA(SMA((CLOSE-LLV (LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,5,1),3,1);
J1:=SMA(RSV1,3,1);J2:=SMA(J1,3,1);
W1:=SMA(RSV2,3,1);W2:=SMA(W1,3,1);
强弱界线:49,POINTDOT,LINETHICK3,COLOR9966CC;
见顶信号:100,COLORCCFF00;

出点准备: IF(CROSS(J2,J1) AND J2>85,70,100),LINETHICK2,COLOR00FF00;
趋势线: WEN,LINETHICK2,COLORFF84FF;
买点准备:IF(趋势线<=10,30,0),LINETHICK2,COLORYELLOW;
G1:W1,LINETHICK2,COLORWHITE;
G2:W2,LINETHICK2,COLORCYAN;
STICKLINE(趋势线>88,100,趋势线,5,1),COLORGREEN;
STICKLINE(趋势线<=10,0,趋势线,5,1),COLORYELLOW;
STICKLINE(COUNT(趋势线<REF(趋势线,1) AND 趋势线<10,2)=2 ,0,20,8,0),COLORRED;
STICKLINE(CROSS(J2,J1) AND J2>85,100,80,8,0),COLORGREEN;
DRAWICON(CROSS(趋势线,49),趋势线,7),COLORRED;
DRAWICON(FILTER(CROSS(G2,G1) AND G2>81,10),G2*1.05,2);
DRAWTEXT(CROSS(趋势线,49),47,'转强'),ALIGN0,COLORRED;
DRAWTEXT(CROSS(49,趋势线),52,'转弱'),ALIGN0,COLORGREEN;

 

青云直上主图
精准买卖
DRAWGBKLAST(CLOSE>0,STRIP(RGB(95,95,95),RGB(0,0,0),0));
AA05:MA(C,5),color0099cc;
五日乖离率:=(c-AA05)/AA05*100;
BB05:=atan((aa05/ref(aa05,1)-1)*100)*180/3.1416;
速度5:=sma(ema((AA05-ref(AA05,1))/ref(AA05,1),3)*100,3,1);
加速度5:ema((速度5-ref(速度5,1)),3),linethick0;
STICKLINE(BB05>30 and AA05>ref(AA05,1), AA05,REF(AA05,1),8,1),colorcyan;
AA10:MA(C,10);AA20:=MA(c,20);
BB10:=atan((aa10/ref(aa10,1)-1)*100)*180/3.1416;
STICKLINE(BB05<0 and AA05<ref(AA05,1), AA05,REF(AA05,1),8,1),coloryellow;
AA30:MA(C,30);
三拾日乖离率:(c-AA30)/AA30*100,linethick0;
Var1:=(AA20-AA30)>ref((AA20-AA30),1) and AA20>ref(aa20,1) and AA30>ref(AA30,1);
Var2:=(AA30-AA20)<ref((AA30-AA20),1) and AA20<ref(aa20,1) and AA30<ref(AA30,1);
BB30:=atan((aa30/ref(aa30,1)-1)*100)*180/3.1416;
STICKLINE(BB30>15 and AA30>ref(AA30,1), AA30,REF(AA30,1),8,1),colorff00ff;
强势狙击:=filter(BB30>30 and BB10>45 and cross(BB05,60),10);
加仓:=filter(count(cross(BB05,30),5)>=1 and AA05>ref(aa05,1)  and 三拾日乖离率>ref(三拾日乖离率,1) and AA10>ref(AA10,1)
and 加速度5>ref(加速度5,1) and 速度5>ref(速度5,1)  ,10) ;
清仓:=filter(count(cross(30,BB05),5)>=1 and (c>AA30 or O>AA30) and AA05<ref(aa05,1)  and 三拾日乖离率<ref(三拾日乖离率,1) and AA10<ref(AA10,1),10);
drawtext(加仓 ,low*0.98,'←加仓'),colorred;
JC:=cross(0,五日乖离率) and 三拾日乖离率<ref(三拾日乖离率,1) and AA10>ref(AA10,1) ;
减仓:=filter(JC,10);
MR:=count(cross(五日乖离率,0),3)>=1 and 三拾日乖离率>ref(三拾日乖离率,1) and AA05>ref(AA05,1) and (c/ref(c,1)-1)*100>5 and ref(c,1)<AA30;
买入:=filter(MR,10);
drawtext(减仓,high*1.02,'←减仓'),colorcyan;
drawtext(买入,low*0.98,'←买入'),coloryellow;
drawtext(清仓 ,high*1.02,'←清仓'),colorgreen;
drawtext(强势狙击,LOW*0.98,'←强势狙击'),coloryellow;
Var21:=MAX(ABS(HIGH-AMOUNT/VOL/100),ABS(AMOUNT/VOL/100-LOW));
Var3:=ABS((OPEN+CLOSE)/2-AMOUNT/VOL/100);
MV:=(Var21+Var3)/AMOUNT*VOL*100*50;
DRAWTEXT(MV>6 and l<=llv(l,10),l*0.95,'←异动'),colorcyan;

 

青云直上选股器

青云直上指标发布后,受到朋友们的喜爱.在此我向大家表示深切的感谢!

有朋友希望我将指标中的"买入","加仓","强势狙击"写成选股公式,现将公式写在下面,希望朋友们能喜欢.

QYZS选股
AA05:=MA(C,5);
五日乖离率:=(c-AA05)/AA05*100;
BB05:=atan((aa05/ref(aa05,1)-1)*100)*180/3.1416;
速度5:=sma(ema((AA05-ref(AA05,1))/ref(AA05,1),3)*100,3,1);
加速度5:=ema((速度5-ref(速度5,1)),3);
AA10:=MA(C,10);AA20:=MA(c,20);
BB10:=atan((aa10/ref(aa10,1)-1)*100)*180/3.1416;
AA30:=MA(C,30);
三拾日乖离率:=(c-AA30)/AA30*100;
Var1:=(AA20-AA30)>ref((AA20-AA30),1) and AA20>ref(aa20,1) and AA30>ref(AA30,1);
Var2:=(AA30-AA20)<ref((AA30-AA20),1) and AA20<ref(aa20,1) and AA30<ref(AA30,1);
BB30:=atan((aa30/ref(aa30,1)-1)*100)*180/3.1416;
强势狙击:filter(BB30>30 and BB10>45 and cross(BB05,60),10);
加仓:filter(count(cross(BB05,30),5)>=1 and AA05>ref(aa05,1)  and 三拾日乖离率>ref(三拾日乖离率,1) and AA10>ref(AA10,1)
and 加速度5>ref(加速度5,1) and 速度5>ref(速度5,1)  ,10) ;
MR:=count(cross(五日乖离率,0),3)>=1 and 三拾日乖离率>ref(三拾日乖离率,1) and AA05>ref(AA05,1) and (c/ref(c,1)-1)*100>5 and ref(c,1)<AA30;
买入:filter(MR,10);

 

下面是选股思路如下:
1.分时走势图下的白线（股价）和黄线（均价)之间的振幅要能随个人喜好控制.
2.白线（股价）和黄线（均价)粘合在一起时的时间长短要能随个人喜好控制.
3.白线（股价）和黄线（均价)之间的上下关系最好是要能随个人喜好控制.
4.个股当时的涨跌幅要能随个人喜好调节.
5.DDX和DDY,DDZ正式用户可以自己设定.
6.软件自动监控预警(大多软件都有此功能).
7.选出股票后再仔细观察它的基本面和当时的量能.

除第5是DDE,我们是老百姓啊用免费就行,分时不需要它.第7中的看基本面,想要到其它地方拿来放进去就可以看了,这个也不放了.
其它条件基本完成.若做的不好请同学们指点,本人可是尽力了(水平有限没办法).
这个指标可继续优化.可自已调节参数,做到你有多大本领你就调多少,自已炒股自作主.可预警可选股.也可做下跌提示等等..................

【分时横盘】(优化版),

tt:=BARSCOUNT(C);
CC:=CLOSE;
zz:=SUM(AMOUNT,tt)/SUM(VOL*100,tt);
zz1:=BETWEEN(C/zz,1.05,0.95);
均线:IF(zz1=0,MA(C,TT),zz),COLOR00FFFF,LINETHICK2;
上均:均线 + AVEDEV(C,tt)*2,COLOR00FF00;
下均:均线 - AVEDEV(C,tt)*2,COLORFF6600;
时长:=if(HOUR>=13 AND HOUR<15 ,1,0);
涨幅:=(close/DYNAINFO(3))>=1.03;
跌幅:=(close/DYNAINFO(3))<=0.97;
涨跌幅:=涨幅 OR 跌幅;
yy:=SMA(vol,30,1);
放量:=(yy-LLV(Llv(yy,1),30))/(HHV(Hhv(yy,1),30)-LLV(Llv(yy,1),30))>0;
横盘:=((HHV(CLOSE,TT)-LLV(CLOSE,TT))/CLOSE)<=0.05;
横涨:=涨跌幅=0 and 横盘 and 时长 and 放量  and CROSS(CC,上均)and DYNAINFO(22)<DYNAINFO(23) ;
横跌:=涨跌幅=0 and 横盘 and 时长 and 放量  and CROSS(下均,CC) ;
PP:= FILTER(横涨,100) ;
UU:= FILTER(横跌,50) ;
DRAWTEXT(PP,上均,'★上突'),colorff00ff;
DRAWTEXT(UU,下均,'★下破'),COLOR00FFFF;
VERTLINE( PP,3),COLORWHITE,LINETHICK2;
VERTLINE( UU,3),COLOR00FF00,LINETHICK2;

下面有二张分时图参考,本指标其实是一个基本的框架指标.只是一间房子,里面你想怎么装修你就怎么装修.就是不断加入你认为好的功能和条件.使其达到自已想达到的目的

 

横盘后上涨分笔预警.
加外盘大于内盘

tt:=BARSCOUNT(C);
CC:=CLOSE;
zz:=SUM(AMOUNT,tt)/SUM(VOL*100,tt);
zz1:=BETWEEN(C/zz,1.05,0.95);
均线:=IF(zz1=0,MA(C,TT),zz);
上均:=均线 + AVEDEV(C,tt)*2;
下均:=均线 - AVEDEV(C,tt)*2;
时长:=if(HOUR>=13 AND HOUR<15 ,1,0);
涨幅:=(close/DYNAINFO(3))>=1.03;
跌幅:=(close/DYNAINFO(3))<=0.97;
涨跌幅:=涨幅 OR 跌幅;
yy:=SMA(vol,30,1);
放量:=(yy-LLV(Llv(yy,1),30))/(HHV(Hhv(yy,1),30)-LLV(Llv(yy,1),30))>0;
横盘:=((HHV(CLOSE,TT)-LLV(CLOSE,TT))/CLOSE)<=0.05;
横盘上涨:=涨跌幅=0 and 横盘 and 时长 and 放量  and CROSS(CC,上均)and DYNAINFO(22)<DYNAINFO(23);
上突:FILTER(横盘上涨,50);

横盘后下跌分笔预警.

tt:=BARSCOUNT(C);
CC:=CLOSE;
zz:=SUM(AMOUNT,tt)/SUM(VOL*100,tt);
zz1:=BETWEEN(C/zz,1.05,0.95);
均线:=IF(zz1=0,MA(C,TT),zz);
上均:=均线 + AVEDEV(C,tt)*2;
下均:=均线 - AVEDEV(C,tt)*2;
时长:=if(HOUR>=13 AND HOUR<15 ,1,0);
涨幅:=(close/DYNAINFO(3))>=1.03;
跌幅:=(close/DYNAINFO(3))<=0.97;
涨跌幅:=涨幅 OR 跌幅;
yy:=SMA(vol,30,1);
放量:=(yy-LLV(Llv(yy,1),30))/(HHV(Hhv(yy,1),30)-LLV(Llv(yy,1),30))>0;
横盘:=((HHV(CLOSE,TT)-LLV(CLOSE,TT))/CLOSE)<=0.05;
横盘下跌:=涨跌幅=0 and 横盘 and 时长 and 放量  and CROSS(下均,CC) ;
下破:FILTER(横盘下跌,50) ;

 

 

 

通达信源码：
{界文KD}
N1:=7;N2:=27;
STICKLINE(C>0,40,60,10,0),COLOR999999;
RSV:=(CLOSE-LLV(LOW,N1))/(HHV(HIGH,N1)-LLV(LOW,N1))*100;
短K:SMA(RSV,3,1),COLORF580F5,LINETHICK0;
短D:SMA(短K,3,1),COLORCCDD33,LINETHICK0;
RSV1:=(CLOSE-LLV(LOW,N2))/(HHV(HIGH,N2)-LLV(LOW,N2))*100;
中K:SMA(RSV1,5,1),COLORRED,LINETHICK0;
中D:SMA(中K,10,1),COLOR33AA33,LINETHICK0;
底线:10,COLORWHITE;
顶线:90,COLOR00FFFF;
STICKLINE(短K>短D,短K,短D,3,1),COLORF580F5;
STICKLINE(短K<=短D,短K,短D,3,1),COLORCCDD33;
STICKLINE(中K>中D,中K,中D,2,0),COLOR0000EF;
STICKLINE(中K<=中D,中K,中D,2,0),COLOR33AA33;