分享

引导小白从零开始学股票公式编辑(三)参照...

 工人ABC 2021-04-10

参照我的《利用周线与DMI和CCI捕获长牛妖股》实例!

上篇中已经教大家学会了均线粘合度的编辑,下面详细讲解一下其他条件编辑:

收盘价C要高于所有均线,只要求出均线的最大值,使用MAX(A,B)函数嵌套如下:

Z1:=MAX( MAX(MAX(MAX(MAX(MA(C,32),MA(C,50)) ,MA(C,98)),MA(C,188) ),MA(C,388) ), MA(C,6) ) ;

再次CCI(98)要金叉100,这里的98是他的参数改成98, 不知道CCI是什么?该怎么做,打开行情软件的公式编辑器选择CCI公式然后在点修改他就看到他的源码如附图,图中的M就是参数,这个时候我们就改成98。所以在金叉100就可以这样写:

TYP := (HIGH + LOW + CLOSE)/3;
CCI1:=(TYP-MA(TYP,98))/(0.015*AVEDEV(TYP,98));

CCI金叉条件:=CROSS( CCI1 , 100 );


最后一个条件DMI的PDI金叉成最大值。同上方法得到DMI的各线公式(附图),P ,M 是参数选用缺省值也就是默认值分别改成 14 和 6 得到如下:

TR1 :=SMA(MAX(MAX(HIGH-LOW,ABS(HIGH-REF(CLOSE,1))),ABS(LOW-REF(CLOSE,1))),14,1);
HD := HIGH-REF(HIGH,1);
LD := REF(LOW,1)-LOW;
DMP:= SMA(IF(HD>0 AND HD>LD,HD,0),14,1);
DMM:= SMA(IF(LD>0 AND LD>HD,LD,0),14,1);
PDI:= DMP*100/TR1;
MDI:=DMM*100/TR1;
ADX:=SMA(ABS(MDI-PDI)/(MDI+PDI)*100,6,1);
ADXR:=(ADX+REF(ADX,6))/2;

注意最后几句是输出语句这时候就要在冒号后面加等于号变成赋值语句,首先满足最大值条件就可这样写:

PDI最大条件:= PDI > MAX ( MAX( MDI , ADX ) ,ADXR );

PDI金叉就是随便金叉另外三根线的一根,这个时候我们就用 OR 这个或者意思的连接词,

PDI金叉条件:= CROSS( PDI ,MDI ) OR CROSS( PDI , ADX ) OR CROSS( PDI , ADXR ) ;

到此所有条件已经教会大家如何编写,安排个作业就是把所有条件整合成选股公式。选股公式最后一句就是把所有条件用 AND 连接在一起,不需要冒号和等于号的赋值或输出。比如我想想选出股价大于100并且收阳线的股票:

C > 100 AND C > O;

就这样可以了,字母O代表开盘价。
更多的实例将陆续发布。

#股票# #A股# #股市分析#

    本站是提供个人知识管理的网络存储空间,所有内容均由用户发布,不代表本站观点。请注意甄别内容中的联系方式、诱导购买等信息,谨防诈骗。如发现有害或侵权内容,请点击一键举报。
    转藏 分享 献花(0

    0条评论

    发表

    请遵守用户 评论公约

    类似文章 更多