Excel 如何在word中随着光标移动，相应的行高亮或者改变颜色

QUOTE:

以下是引用dell2000在2008-10-21 15:19:00的发言：
为了看得更清楚，如果在word中随着光标移动，相应的行高亮或者改变颜色，那就好了，有何办法？请教了

我这里有两种方案，但都还不完美，仅供楼主应急用。

方案一：本方案将行设为动态文字。输入代码后，运行AutoExec或重启Word后即可。

优点：比较符合楼主的显示要求。缺点：更改了文字的格式设置，可能会带来一些不良后果（我未做太多测试）。

第一步：在VBE中插入一个类模块class1，输入以下代码：

Public WithEvents appWord As Word.Application

Dim myRange

Private Sub appWord_DocumentBeforeClose(ByVal Doc As Document, Cancel As Boolean)

   myRange = Empty   '此句是为了避免文档关闭后出现myRange对象丢失的现象

End Sub

Private Sub appWord_DocumentBeforeSave(ByVal Doc As Document, SaveAsUI As Boolean, Cancel As Boolean)

   ActiveDocument.Bookmarks("\Line").Range.Font.Animation = wdAnimationNone   '此句是为了避免将动态效果保存

End Sub

Private Sub appWord_WindowSelectionChange(ByVal Sel As Selection)

   If Not IsEmpty(myRange) Then

     If myRange.InRange(ActiveDocument.Bookmarks("\Line").Range) _

        And myRange.Font.Animation = wdAnimationMarchingRedAnts Then

        Exit Sub

     End If

     myRange.Font.Animation = wdAnimationNone            '取消动态效果

   End If

   Set myRange = ActiveDocument.Bookmarks("\Line").Range

   myRange.Font.Animation = wdAnimationMarchingRedAnts

End Sub

第二步：在VBE中插入一个普通模块，输入以下代码：

   Dim a As New class1

Sub AutoExec()

   Set a.appWord = Word.Application

End Sub