Ftp判断文件是否上传成功批处理

开下面这个批处理是否能实现你的要求，
从另一台ftp去判断

@echo off
rem 指定FTP用户名
set ftpUser=asx
rem 指定FTP密码
set ftpPass=asx-asx
rem 指定FTP服务器地址
set ftpIP=172.19.103.42
rem 指定待下载的文件位于FTP服务器的什么位置
set ftpFolder=/export/home/PROD/ntcdata
rem 指定从FTP下载下来的文件存放到什么地方
set DownFolder=D:\AppServ\www\BadDut\data\dutbin\wright\ntdutbin-st
set DownFolder2=D:\AppServ\www\BadDut\data\dutbin\wright\ntdutbin-o
set DownFolder3=D:\AppServ\www\BadDut\data\summary\wright\ntsummary_st
set DownFolder4=D:\AppServ\www\BadDut\data\summary\wright\ntsummary_o

rem 指定下载几天前的文件
set DaysAgo=1
set ftpDir=%temp%\TempDir.txt
set ftpDown=%temp%\TempDown.txt

rem 假设本机日期格式为yyyy-mm-dd
set FileY=%date:~0,4%
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
set /a PassDays-=DaysAgo
call :DaysToDate %PassDays% DstYear DstMonth DstDay

>"%ftpDir%" echo.%ftpUser%
>>"%ftpDir%" echo.%ftpPass%
>>"%ftpDir%" echo bin
>>"%ftpDir%" echo cd "%ftpFolder%"
>>"%ftpDir%" echo dir * "%temp%\FileList.txt"
>>"%ftpDir%" echo bye
start ftp -v -i -s:"%ftpDir%" %ftpIP%

rem 根据实际情况自行调节延迟时间
ping -n 350 127.1 >nul

findstr /i ":*\.SWM$" "%temp%\FileList.txt">"%temp%\FileDate.txt"
findstr /i ":*\.TWM$" "%temp%\FileList.txt">>"%temp%\FileDate.txt"
findstr /i ":*\.OWM$" "%temp%\FileList.txt">>"%temp%\FileDate.txt"

>"%ftpDown%" echo.%ftpUser%
>>"%ftpDown%" echo.%ftpPass%
>>"%ftpDown%" echo bin
>>"%ftpDown%" echo cd "%ftpFolder%"
(for /f "usebackq tokens=1-9 delims= " %%a in ("%temp%\FileDate.txt") do (
  setlocal enabledelayedexpansion
  if "%%f" equ "Jan" (
    set FileM=01
  ) else if "%%f" equ "Feb" (
    set FileM=02
  ) else if "%%f" equ "Mar" (
    set FileM=03
  ) else if "%%f" equ "Apr" (
    set FileM=04
  ) else if "%%f" equ "May" (
    set FileM=05
  ) else if "%%f" equ "Jun" (
    set FileM=06
  ) else if "%%f" equ "Jul" (
    set FileM=07
  ) else if "%%f" equ "Aug" (
    set FileM=08
  ) else if "%%f" equ "Sep" (
    set FileM=09
  ) else if "%%f" equ "Oct" (
    set FileM=10
  ) else if "%%f" equ "Nov" (
    set FileM=11
  ) else if "%%f" equ "Dec" (
    set FileM=12
  )
  set FileD=10%%g
  set FileD=!FileD:~-2!
  if "!FileM!" equ "%DstMonth%" (
    if "!FileD!" equ "%DstDay%" (
     echo get "%%i" "%DownFolder%\%%i"
    )
  )
  endlocal
))>>"%ftpDown%"
>>"%ftpDown%" echo bye
start ftp -v -i -s:"%ftpDown%" %ftpIP%

rem 根据实际情况自行调节延迟时间
ping -n 700 127.1 >nul

copy /y "%DownFolder%\*.*" "%DownFolder2%"

ping -n 800 127.1 >nul

copy /y "%DownFolder%\*.*" "%DownFolder3%"

ping -n 900 127.1 >nul

copy /y "%DownFolder%\*.*" "%DownFolder4%"
goto :eof

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF

批处理的思路是当你的A的FTP没上传一个文件时把这个文件上传的路径和完整名字记录到一个指定的.txt文件内，然后下次上传的时候把总目录和这个已上传文件比对，没有则上传，这个批处理还得高人指教你。

最简单的方法是你在当前文件夹用dir /s /a /b >all.txt
然后你有新文件需要上传到时候再次用dir /s /a /b >new-all.txt 
比对all.txt 和new-all.txt这个完全可以用很多比对文件的软件来比对Beyond Compare 来比对