【日内策略】Hans123

真圆易行 2012-11-10

展开全文

【日内策略】Hans123

2012-11-09 10:18:01 作者：来源：浏览次数：26

//策略：HANS123
//周期：日内
//类别：趋势突破

作为外汇市场上广为流行的一种突破交易策略，HANS123以其简洁的开盘后N根K线的高低点突破，作为交易信号触发的评判标准。这也是一种入场较早的交易模式，配合适当过滤技术，或可提高其胜算。

主要特点：

在开盘30分钟后准备入场；

上轨＝开盘后30分钟高点；

下轨＝开盘后30分钟低点；

用法:

当价格突破上轨，买入开仓；

当价格跌穿下轨，卖出开仓。

代码（金字塔语言）：

//策略：HANS123
//周期：日内
//类别：趋势突破
//修订时间:2012.11.1
//Designed By Rogarz

//准备中间变量

input:ss(1,1,100,1);
N:=barslast(date<>ref(date,1))+1;
开盘30分钟最高价:=valuewhen(time<=090000+30*100,hhv(h,n));
开盘30分钟最低价:=valuewhen(time<=090000+30*100,llv(l,n));
手数:=ss;
上轨:开盘30分钟最高价;
下轨:开盘30分钟最低价;
//条件
开多条件:=c>上轨;
开空条件:=c<下轨;
//交易系统
if time>090000+30*100 and time<150000-10*100 then begin
开多:buy(开多条件 and holding=0,手数,market);
开空:buyshort(开空条件 and holding=0,手数,market);
end
//平仓
if time>=150000-10*100 then BEGIN
收盘平多:sell(1,手数,market);
收盘平空:sellshort(1,手数,market);
end

资金:asset,noaxis;

######################################################################################

//参数版

//策略：HANS123
//周期：日内
//类别：趋势突破
//修订时间:2012.11.1
//Designed By Rogarz

//准备中间变量
input:ss(1,1,100,1),nmin1(30,1,1000,1),nmin2(10,1,100,1),n1(0,0,100,1);
N:=barslast(date<>ref(date,1))+1;
开盘30分钟最高价:=valuewhen(time<=090000+nmin1*100,hhv(h,n));
开盘30分钟最低价:=valuewhen(time<=090000+nmin1*100,llv(l,n));
手数:=ss;
上轨:开盘30分钟最高价+n1*mindiff;
下轨:开盘30分钟最低价-N1*mindiff;
//条件
开多条件:=c>上轨;
开空条件:=c<下轨;
//交易系统
if time>090000+nmin1*100 and time<150000-10*100 then begin
开多:buy(开多条件 and holding=0,手数,market);
开空:buyshort(开空条件 and holding=0,手数,market);
end
//平仓
if time>=150000-nmin2*100 then BEGIN
收盘平多:sell(1,手数,market);
收盘平空:sellshort(1,手数,market);
end