本帖最后由 兰博基尼 于 2010-12-5 16:46 编辑
缠师用的MACD指标2.0
大智慧L2通过，其它软件自行修改也能用。
用于日线，用于低于日线级别请调高“股价新低:=股价L1=股价LL and 股价L1/股价L3<0.9;”中的“股价L1/股价L3”值。
本帖隐藏的内容需要回复才可以浏览
大智慧L2用
N:=2;
SHORT:=12*N;
LONG:=29*N;
M:=9*N;
DIFF : EMA(CLOSE,SHORT) - EMA(CLOSE,LONG);
DEA : EMA(DIFF,M);
MACD : 2*(DIFF-DEA), COLORSTICK;
0,dotline,colorwhite;
{以下处理底背离}
N1:=last(MACD<0);{绿柱天数}
N2:=REF(last(MACD>0),N1);{绿柱前红柱天数}
N3:=REF(last(MACD<0),N2+N1);{红柱前绿柱天数}
MINMD1:=LLV(MACD,N1);
MINMD3:=REF(LLV(MACD,N3+N2),N1);
MINDIFF1:=LLV(DIFF,N1);
MINDIFF3:=REF(LLV(DIFF,N2+N3),N1);
MINDEA1:=LLV(DEA,N1);
MINDEA3:=REF(LLV(DEA,N2+N3),N1);
股价L1:=LLV(L,N1);
股价L3:=REF(LLV(L,N2+N3),N1);
股价LL:=LLV(L,N1+N2+N3);
绿柱缩短:=MACD<0 AND MACD>REF(MACD,1) AND REF(MACD,1)<REF(MACD,2);
MACD底背离:=MACD<0 AND MINMD1>MINMD3;
DIFF底背离:=DIFF<0 AND MINDIFF1>MINDIFF3;
DEA底背离:=DEA<0 AND MINDEA1>MINDEA3;
股价新低:=股价L1=股价LL and 股价L1/股价L3<0.9;
底背离:绿柱缩短 AND MACD底背离 AND DIFF底背离 AND DEA底背离 AND 股价新低,COLORRED,PRECIS0,LINETHICK0;
VERTLINE(底背离 ,1 ),colorred;
DRAWICON(底背离,MACD*0.97,1,1),ALIGN1;
{以下处理顶背离}
M1:=last(MACD>0);{ 红柱天数}
M2:=REF(last(MACD<0),M1); {红柱前绿柱天数}
M3:=REF(last(MACD>0),M2+M1); {绿柱前红柱天数}
MAXMD1:=HHV(MACD,M1);
MAXMD3:=REF(HHV(MACD,M3+M2),M1);
MAXDIFF1:=HHV(DIFF,M1);
MAXDIFF3:=REF(HHV(DIFF,M2+M3),M1);
MAXDEA1:=HHV(DEA,M1);
MAXDEA3:=REF(HHV(DEA,M2+M3),M1);
股价H1:=HHV(H,M1);
股价HH:=HHV(H,M1+M2+M3);
红柱缩短:=MACD>0 AND MACD<REF(MACD,1) AND REF(MACD,1)>REF(MACD,2);
MACD顶背离:=MACD>0 AND MAXMD1<MAXMD3;
DIFF顶背离:=DIFF>0 AND MAXDIFF1<MAXDIFF3;
DEA顶背离:=DEA>0 AND MAXDEA1<MAXDEA3;
股价新高:=股价H1=股价HH;
顶背离:红柱缩短 AND MACD顶背离 AND 股价新高,COLORGREEN,PRECIS0,LINETHICK0;
VERTLINE(顶背离 ,1 ),colorgreen;
DRAWICON(顶背离,MAX(HHVALL(MACD),HHVALL(DIFF),HHVALL(DEA)),2,1),ALIGN1;
我随便翻看了几支股票，发现凡出现双底背离的地，基本上是中线大底，即使不是，也很少有赔钱的。缠师之所用以2倍周期，估计是和其资金量太大，只适宜做中长线有关系。但从另一个角度来看，不正是我们选中线牛股的一个方法吗？ |
